%%
%%  *:Q_SideStory Content
%%
%% These quests essentially act as filler for the LocalQuest ladders.
%%
%% To test a sidestory, set its requires attribute to *:Q_DSideStory
%%

Content
	name <Local Bully>
	requires <*:Q_SideStory -"Safe" -!Ne>
	% desc <A local bully is making mischief. Track them down and put a stop to it.>
	desc <地元の暴漢が迷惑行為を働いている。追跡して止めさせよう。>

	% E1 is an outdoors scene for the hideout.
	% E2 is the bully's hideout.
	% E3 is the bully.
	% E4 is the Mischief mood.
	Element1 <Scene Outdoors>
	Element2 <QuestScene>
	Place2 <1>
	Element3 <NewNPC 0 2 Criminal>
	Place3 <2 (Bully)>
	Element4 <Prefab>

	% P%id%01 = Initialization Counter
	update <if= P%id%01 0 P= %id%01 1 SetMood %4% %1%>

	% SubQuest1 = Local Tough; find out why this NPC is so bad.
	SubPlot1 <*Q_LocalTough 2 3>

	sub
		STC QS_Workshop
		name <%name3%'s Hideout>
		name_I18N <%name3% の隠れ家>
		SetID 2
		entrance <*QUEST-INACTIVE>

		Persona 3
		special <UNLISTED>
		greeting <if= PlotStatus %plotid% %id% else GoChat Goto GoGreet>
		GoChat <NewChat SayAnything>
		*GoGreet <*YouWentThroughALotOfTrouble .%id1%_GoInit>
	end
	inv
		MinorMood 1
		name <Mischief-Making Bully>
		plot_type <*Mischief>
		Element1 <Grab 1>
		Element2 <Grab 2>
		Element3 <Grab 3>
		% Msg_1 <%name3%'s up to no good, that's for sure.>
		Msg_1 <%name3% がまたロクでもないことをしようとしてる。間違いない%JG_YO。>
	end

Content
	name <Student Loans>
	requires <*:Q_SideStory ~Research ~Poor -Dystopia>
	% desc <A grad student needs help paying for tuition. We all know how expensive education is in the GH universe.>
	desc <とある院生が学費の援助を求めている。GH 世界の教育費の高さは皆の知る通り。>

	% E1 is the student.
	% E2 is a scene
	Element1 <Prefab>
	Place1 <2 (Citizens) Ally Pass>
	Element2 <Scene (Building|Meeting) Public>
	end <ifNPCDead %1% LoseSubPlot %plotid% CancelSubPlot %plotid1%>
	update <ifSubPlotWon %plotid1% QMemo %plotid% %id%01>

	% Msg%id%01 <You should go tell %name1% that you found \OPR %1% a sponsor.>
	Msg%id%01 <学費のスポンサーが見つかったと %name1% に伝えよう。>

	% SubQuest1 is the FindMoney bit.
	% SubQuest2 is the victory bit.
	SubPlot1 <*:Q_FindMoney 1>
	SubPlot2 <*Q_Win_OneShotReward.nocash 1>

	sub
		Persona 1
		% rumor%id% <%name1% has a lot of student loans.>
		rumor%id% <%name1% が多額の学生ローンを抱えている>
		greeting <if= PlotStatus %plotid% %id% else GoChat if# PlotStatus %plotid1% 0 else GoCheckFirst NewChat Say 1 AddChat 1 AddChat 2>
		GoCheckFirst <if= PlotStatus %plotid% %id% else GoChat ifG React 0 else GoChat ifChatNPCInPlay else GoComplain NewChat Say 2 AddChat 3 AddChat 4>
		GoComplain <NewChat Say 8>
		GoChat <NewChat SayAnything>
		result1 <Goto .%id2%_GoInit>
		result2 <Cash+ -2000000  PCAlly %1% NPCLevel %1% %threat% SetPlotStatus %plotid% -1 CancelSubPlot %plotid1% NewChat Say 5 History 6>
		result3 <NewChat Say 3 Cash+ -1 SetPlotStatus %plotid1% %id1% QMemo %plotid% 4>
		result4 <EndChat Say 7 AddSociable -d4 SetPlotStatus %plotid% -2>
		% Msg1_1 <The student loan people called today. I told them that %name1% was dead; they didn't believe me.>
		% Msg1_2 <How long can you survive on just noodles before you start to catch scurvy? I think I'm okay...>
		% Msg1_3 <I expect it'll take five years to pay off my student debt. The problem is, it's only three weeks until I starve to death.>
		% Msg2 <Hey there, spare a credit for a starving student?>
		% Msg3 <Thank you so much. I went to university to improve my life, but now I'm stuck with two million in student loans and no way to pay them off. If only I had some kind of benefactor...>
		% Msg4 <%name1% has $2M in student loan debt, and could use some help to get on \PPR %1% feet.>
		% Msg5 <Wow, thanks! Look, if you ever need my help, I want you to know that you can count on me.>
		% Msg6 <After you repaid \PPR %1% student debt, %name1% pledged to help you.>
		% Msg7 <If I had money you wouldn't treat me with such disrespect! Then again, if I had money I wouldn't be forced to beg...>
		% 後ろにくっ付いてる余計なpromptは何なのか。下ではその部分は削除。
		% Msg8 <Um, %name1% isn't here... And if you're one of the student loan people, you should know that \SPR %1% 's dead.>		Prompt1 <I found someone to help you out.>
		% こっちにも prompt1 があるのが謎の原因。
		% Prompt1 <I found a sponsor to pay off your loan.>
		% CPrompt1 <if= PlotStatus %plotid1% -1 Accept>
		% Prompt2 <I've decided to help you myself. [Give $2M]>
		% CPrompt2 <ifG PC$ 1999999 Accept>
		% Prompt3 <I can do that. [Give $1]>
		% CPrompt3 <ifG PC$ 0 Accept>
		% Prompt4 <Out of my way, freeloader.>
		Msg1_1 <今日、学生ローンの人から電話があった%JG_NDA。%name1% は死んだって言ってみたんだ%JG_GA……信じてもらえなかった%JG_YO。>
		Msg1_2 <生麺だけでマトモに生きていられるのってどれくらいの期間%JG_KANA？ まだ大丈夫だと思う%JG_GA……。>
		Msg1_3 <予定では、学生ローンの返済が終わるまでに５年。問題は、飢え死にまではあと３週間で十分だってこと%JG_DAYO%JV_SIL_R。>
		Msg2 <ああ、そこの人……飢えた学生に、ちょっとでもお金を恵んでもらえない%JG_KANA%JV_SIL_R？>
		Msg3 <ありがとう。より良い人生にしようと思って大学に行ったのに、今じゃ200万の学生ローンを抱えてしまって払えるアテもない身な%JG_NDA。どこかに寄付してくれる人でもいないもの%JG_KANA%JV_SIL_R。>
		Msg4 <%name1% は $2,000,000 の学生ローンを抱えており、生活の支援を必要としている。>
		Msg5 <うわあ、ありがとう！ もし、もしも%JS2が誰かに助けてほしい時は、絶対に%JF2が力になる%JG_YO！>
		Msg6 <学生ローンの支払いを肩代わりしたことで、%name1% はあなたの助けになることを誓った。>
		Msg7 <お金さえあったら、そんな酷い物言いはされないのに！ でも、お金があったらそもそも物乞いなんてしないよ%JV_NA……。>
		Msg8 <あー、%name1% は不在%JV_DESU……もしかして学生ローンの人？ \SPR %1%は死んだらしい%JV_DESUよ。>
		Prompt1 <ローンを払ってくれるスポンサーが見つかったよ。>
		CPrompt1 <if= PlotStatus %plotid1% -1 Accept>
		Prompt2 <もう自分が出してしまおう。[$2,000,000 渡す]>
		CPrompt2 <ifG PC$ 1999999 Accept>
		Prompt3 <いいよ。[$1 渡す]>
		CPrompt3 <ifG PC$ 0 Accept>
		Prompt4 <乞食はどっかに消えて%JG_R_AGG。>
	end
	inv
		NPC Student
		Survival
		Science
	end


Content
	name <Rishtan: Mechanical Genius>
	% desc <The local mechanic wants to start a customization shop, but lacks money.>
	desc <地元のメカニックが改造屋を始めたがっているが、資金がない。>
	requires <*:Q_SideStory L5PAT ~"Safe">

	% E1 is the shop manager
	% E2 is Rishtan
	% E3 is the garage where the manager is
	% E4 is Rishtan's workshop
	Element1 <Prefab>
	Place1 <3 (Citizens) Pass>
	Element2 <Prefab>
	Place2 <4 (Citizens) Pass>
	Element3 <Scene Building Public Garage>
	Element4 <QuestScene>
	Place4 <3>

	%% FAIL CONDITIONS:
	%% - Rishtan Dies
	%% - After completing mission, E1 dies
	end <ifNPCDead %2% else .%id%_GoCheckE1 LoseSubPlot %plotid%>
	.%id%_GoCheckE1 <if= NPCVar %2% 1 1 ifNPCDead %1% WinSubPlot %plotid%>

	SubPlot1 <*:Q_FindMoney.Investor 2>

	sub
		Persona 1
		Greeting <if= PlotStatus %plotid% %id% else GoGreet if= NPCVar %2% 1 1 else GoCheckQuest NewChat Say 1 AddChat 1>
		GoCheckQuest <if= PlotStatus %plotid1% -1 else GoGreet NewChat Say 2>
		*GoGreet <*NiceToMeetYou GoOpenShop>
		*GoOpenShop <*SHOP_GENERAL GoGoodbye>
		*GoGoodbye <*GOODBYE>
		Result1 <NewChat Say 3 WinSubPlot %plotid% AddReact d10 CustomMecha .%id%_meks %threat%>
		.%id%_meks <GENERAL HOELL COMET MUGLE>
		% Msg1 <You did a really good thing for %name2%, for both of us really. I just wanted the chance to thank you.>
		% Msg2 <You found an investor? Then you better get downstairs and let %name2% know about it, before he blows a diode or something.>
		% Msg3 <Well, because we wouldn't have a store without you, I want you to have this mecha. Thanks.>
		% Prompt1 <It was the least I could do.>
		Msg1 <%JS2は本当に %name2% の、%JR_NO、%JF2%JF_TACHI２人の助けになってくれた。お礼を言う機会を待っていた%JV_N%JV_M_DA。>
		Msg2 <出資してくれる人が見つかった%JV_F_NO？ じゃあ下に行って %name2% に教えてやって……彼がまた何か爆発させる前に。>
		Msg3 <%JS2がいなかったら、%JF2%JF_TACHIは店を開けなかった。お礼のしるしにこのメックを受け取ってほしい%JV_N%JV_M_DA。ありがとう。>
		Prompt1 <最低限のことをしただけ%JG_DA。>

		Persona 2
		special <UNLISTED>
		% rumor%id% <there was some talk of opening a custom shop in %name3%, but nothing ever came of it.>
		rumor%id% <%name3% に改造屋ができるっていう話があったんだ%JG_GA、それから何も進展がない>
		% V1 = Conversation skill roll counter
		Greeting <if= NPCVar %2% 1 1 else GoCheckQuest NewChat Say 18 AddChat 16 AddChat 17>
		GoCheckQuest <if# PlotStatus %plotid1% 0 else GoIntro NewChat Say 16 AddCHat 14 AddChat 15>
		GoIntro <if= PlotStatus %plotid% %id% else GoChat  ifG PCRenown %threat% else GoLowIntro ifG React d6 else GoLowIntro NewChat Say 9  AddChat 7 AddChat 8 AddChat 9>
		GoLowIntro <ifChatNPCUnknown else GoSecondTime NewChat Say 1 AddChat 1 AddChat 2 AddChat 3>
		GoSecondTime <NewChat Say 2  AddChat 1 AddChat 2 AddChat 3>
		GoBeginQuest <QMemo %plotid% 20  SetPlotStatus %plotid1% %id1%>
		*GoChat <*MISC_CHATTER>
		*GoGoodbye <*GOODBYE>
		result1 <NewChat Say 3 AddChat 4 AddCHat 5 AddChat 3>
		result2 <EndChat Say 4>
		result3 <NewChat Say 5 AddChat 4 AddChat 1 AddChat 6>
		result4 <Goto result2>
		result5 <if= V1 0 else GoR5Fail V= 1 1  ifConversation SkillTar %threat% else GoR5Fail NewChat Say 6  AddChat 10 AddChat 11  Goto GoBeginQuest>
		GoR5Fail <EndChat Say 7>
		result6 <EndChat Say 8>
		result7 <NewChat Say 10 AddChat 10 AddChat 11  Goto GoBeginQuest>
		result8 <NewChat Say 11 AddReact -d30  AddNPCReact %1% -15   AddSociable -d8   SetPlotStatus %plotid% -2>
		result9 <NewChat Say 12 AddChat 12 AddChat 13>
		result10 <NewChat Say 13 AddChat 11 AddChat 14>
		result11 <NewChat Say 14>
		result12 <AddCheerful d10 Goto result7>
		result13 <AddCheerful d10 Goto result8>
		result14 <NewChat Say 15 History 21 AddReact 15  NPCVar= %2% 1 1 Cash+ -5000000 XPV 100 AddRenown 1>
		result15 <NewChat Say 17 History 21 AddReact d8  NPCVar= %2% 1 1                XPV 100>
		result16 <EndChat Say 19 shop .wares Goto GoGoodbye>
		.wares <MECHA MEK_ENG>
		result17 <Goto GoChat>
		% Msg1 <What are you doing down here? This is a place of business, not a social club.>
		% Msg2 <So you're back again. I hope you've got a good reason for bothering me this time.>
		% Msg3 <I fix things for %name1%... Mecha, mostly, but occasionally robots and office equipment. Of course what I'd really like to do is open up a conversion shop and become a famous mecha designer, but that's never going to happen.>
		% Msg4 <Look, I've got to get these repairs done, I don't have time to chat. Maybe if you come back later I'll have more time but right now I'm swamped.>
		% Msg5 <Then you need to speak with %name1%, upstairs. I handle the labor, \SPR %1% handles the business. The exit is just over there.>
		% Msg6 <First of all because we don't have the tools I need here for making custom parts. Unfortunately we don't have enough money to upgrade the workshop, so until this shop starts doing better I'm out of luck.>
		% Msg7 <Because... look, you wouldn't be interested in my life story, and I don't have time to tell it. I have to get back to work.>
		% Msg8 <I don't need any help, I just need to get back to work. You can talk with %name1% if you'd like a job here but I honestly don't think we can afford another mechanic.>
		% Msg9 <Look who it is... the famous \PC . If you're not too busy on your fantastic adventures I have a business offer for you.>
		% Msg10 <Well, I'd like to expand the garage, start doing mecha customizations... Unfortunately, I don't have the equipment we'd need. If you would invest some money now then maybe in a few years there'll be a huge amount of profit.>
		% Msg11 <I see... and this without even hearing my idea. That's just great. Fine, I don't need you... I can do this all on my own...>
		% Msg12 <Yes, I remember that very well... Though my counselor says I'll be learning to live with the trauma soon. Now do you want to hear about my business idea or not?>
		% Msg13 <I figure we'll need around five million for the basic equipment. After that I just need to build a reputation as a designer, then soon we might even make a profit.>
		% Msg14 <If you can, that would be great. I just know that I can make it as a mecha designer, all I need is one chance to prove it!>
		% Msg15 <Wow, this is great! Thank you so much! I promise that when this shop starts making profit, I'll pay you back with interest...>
		% Msg16 <In order to start my customization business, I'll need at least five million credits for new equipment.>
		% Msg17 <That's fantastic news! I'll order the new equipment right away... Come back here later and I'll show you what I can do!>
		% Msg18 <Welcome to %name2%'s custom mecha shop. Thank you again for helping this dream to come true!>
		% Msg19 <I have a number of mecha for sale, some of which I've customized myself. I also have some replacement parts in case you'd like to try your hand at mecha engineering.>
		% Msg20 <%name2% in %name3% wants to open a mecha customization shop, but needs money to buy the equipment.>
		% Msg21 <You helped Rishtan open his customization shop in \SCENE RootSceneID .>
		% Prompt1 <What is it that you do down here?>
		% Prompt2 <I just wanted to chat.>
		% Prompt3 <I need to get my mecha repaired.>
		% Prompt4 <Uh-huh. So do you know any rumors?>
		% Prompt5 <Why do you think it can't happen?>
		% Prompt6 <Maybe I could help you out.>
		% Prompt7 <Alright, what kind of offer?>
		% Prompt8 <I'm not interested.>
		% Prompt9 <I was in here bothering you before! Remember?>
		% CPrompt9 <ifChatNPCKnown Accept>
		% Prompt10 <How much money do you need?>
		% Prompt11 <Maybe I can find someone else to invest.>
		% Prompt12 <Okay. Tell me about it.>
		% Prompt13 <Sorry, it doesn't sound interesting.>
		% Prompt14 <I can do that. [Give $5M]>
		% CPrompt14 <ifG PC$ 4999999 Accept>
		% Prompt15 <I've found an investor for you.>
		% CPrompt15 <if= PlotStatus %plotid1% -1 Accept>
		% Prompt16 <I'd like to see what you have.>
		% Prompt17 <Just stopped by to chat, thanks.>
		Msg1 <ここで何をしているんだ？ ここは仕事場だ、社交場じゃないぞ。>
		Msg2 <また来たのか。それなりの理由があって来てるんだろうな？>
		Msg3 <%name1% と修理屋をしている……だいたいはメックだが、たまにロボットだのオフィス機器なんかも。もちろん、いつかは自分の店を持ってメックデザインをやりたいが……まあ無理だろうな。>
		Msg4 <見ろ、%JF2には修理の仕事がまだこんなに残ってる。お喋りをしてる時間はないんだ。また今度なら多少は余裕があるかもしれないが、今は立て込んでる真っ最中なんだよ。>
		Msg5 <それなら上にいる %name1% と話してくれ。%JF2の仕事は肉体労働、商談は\SPR %1%の担当だ。出口はすぐそこにある。>
		Msg6 <まず、パーツの自作に必要な設備がない。で、それを買うための金もない。だから今の仕事でもっと稼ぎを出さないと、無理だ。>
		Msg7 <それは……いや、%JF2の人生の話なんて興味ないだろう。喋ってる時間もない。仕事に戻らせてくれ。>
		Msg8 <他からの助けは頼んでない。いいから仕事に戻らせてくれ。そんなにここで働きたければ %name1% と話をしてくればいい……メカニックを増やす余裕など無いと思うがね。>
		Msg9 <これは……有名人の \PC じゃないか。素晴らしい冒険の旅に忙しいのでなければ、少しビジネスの話をさせてはもらえないだろうか。>
		Msg10 <うむ……%JF2はこの仕事場を拡張して、メックの改造屋を始めたいと考えているんだ。しかし、残念ながら……そのための設備が足りていない。もし資金を出してもらえるなら、何年か後には大きな利益を上げて返せるだろう。>
		Msg11 <……まだ話も聞かないうちから、それか。分かった、上等だ。%JS2の助けなど必要ない……自分の力でやってみせるさ……。>
		Msg12 <いや、もちろん良く覚えてる……あれのおかげでトラウマとの向き合い方が身に付くだろう、とカウンセラーには言われたがね。それで、ビジネスの話は聞いてもらえるのか？>
		Msg13 <見積もりでは、基本的なものを揃えるのにおよそ $5,000,000 が必要だ。そこからメックデザイナとしての評価さえ確立できれば、きっと利益を生めるようになるだろう。>
		Msg14 <そうしてもらえるなら、ありがたい。メックデザインなら自信はあるんだ、それを証明するためのチャンスさえ手に入れられれば……！>
		Msg15 <おおっ、素晴らしい！ 本当に感謝する！ 店が利益を上げられるようになったら、かならず配当を払うと約束するぞ……。>
		Msg16 <%JF2が店を始めるには、新しく設備を整えるのに少なくとも $5,000,000 が必要になる。>
		Msg17 <素晴らしいニュースだ！ すぐに設備を発注しよう……また今度来てくれ、%JF2の腕を見せてやるぞ！>
		Msg18 <%name2% のカスタムメック・ショップへようこそ。夢を叶えさせてくれて、本当に感謝している！>
		Msg19 <まずは販売用のメック……いくつかは%JF2が自分で手を加えたものだ。自分で改造してみたい場合に備えて、交換用パーツも揃えてあるぞ。>
		Msg20 <%name3% の %name2% はメックの店を開きたいと考えているが、そのための資金が足りていない。>
		Msg21 <\SCENE RootSceneID の Rishtan がメックの店を開業する手助けをした。>
		Prompt1 <ここで何をしてる%JV_N%JV_M_DA？>
		Prompt2 <ちょっと話がしたかった%JV_F_NO。>
		Prompt3 <メックの修理をしてほしい。>
		Prompt4 <そうなの%JV_KA_Q。じゃあ何か面白い噂とか知らない？>
		Prompt5 <どうして無理な%JV_N%JV_M_DA？>
		Prompt6 <何か手伝えることがあるかも。>
		Prompt7 <いいよ、どんなの%JV_M_DA？>
		Prompt8 <興味ない%JV_F_WA。>
		Prompt9 <前にもここに来た%JV_DAROU、覚えてないの%JV_KA_Q？>
		CPrompt9 <ifChatNPCKnown Accept>
		Prompt10 <いくらくらい必要%JV_M_DA？>
		Prompt11 <どこかで出資者を探してみる%JG_YO。>
		Prompt12 <オーケー、話を聞く%JG_YO。>
		Prompt13 <悪いけど、興味が沸きそうにない%JV_F_WA。>
		Prompt14 <それくらいなら。[$5,000,000 渡す]>
		CPrompt14 <ifG PC$ 4999999 Accept>
		Prompt15 <出資者が見つかった%JV_YO。>
		CPrompt15 <if= PlotStatus %plotid1% -1 Accept>
		Prompt16 <商品を見せてほしい。>
		Prompt17 <ちょっと寄ってみただけ%JV_M_DA。ありがとう。>

		MetaScene 1
		sub
			room
			name <Mecha Shop>
			name_I18N <メック店>
			ShowNAME <true>
			minimap <.......2......1.....&---!>
			special <SHAREDPALETTE>
			desig <HOME>
			inv
				TrapDoor
				MiniMapComponent 2
				desig <ENTRANCE %4%>
				Hide
				update <if= PlotStatus %plotid% %id%   SetStat STAT_MetaVisibility 0>
			end
		end

		MetaScene 2
		sub
			room
			minimap <......##...#2.....1......>
			special <SHAREDPALETTE>
			desig <HOME>
			inv
				STC COMPUTER-1
				name <Design Console>
				name_I18N <デザイン・コンソール>
				MiniMapComponent 2
			end
		end

		STC QS_Workshop
		SetID 4
		name <%name2%'s Workshop>
		name_I18N <%name2% の工房>
	end
	inv
		NPC Mechanic

		NPC Mechanic
		name <Rishtan>
		CharDesc Male Pragmatic Shy
		% Actual game age = 24
		Age 4
		% V1 = Have arranged funding, thereby unlocking store
		Shopping 8
		MechaEngineering 10
	end


Content
	name <Rat Killing>
	% desc <The PC has to kill a rat for the NPC.>
	desc <PC は NPC のためにネズミを１匹殺さなければならない。>
	requires <*:Q_SideStory>

	% E1 is the shopkeeper
	% E2 is the infested basement
	% E3 is the mall for the shopkeeper
	element1 <Prefab>
	Place1 <3 (Citizens) Pass Ally>
	Element2 <QuestScene>
	Place2 <3>
	Element3 <Scene Mall Public>

	%% FAIL CONDITIONS:
	%% - E1 dies
	end <ifNPCDead %1% LoseSubPlot %plotid%>

	update <if= SceneVar %2% 1 1 SetPlotSTatus %plotid1% %id1%>

	% Quest1 is the continuation after the PC has cleared the basement.
	SubPlot1 <*Q_WinTask 1>

	sub
		Persona 1
		% rumor%id% <%name1% has a real problem in the basement.>
		rumor%id% <%name1% のところの地下で何か問題が起きている>
		% V1 = Have given quest
		greeting <if= PlotStatus %plotid% %id% else GoGreet if= V1 1 else GoFirstTime NewChat Say 1 AddChat 1 AddChat 2>
		GoFirstTime <ifChatNPCInPlay else GoBusy NewChat Say 2 AddChat 3 AddChat 4>
		GoBusy <NewChat Say 6>
		*GoGreet <*NiceToMeetYou GoOpenShop>
		*GoOpenShop <*SHOP_GENERAL GoGoodbye>
		*GoGoodbye <*GOODBYE>
		Result1 <Goto GoOpenShop>
		Result2 <NewChat Say 1>
		Result3 <NewChat Say 3  V= 1 1  QMemo %plotid% 5  UpdateProps>
		result4 <NewChat Say 4  SetPlotStatus %plotid% -2>
		% Msg1 <So, how goes the extermination of those rats?>
		% Msg2 <Hey, I was wondering if you could help me with a little problem.>
		% Msg3 <There are some rats or something infesting the basement. One of my workers got bit just recently... I need you to exterminate them. This door will take you down there.>
		% Msg4 <I understand. I won't bother you about it again.>
		% Msg5 <%name1% in %name3% asked you to clear some vermin out of \PPR %1% basement.>
		% Msg6 <I'm kind of busy right now... Why don't you drop by %name3% if there's something you need?>
		% Prompt1 <Actually, I need to buy some things first.>
		% Prompt2 <Still working on it.>
		% Prompt3 <What kind of problem?>
		% Prompt4 <Sorry, I'm not interested.>
		Msg1 <ネズミ退治は順調に進んでる%JG_KANA？>
		Msg2 <%JR_HEY、%JS2……ちょっとした問題の解決をお願いできない%JG_KANA。>
		Msg3 <地下でネズミか何かが大繁殖している%JG_NDA。この間、ウチの従業員が一人そいつらに噛まれてしまって……%JF2に駆除をお願いしたい%JV_F_NO。この扉から下に行ける%JG_YO。>
		Msg4 <そう%JV_DESUKA。ではもう邪魔はし%JV_MASENよ。>
		Msg5 <%name3% の %name1% から、地下階の害獣駆除を依頼された。>
		Msg6 <今はちょっと忙しい%JG_NDA%JV_SIL_R何か入用なら、%name3% に寄ってくれ%JV_MASENか？>
		Prompt1 <その前にちょっと買い物がしたい。>
		Prompt2 <まだ途中%JV_M_DA。>
		Prompt3 <どんな問題？>
		Prompt4 <悪いけど、興味ない%JV_F_WA%JV_NA。>

		MetaScene 1
		sub
			room
			name <General Shop>
			name_I18N <小売店>
			ShowNAME <true>
			minimap <2#...+#.......1.....&---!>
			special <SHAREDPALETTE>
			desig <HOME>
			sub
				Door
				update <if= V1 0 else GoCheckQuest V= 1 1 SetStat STAT_Lock HardSkillTar %threat%>
				GoCheckQuest <ifG PlotStatus %plotid% 0 SetStat STAT_Lock 0>
			end
			inv
				TrapDoor
				MiniMapComponent 2
				desig <ENTRANCE %2%>
			end
		end

		STC QS_ExterminationBasement
		name <%name1%'s Basement>
		name_I18N <%name1% の地下階>
		SetID 2
	end
	inv
		NPC Shopkeeper
	end


Content
	name <"Give Mission" NewNPC>
	requires <*:Q_SideStory>
	% desc <A randomly generated NPC will give the PC a mission, to be handled by a "GiveMission" subquest.>
	desc <ランダム生成された NPC が PC に任務を与え、この続きは "GiveMission" のサブクエストで扱われる。>

	% E1 is the root scene
	% E2 is the person who will be giving the mission.
	% E3 is the scene where they are located
	Element1 <.>
	Element2 <NewNPC 0 1>
	Place2 <3 (Citizens) Pass>
	Element3 <Scene Building Public !Okay 2>

	%% FAIL CONDITIONS:
	%% - E2 dies
	end <ifNPCDead %2% LoseSubPlot %plotid%>

	update <ifSubPlotWon %plotid1% else .%id%_GoCheckLoss SetPlotStatus %plotid2% %id2%>
	.%id%_GoCheckLoss <ifSubPlotLost %plotid1% SetPlotStatus %plotid3% %id3%>

	% SubQuest1 is the mission.
	% SubQuest2 is the victory, after the mission is completed.
	% SubPlot3 is the loss condition
	SubPlot1 <*:Q_MinorMission 2>
	SubPlot2 <*Q_WinTask 2>
	SubPlot3 <*Q_LoseTask 2>

	sub
		Persona 2
		% rumor%id% <%name2% needs help from a cavalier.>
		rumor%id% <%name2% がメック乗りの助けを必要としている>
		greeting <if= PlotStatus %plotid% %id% else GoChat if= PlotStatus %plotid1% 0 else GoRemind Goto GoEnemyCheck>
		*GoRemind <*GenericMissionReminder>
		*GoEnemyCheck <*ENEMY_CHECK GoOfferQuest ChatNPCFac GoMakeEnemy>
		GoMakeEnemy <SetPlotStatus %plotid% -2 ifG d20 React PCEnemy %2%>
		*GoOfferQuest <*DoYouWantAJob GoStartQuest>
		GoStartQuest <SetPlotStatus %plotid% %id% Goto .%id1%_GoInit>
		GoChat <NewChat SayAnything>
	end


Content
	name <Restaurant Dreams>
	% desc <An aspiring chef wants to start a restaurant. Maybe the PC can help.>
	desc <野心的なシェフがレストランを開きたがっている。PC は手助けができるかもしれない。>
	requires <*:Q_SideStory ("Cuisine"|"Rich")>

	% E1 is the cook
	% E2 is a scene for the restaurant
	Element1 <Prefab>
	Place1 <2 (Citizens) Pass Ally>
	Element2 <Scene (Building|Meeting) Public>

	%% FAIL CONDITIONS:
	%% - E1 dies
	end <ifNPCDead %1% LoseSubPlot %plotid%>

	% SubQuest1 is the search for money
	SubPlot1 <*:Q_FindMoney.Investor 1>

	sub
		Persona 1
		% rumor%id% <%name1%'s dream is to some day open a restaurant.>
		rumor%id% <%name1% の夢はレストランを開くこと>
		% V1 = Salad Timer
		greeting <ifSubPlotWon %plotid% else GoCheckQuest ifG ComTime V1 else GoNoSalad ifChatNPCinPlay else GoNoSalad NewChat Say 16 AddChat 12 AddChat 13>
		GoNoSalad <NewChat Say 15>
		GoCheckQuest <if= PlotStatus %plotid% %id% else GoChat if# PlotStatus %plotid1% 0 else GoMakeOffer  NewChat Say 1 AddChat 1 AddChat 2 AddChat 3>
		GoMakeOffer <if= PlotStatus %plotid1% 0 else GoChat  ifG React 30 else GoNoLike  NewChat Say 10 AddChat 10 AddChat 11>
		GoNoLike <NewChat SayAnything AddChat 7>
		*GoChat <*MISC_CHATTER>
		GoStartQuest <SetPlotStatus %plotid1% %id1% QMemo %plotid% 7>
		result1 <NewChat Say 13 History 14 AddReact d10 WinSubPlot %plotid% V= 1 NextDay>
		result2 <NewChat Say 2>
		result3 <NewChat Say 3 AddChat 4 AddChat 5>
		result4 <EndChat Say 4 History 14 Cash+ -2000000 AddReact * 2 d10  WinSubPlot %plotid% V= 1 NextDay>
		result5 <NewChat Say 5>
		result7 <NewChat Say 6 AddChat 8 AddChat 3 AddChat 9 Goto GoStartQuest>
		result8 <NewChat Say 8>
		result9 <NewChat Say 9>
		result10 <NewChat Say 11 AddChat 8 AddChat 3 AddChat 9 Goto GoStartQuest>
		result11 <NewChat Say 12 AddReact -10 CancelSubPlot %plotid%>
		result12 <NewChat Say 17 PCEat GiveSTC .salad V= 1 NextDay>
		.salad <SALAD-1>
		result13 <NewChat Say 18>
		% Msg1 <So, have you had any luck finding investors for my restaurant yet?>
		% Msg2 <Well, until such a time as you have, I'll be right here reading these cookbooks. I've got to be ready for my big day.>
		% Msg3 <It's going to take at least $2,000,000 to set up a decent restaurant, and even then I might not be able to afford chairs. It shouldn't matter, though- for fine cuisine, people should be willing to stand.>
		% Msg4 <Wow, you'd do that? Thanks! I'll be sure to name a salad in your honor... "Salad du \PC "...>
		% Msg5 <It's a bit too steep for me as well, and that's the problem. Let me know when you find something.>
		% Msg6 <Yes, that's right. Why does that matter to you?>
		% msg7 <%name1% in %name2% needs an investor so \SPR %1% can open a restaurant.>
		% msg8 <It'd be great if you could. Come back here and let me know if you find anything.>
		% Msg9 <Well, if you come up with anything, come back here and let me know. I'll take all the help I can get.>
		% Msg10 <Hey, how would you like to help me with something?>
		% Msg11 <I came to this city to study cooking. It's my dream to open a restaurant, but right now I don't have the money. I heard that cavaliers know lots of people; do you think maybe someone you know could help me?>
		% Msg12 <I understand. Maybe someday when I'm rich and successful I'll be able to brush people off like that too.>
		% Msg13 <Thank you so much! I'll be sure to name a salad in your honor... "Salad du \PC "...>
		% Msg14 <You helped %name1% to open a restaurant in \SCENE RootSceneID .>
		% Msg15 <Hi, \PC ! I'm working on some new recipes for my grand opening.>
		% Msg16 <You've arrived at just the right time. How would you like to try my new "Salad du \PC "?>
		% Msg17_1 <Here you go. I'm still working on the ingredients, but I think this is pretty close to the final recipe.>
		% Msg17_2 <Here you are. I hope you like it.>
		% Msg17_3 <Here you go. Come back tomorrow and I may have something else for you to try.>
		% Msg18 <Come back whenever you're hungry, then.>
		% Prompt1 <Actually, I have.>
		% CPrompt1 <ifSubPlotWon %plotid1% Accept>
		% Prompt2 <No, not yet.>
		% Prompt3 <I'd like to invest in it myself.>
		% CPrompt3 <ifPCRenowned Accept>
		% Prompt4 <I can afford that. [Give Money]>
		% CPrompt4 <ifG PC$ 1999999 Accept>
		% Prompt5 <That's a bit too steep for me.>
		% Prompt7 <Aren't you the person who wants to open a restaurant?>
		% Prompt8 <Maybe I could find you an investor.>
		% Prompt9 <I don't know.>
		% Prompt10 <Tell me what you want.>
		% Prompt11 <Sorry, kid, I don't have the time.>
		% Prompt12 <Sounds good. Let me try it!>
		% Prompt13 <Thanks, but I'm not hungry.>
		Msg1 <で、レストランに出資してくれる人は見つかった%JV_F_NO？>
		Msg2 <あ〜、じゃあ見つけてくれるまでここで料理の本を読んでる%JG_YO。その日のための準備は念入りにしとかないと%JG_NE！>
		Msg3 <マトモなレストランにしようと思ったら、少なくとも $2,000,000 くらい……それでも椅子とかまで揃えるのには足りないかもしれない。でもそっちは別にいい%JG_YO、極上の料理のためならみんな立ってるくらい平気なはずだから。>
		Msg4 <おおっ、出してくれるの%JV_KA_Q？ ありがとう！ 敬意を表して、新しいサラダに名前を付けよう……“サラド・ドゥ・\PC”とか。>
		Msg5 <%JF2にも高すぎるから問題な%JG_SK。何かツテが見つかったら教えて%JG_R。>
		Msg6 <そう、その通り%JG_DAYO。それがどうかしたの%JV_KA_Q？>
		msg7 <%name2% の %name1% はレストランを開業するために出資者を必要としている。>
		msg8 <そうしてくれるなら助かる%JG_YO。何か見つかったら知らせて%JG_R。>
		Msg9 <え〜、もし何か見つかったら、ここに来て知らせて%JG_R_AGG。助けなら何でも貰っとくから。>
		Msg10 <あ、ちょっと。%JF2に助けて欲しいことがある%JV_Nだけど。>
		Msg11 <この街には料理の勉強をしに来た%JG_NDA。レストランを開くのが夢なんだ%JG_GA、今は資金がなくて。メック乗りは人脈がスゴいって話を聞いたから……誰か手を貸してくれそうな人って知らない%JG_KANA？>
		Msg12 <分かった%JG_YO。いつか成功して金持ちになったら、%JF2もそんな風に他人をコケにしてやるから。>
		Msg13 <マジでありがとう！ 敬意を表して、新しいサラダに名前を付けよう……“サラド・ドゥ・\PC”とか。>
		Msg14 <\SCENE RootSceneID の %name1% がレストランを開店するのを支援した。>
		Msg15 <やあ、\PC！ グランドオープンに向けて、新しいレシピを開発してるところな%JG_NDA。>
		Msg16 <丁度バッチリのタイミングで時に来た%JG_NE。新作“サラド・ドゥ・\PC”を味わってみない%JV_KA_Q？>
		Msg17_1 <どうぞ。まだ素材が完全に決まってないんだけど、これでも完成にかなり近いはず%JG_DAYO。>
		Msg17_2 <どうぞ。気に入ってくれるといいけど。>
		Msg17_3 <どうぞ。また明日来てくれれば、別のものも味見してもらえるかも。>
		Msg18 <じゃあ、また腹ペコの時にでも来て。>
		Prompt1 <実は見つかった%JV_F_NO。>
		CPrompt1 <ifSubPlotWon %plotid1% Accept>
		Prompt2 <%JR_NO、まだ。>
		Prompt3 <%JF2が出させてもら%JV_OU。>
		CPrompt3 <ifPCRenowned Accept>
		Prompt4 <それくらいなら。[金を渡す]>
		CPrompt4 <ifG PC$ 1999999 Accept>
		Prompt5 <ちょっと高すぎるかなあ。>
		Prompt7 <レストランを開こうとしてるって聞いた%JG_GA。>
		Prompt8 <どこかで出資者を見つけられるかもしれない%JV_F_WA。>
		Prompt9 <いや、別に何も。>
		Prompt10 <言ってみて。>
		Prompt11 <子供に付き合ってる時間はない%JV_F_WA%JV_NA。>
		Prompt12 <いい%JV_F_WAね、食べてみる！>
		Prompt13 <ありがとう、でも今は腹は減ってない%JG_NDA。>
	end
	inv
		NPC Cook
		chardesc Passionate Young
	end


Content
	name <Addiction Issues>
	% desc <An NPC asks you to help his cousin escape a life of sin and debauchery.>
	desc <とある NPC から、彼のいとこが罪と放蕩にまみれた生活から抜け出す手助けをしてほしいと頼まれる。>
	requires <*:Q_SideStory "City">

	% E1 is the home scene
	% E2 is the mission-giving NPC
	% E3 is the wayward cousin
	% E4 is the mission-giver's home scene
	Element1 <.>
	Element2 <NewNPC 1 1 Lawful Easygoing>
	Place2 <4 (Citizens) pass ally>
	Element3 <NewNPC 0 1 Criminal Passionate Young>
	Element4 <Scene Building Legit Public>

	%% FAIL CONDITIONS:
	%% - E2 dies
	end <ifNPCDead %2% LoseSubPlot %plotid%>

	update <ifSubPlotWon %plotid1% else .%id%_GoCheckLoss SetPlotStatus %plotid2% %id2%>
	.%id%_GoCheckLoss <ifSubPlotLost %plotid1% SetPlotStatus %plotid3% %id3%>

	% SubQuest1 is the intervention for the target
	% SubQuest2 is the victory if E2 is reformed
	% SubQuest3 is the loss condition
	SubPlot1 <*:Q_PersonalIntervention 3 2>
	SubPlot2 <*Q_WinTask 2>
	SubPlot3 <*Q_LoseTask 2>

	sub
		Persona 2
		% rumor%id% <%name2% has been very worried about %name3%.>
		rumor%id% <%name2% は %name3% のことが気がかりで仕方ない。>
		greeting <if= PlotStatus %plotid% %id% else GoGreet  if# PlotStatus %plotid1% 0 else GoCheckQuest NewChat Say 4 AddChat 4>
		*GoGreet <*NiceToMeetYou GoChat>
		*GoChat <*MISC_CHATTER>
		GoCheckQuest <ifNPCOK %3% else GoCancelQuest Goto GoAskHelp>
		GoCancelQuest <CancelSubPlot %plotid% Goto GoGreet>
		*GoAskHelp <*INeedYourHelp GoAccept GoRefuse>
		GoAccept <NewChat Say 1 QMemo %plotid% 2 SetPlotStatus %plotid1% %id1% AddChat 1 AddChat 2 AddChat 3>
		GoRefuse <NewChat Say 3 AddReact -d20  CancelSubPlot %plotid%>
		Result1 <NewChat Say 6>
		Result2 <NewChat Say 7 AddEasygoing -d10>
		result3 <NewChat Say 8>
		result4 <NewChat Say 8>
		% Msg1 <My cousin %name3% has been missing for a couple of days now. In the past \SPR %3% 's had trouble with drugs and gambling, so I dread to think what \SPR %3% might be up to now.>
		% Msg2 <%name2% in %name4% is worried that \PPR %2% cousin %name3% may have fallen off the wagon.>
		% Msg3 <Suit yourself, if you don't want to get involved.>
		% Msg4 <Have you had any news about %name3% yet?>
		% Msg6 <I couldn't say... \SPR %3% always had a thing for drugs, gambling, and pornography, so wherever you can find those you should be able to find \OPR %3% .>
		% Msg7 <You may be right, but I can't help but worry... we are family, after all. If you see %name3% please tell \OPR %3% to come home.>
		% Msg8 <Thank you. Please, let me know when you have any information.>
		% Prompt1 <Where do you think %name3% is?>
		% Prompt2 <What %name3% wants to do is none of your business.>
		% Prompt3 <I'll see what I can find out.>
		% Prompt4 <I'm still working on it.>
		Msg1 <%JF2の従兄弟の %name3% が一昨日から行方不明な%JG_NDA。\SPR %3%は昔、麻薬とギャンブルに嵌ったことがあって……また最悪なことになってるんじゃないかと、心配な%JG_SK。>
		Msg2 <%name4% にいる %name2% は、従兄弟の %name3% がまた素行不良に陥ったのではないかと心配している。>
		Msg3 <関わりたくないのなら、もう帰って%JG_R_AGG。>
		Msg4 <%name3% の状況、何か分かった%JV_Q？>
		Msg6 <それは何とも……\SPR %3%はいつも麻薬とかギャンブルとか……ポルノとか、を求めていたから、そういうものがある場所に行けば、きっと……。>
		Msg7 <そうかもしれない%JG_GA、どうしても心配な%JG_NDA%JV_SIL_Rあれでも、家族だから。もし %name3% を見かけたら、家に戻るように伝えてほしい%JV_N%JV_DESU。>
		Msg8 <ありがとう。何か分かったら教えて%JV_KUDASAI……頼%JV_MIMASU。>
		Prompt1 <%name3% の居場所に心当たりは？>
		Prompt2 <%name3% が何をしようと関係ないんじゃ？>
		Prompt3 <できることを探してみ%JV_YOU。>
		Prompt4 <まだ調べてる%JV_F_WA。>

		Persona 3
		special <UNLISTED>
		Greeting <NewChat SayAnything>
	end


Content
	name <Losing my Inventory>
	% desc <A local mechanic is losing his repair parts. The PC may be able to help.>
	desc <地元のメカニックが修理用のパーツを失くしている。PC は手助けができるかもしれない。>
	requires <*:Q_SideStory>

	% E1 is the mechanic.
	% E2 is the scene for their shop
	Element1 <Prefab>
	Place1 <2 (Citizens) Pass Ally>
	Element2 <Scene Building (Garage|Spaceport) Public>

	% FAIL CONDITIONS:
	% - E1 dies
	end <ifNPCDead %1% LoseSubPlot %plotid%>

	update <ifSubPlotWon %plotid1% else .%id%_GoCheckLoss SetPlotStatus %plotid2% %id2%>
	.%id%_GoCheckLoss <ifSubPlotLost %plotid1% SetPlotStatus %plotid3% %id3%>

	% SubQuest1 is the search for the missing parts.
	% SubQuest2 is the reward for finding the parts.
	% SubQuest3 is the loss condition
	SubPlot1 <*:Q_StolenMaterials 1>
	SubPlot2 <*Q_WinTask 1>
	SubPlot3 <*Q_LoseTask 1>

	sub
		Persona 1
		% rumor%id% <%name1% doesn't have enough spare parts to keep the garage in business.>
		rumor%id% <修理用の部品が足りないせいで、%name1% の店は営業ができない>
		Greeting <if= PlotStatus %plotid% %id% else GoGreet if# PlotStatus %plotid1% 0 else GoCheckFirst NewChat Say 1 AddChat 1>
		GoCheckFirst <NewChat Say 2 AddChat 4 AddChat 5>
		*GoGreet <*NiceToMeetYou GoCheckClose>
		GoCheckClose <ifSubPlotLost %plotid% else GoRegularService NewChat Say 6>
		*GoRegularService <*SHOP_MECHA GoBye>
		*GoBye <*GOODBYE>
		Result1 <NewChat Say 3>
		result4 <Goto GoBye>
		result5 <NewChat Say 7 QMemo %plotid% 8 SetPlotStatus %plotid1% %id1% AddChat 7>
		result7 <NewChat Say 9>
		% Msg1 <Have you found out what happened to all my missing repair parts yet?>
		% Msg2 <I usually do service on all kinds of machine. I also sell a variety of new mecha and replacement parts.>
		% Msg3 <Three hundred tons of salvage doesn't just disappear... It's got to be around this place somewhere.>
		% Msg4 <That's fantastic news! I'll be able to re-open my shop shortly.>
		% Msg5 <That's serious bad news. My business can't afford a loss like that... I can't see any way to re-open the shop.>
		% Msg6 <The shop's closed.>
		% Msg6_1 <The shop's closed. The shop is always closed.>
		% Msg7 <Well, you see, that's a problem. I'm in a bit of a jam right now- all of my stock has gone missing. It seems likely that someone stole it, but then again it seems unlikely that anyone would steal 300 tons of scrap metal.>
		% Msg8 <%name1% in %name2% had to close \PPR %1% garage because all of \PPR %1% stock went missing.>
		% Msg9 <It'd be great if you could. Without those parts, I won't be able to stay in business.>
		% Prompt1 <No, I haven't.>
		% Prompt4 <Thanks, but I don't need anything now.>
		% Prompt5 <Let me see what you have.>
		% Prompt7 <I could try to find it for you.>
		% Msg4 と Msg5 が使われてない。
		Msg1 <ウチの在庫がどこに消えたか、何か手がかりは掴めた%JG_KANA？>
		Msg2 <ここでは機械ならだいたい何でも扱ってる%JG_YO。新品のメックとか、交換用のパーツなんかも売ってる%JG_YO。>
		Msg3 <300トン分の機械がいきなり消えたりするはずはない%JV_F_WA……この辺りのどこかにあるはず%JG_DAYO。>
		Msg4 <素晴らしいニュース%JG_DAYO！ これですぐに営業が再開できる%JG_YO。>
		Msg5 <最悪%JG_DANE。そんな損失、取り戻せるはずがない%JV_F_WA……もう店を再開するのは無理%JG_DAYO。>
		Msg6 <この店は閉店した%JG_YO。>
		Msg6_1 <この店は閉店してる%JG_YO%JV_SIL_Rずっと閉店したまま%JG_DAYO。>
		Msg7 <ええと、それが、ちょっと問題があって。在庫の部品が全部消えてしまって、どうしようもなくなってる%JG_NDA。きっと盗まれたと思ってはいるんだ%JG_GA、でも300トンはあるスクラップを盗むなんてどう考えてもおかしくて……。>
		Msg8 <%name2% の %name1% は、在庫の商品が突然消えたために閉店せざるを得なくなっている。>
		Msg9 <そうしてもらえるとありがたい。あの在庫がなかったら、とても商売が続けられない%JG_YO。>
		Prompt1 <%JR_NO、まだ。>
		Prompt4 <ありがとう、でも今のところ必要なものはない%JV_F_WA。>
		Prompt5 <商品を見せてほしい。>
		Prompt7 <何とか探してみ%JV_YOU。>

		MetaScene 1
		sub
			room
			name <Mecha Shop>
			name_I18N <メック店>
			ShowNAME <true>
			minimap <..............1.....&---!>
			special <SHAREDPALETTE>
			desig <HOME>
		end
	end
	inv
		NPC Mechanic
		CharDesc Easygoing
	end


%%
%%  *:Q_DEBUG
%%
%%  This quest will load a debug side story and activate it.
%%

Content
	name <Debugging Frame>
	requires <*:Q_DEBUG>
	update <if= V1 0 V= 1 1 SetPlotStatus %plotid1% %id1%>
	subplot1 <*:Q_DSideStory>

