%% *:CS_MechaEncounter Content
%%
%%	&Raiders	The enemies are raiders aligned with the enemy NPC/Faction
%%	&Secondary	This is a secondary encounter
%%
%% This is the basic building block of any adventure- a mecha fight scene.
%% This component will likely alter the context of the core story.
%%
%% The parent plot sets the plot status to this layer's ID when ready.
%%
%% When this subplot concludes, it sets one of the following triggers:
%%  .%id%_%plotid%_GoWin
%%  .%id%_%plotid%_GoLoss
%% It will also hide the encounter with SetEncounterInactive.
%%
%% This is a MAIN COURSE subplot.
%%
%%  Param1: The outdoors scene where the encounter will be placed
%%  Param2: The encounter to be used as the entrance
%%

Content
	name <Warned About You>
	% desc <Discover your new enemy faction.>
	desc <新たな敵勢力が明らかになる。>
	requires <*:CS_MechaEncounter ~&Raiders E:++ P:++ ~P:PCFAC F:-- ~E:A.nme ~E:A.jr_ ~E:A.sr_ ~E:A.equ ~E:A.env>
	changes <F:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the new enemy faction
	% E4 is the enemy fighter
	% E5 is the Enemy NPC, for safe keeping
	Element3 <Faction !Enemy -3 !Okay -1>
	Element4 <Prefab>
	Place4 <2 (Enemies) sd enemy>
	Element5 <Grab 1>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %4% StoryDL  SetNPCFaction %4% %3%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	%% Debriefing Message - Win or Lose
	% Msg%id%11 <%name5% is working for %name3%... at least we now know what we're up against.>
	Msg%id%11 <%name5% は %name3% の目的のために動いている%JV_F_WA……少なくともこれで、敵の正体が分かったわけ%JV_M_DA%JV_F_NE。>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 4 ForceChat %4%  History 1 &SetEnemyFac %3%  SetXXRAttitude %4% XXR_A_Antagonistic  CancelSubPlot %plotid1%  SetDebriefing %id%11  if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%  ifNPCOK %4% FreezeNPC %4%>

		% Msg1 <You fought %name4%, who revealed \PERSONA &EnemyNPC works for %name3%.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated %name4%'s lance.>
		% Msg4 <You face a strike team led by %name4% of %name3%.>
		Msg1 <%name4% と戦い、\PERSONA &EnemyNPC が %name3% のために動いていることを突き止めた。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <%name4% の部隊を打ち倒した。>
		Msg4 <%name3% の %name4% に率いられた襲撃部隊と対峙した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %3%   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 70>
			GoSmallDeploy <WMecha 2 StoryDL 30>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 65>
			ParaX 10
			ParaY 5
		end

		Persona 4
		special <UNLISTED>
		greeting <if= PlotStatus %plotid% %id% else %pop% Goto GoGreet>
		GoGreet <EndChat Say %id%01 AddChat %id%01 AddChat %id%02>
		*GoThemeExpo <*THEME_EXPO&Enemy na>
		result%id%01 <Goto GoThemeExpo>
		result%id%02 <Goto GoThemeExpo>
		% Msg%id%01 <You must be \PC . %name5% warned us that you've been a constant irritation... Let's see if I can succeed where \SPR %5% failed.>
		% Msg%id%01_1 <You must be \PC . I understand that %name5% is looking forward to defeating you... Let's see if I can rob \OPR %5% of that pleasure.>
		% CMsg%id%01_1 <ifNPCAttitude %5% XXR_A_NeverMet Accept>
		% Msg%id%01_2 <You must be \PC . %name5% claims that you're a major threat... Of course, \SPR %5% is kind of a loser. I guess I'm going to have to find out for myself.>
		% CMsg%id%01_2 <ifNPCAttitude %5% XXR_A_IsJunior Accept>
		% Msg%id%01_3 <You must be \PC . %name5% warned us that you've been a minor irritant... It should be no problem for me to defeat you.>
		% CMsg%id%01_3 <ifNPCAttitude %5% XXR_A_IsSenior Accept>
		% Msg%id%01_4 <You must be \PC . %name5% warned us that you are a formidible threat... Let's see if I can succeed where \SPR %5% failed.>
		% CMsg%id%01_4 <ifNPCAttitude %5% XXR_A_IsEqual Accept>
		% Msg%id%01_5 <You must be \PC . I don't know what you've done, but you really got under %name5%'s skin... Killing you should be worth an easy promotion.>
		% CMsg%id%01_5 <ifNPCAttitude %5% XXR_A_EnviesPC Accept>
		% Prompt%id%01 <You're welcome to try.>
		% Prompt%id%01_1 <Sure. I've got enough whoop-ass to go around.>
		% Prompt%id%02 <Underestimate me at your own risk.>
		% Prompt%id%02_1 <It's your funeral.>
		Msg%id%01 <%JS_AGGが \PC %JV_M_DA%JV_NA。%JS_AGGが小賢しく邪魔を続けていると %name5% から聞いている%JV_ZO……あれに失敗を与えたという腕前、見せてもら%JV_OUか%JV_SIL。>
		Msg%id%01_1 <%JS_AGGが \PC %JV_M_DA%JV_NA。%name5% は%JS_AGGを叩きのめすのを楽しみにしてるようだ%JG_GA……その楽しみ、奪わせてもらう%JV_ZO。>
		CMsg%id%01_1 <ifNPCAttitude %5% XXR_A_NeverMet Accept>
		Msg%id%01_2 <%JS_AGGが \PC %JV_M_DA%JV_NA。%name5% は%JS_AGGが重大な脅威だと主張してる%JG_GA……所詮、奴は負け犬%JG_DA。%JF2自身の目で確かめさせてもらう%JV_ZO。>
		CMsg%id%01_2 <ifNPCAttitude %5% XXR_A_IsJunior Accept>
		Msg%id%01_3 <%JS_AGGが \PC %JV_M_DA%JV_NA。%name5% は%JS_AGGが些細な障害だと主張していた%JG_GA……%JF2なら問題なく勝てる相手%JV_DAROUよ。>
		CMsg%id%01_3 <ifNPCAttitude %5% XXR_A_IsSenior Accept>
		Msg%id%01_4 <%JS_AGGが \PC %JV_M_DA%JV_NA。%name5% は%JS_AGGが厄介な相手だと警告していた%JG_GA……あれに失敗を与えたという腕前、見せてもら%JV_OUか%JV_SIL。>
		CMsg%id%01_4 <ifNPCAttitude %5% XXR_A_IsEqual Accept>
		Msg%id%01_5 <%JS_AGGが \PC %JV_M_DA%JV_NA。一体何をやらかしたのか知らない%JG_GA、相当に %name5% の面子を潰したらしい%JV_F_WA%JV_NA……%JS_AGGを殺れば、昇進は簡単%JV_DAROUよ。>
		CMsg%id%01_5 <ifNPCAttitude %5% XXR_A_EnviesPC Accept>
		Prompt%id%01 <やってみるといい%JV_F_WA。>
		Prompt%id%01_1 <そう%JV_KA_Q、なら好きなだけ弾を喰らっていくといい%JV_F_WA。>
		Prompt%id%02 <侮りたければ、自己責任で%JV_NA。>
		Prompt%id%02_1 <ここが%JS_AGGの墓場%JG_DAYO。>
	end
	inv
		NPC Mecha Pilot
	end

Content
	name <Plague of Bandits>
	size 8
	% desc <Defend an allied cruiser from bandits; find out this has been happening quite often.>
	desc <味方の船を賊から守り、そのような事件が多発していることを知る。>
	requires <*:CS_MechaEncounter F:CRIME F:P.--- -C:THIEF>
	changes <F:P>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is a local public scene
	% E4 is a trucker to be used in the exposition
	Element3 <Scene Public !Near -7>
	Element4 <Character Trucker !Okay -3 !XClude -2 !Near 3 NeverFail>
	NeverFail4 <Trucker>
	Place4 </>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	% Msg%id%11 <I'm glad %name4% got away safely. Something needs to be done about these bandits...>
	% Msg%id%11_1 <Something needs to be done about \FACTION &EnemyFac ... They've been stepping up their attacks.>
	% CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>
	Msg%id%11 <%name4% が無事で何よりだった%JV_F_WA。あの賊どもには対処が必要%JG_DA%JV_SIL_R。>
	Msg%id%11_1 <\FACTION &EnemyFac を何とかしないと……奴らは攻撃の手を強めている%JV_F_WA。>
	CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Decimation&Reinforcements>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  History 2  Monologue %4% 7  SetXXRPlot &EnemyFac XXR_P_PublicAttack  CancelSubPlot %plotid1% if# P%id%02 0 Alert 6>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1 Alert 3 History 4 Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1 ifG T3 0 else GoLoseMission  Alert 5  SetDebriefing %id%11  XPV 100  Salvage  Return  Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		GoLoseMission <Alert 4 History 4 Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		end <SetEncounterInactive %2%   MoveNPC %4% %3%>
		% Msg1 <You find a cargo ship under attack by bandits. Its captain, %name4%, contacts you.>
		% Msg2 <You found a cargo ship under attack by bandits.>
		% Msg3 <Without your protection, the cargo ship quickly falls to the bandits.>
		% Msg4 <You failed to protect the cargo ship.>
		% Msg5 <With the bandits gone, %name4% continues safely to \PPR %4% destination.>
		% Msg6 <Your reinforcements are here, as promised.>
		% Msg7 <I could use some help dealing with these raiders- it seems that lately we've been getting far more attacks than usual.>
		Msg1 <賊に襲われている貨物船を発見した。その船長、%name4% からあなたに通信が届いた。>
		Msg2 <賊に襲われている貨物船を発見した。>
		Msg3 <あなたの支援が得られなかったことで、貨物船はすぐに賊の手に落ちた。>
		Msg4 <貨物船を守ることができなかった。>
		Msg5 <賊を撃退し、%name4% は安全に目的地へと航行していった。>
		Msg6 <味方の援軍が到着した。>
		Msg7 <この賊を片付けるのに手を貸してもらいたい%JV_F_WA──このところ、襲撃が今までになく増加している%JG_NDA。>

		sub
			team 1
			SetEnemy 2
			SetAlly 3 4
			ParaX 15
			ParaY 25

			team 2
			SetEnemy 1 3 4
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 180>
			GoSmallDeploy <WMecha 2 StoryDL 100>
			ParaX 45
			ParaY 25

			team 3
			name <Cruiser Team>
			setenemy 2
			setally 1 4

			team 4
			name <Allies>
			setenemy 2
			setally 1 3
			home <Cruiser Zone>
			Deploy <if= PlotStatus %plotid% %id% if# p%id%02 0  WMecha 4 StoryDL 80>

			rect
			name <Cruiser Zone>
			special <SubZone>
			width 12
			height 12
			MFX 1
			MFY 19
			sub
				SuperProp
				requires <*Cruiser>
				SetTeam 3
			end
		end
	end

Content
	name <Capture Weapons Shipment>
	size 7
	% desc <Capture an enemy cruiser, learn they're working on a weapons program.>
	desc <敵の船を制圧し、彼らが新兵器の開発に取り組んでいることを知る。>
	requires <*:CS_MechaEncounter &Raiders (F:P.---|F:P.pat) -!Ne -!Lo>
	changes <F:P>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter

	% P%id%01 = Initialization Counter
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	%%  Debriefing Msg - Found weapons shipment
	% Msg%id%11 <You say they had some prototype mecha? This can't possibly be good...>
	% Msg%id%11_1 <So \FACTION &EnemyFac has started an advanced weapons program? This is really not good news...>
	% CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>
	Msg%id%11 <奴らがプロトタイプのメックを持っていたと？ また面倒なことになりそう%JV_M_DA%JV_NA……。>
	Msg%id%11_1 <では、\FACTION &EnemyFac が新兵器の開発を始めていると？ 良いニュースだとは言えない%JV_F_WA%JV_NA……。>
	CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  CancelSubPlot %plotid1%>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1 Alert 2 History 3 Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   ifG T3 0 else GoCheckWin  Alert 4 WMecha 2 StoryDL 70>
		GoCheckWin <if= V1 0 V= 1 1   ifG T4 0 else GoLoseEncounter XPV 100  AddRenown 1   Alert 5 History 6 CustomMecha .mek StoryDL SetDebriefing %id%11  SetXXRPlot &EnemyFac XXR_P_WeaponProgram   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		.mek <GENERAL \FACTION_DESIG &EnemyFac>
		GoLoseEncounter <Alert 2 History 3 Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You discover your enemies escorting a cruiser. If you capture the vessel by disabling its weapons and engines, you can find out what they're transporting.>
		% Msg2 <You failed to capture the enemy vessel.>
		% Msg3 <You encountered an enemy cruiser, but failed to capture it.>
		% Msg4 <Reinforcements arrive!>
		% Msg5 <You capture the enemy vessel. You find that they were transporting a prototype mecha.>
		% Msg6 <You captured an enemy vessel and their prototype mecha.>
		Msg1 <輸送艦を護衛しているの敵勢力を発見した。あの艦を無力化させて制圧すれば、何を運んでいるのか調べられるだろう。>
		Msg2 <敵艦に逃げられた。>
		Msg3 <敵の輸送艦に遭遇したが、その制圧に失敗した。>
		Msg4 <敵の増援が現れた！>
		Msg5 <敵艦を制圧した。輸送されていたのは試作型のメックだった。>
		Msg6 <敵の輸送艦を制圧し、中にあったプロトタイプのメックを手に入れた。>

		sub
			team 1
			SetEnemy 2 3
			ParaX 45
			ParaY 25

			team 2
			SetEnemy 1
			SetAlly 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 150>
			GoSmallDeploy <WMecha 2 StoryDL 70>
			home <Enemy Zone>

			team 3
			setenemy 1
			setally 2

			team 4
			name <Neutral Bitz>

			rect
			name <Enemy Zone>
			special <SubZone>
			width 12
			height 12
			MFX 1
			MFY 19
			sub
				SuperProp
				requires <*Cruiser>
				Team1 4
				Team2 3
				Team3 3
			end
		end
	end


Content
	name <Enemy Faction Revealed>
	size 6
	% desc <Fight some mecha and find out who they work for.>
	desc <メック部隊と交戦し、その雇い主を探る。>
	requires <*:CS_MechaEncounter &Raiders F:-- (!Ne|!Lo|&Secondary)>
	changes <F:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the new enemy faction
	Element3 <Faction ArchEnemy !Okay -1 !XClude -3>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	%%  Debriefing Msg
	% Msg%id%11 <So the raiders we've been fighting work for %name3%...>
	% Msg%id%11_1 <So \PERSONA &EnemyNPC 's raiders were actually sent by %name3%...>
	% CMsg%id%11_1 <ifNPCOK &EnemyNPC Accept>
	Msg%id%11 <つまり、今までの賊は %name3% の手の者だったというわけ%JV_KA_Q%JV_F_NE……。>
	Msg%id%11_1 <つまり、\PERSONA &EnemyNPC の一味は %name3% によって送り込まれたというわけ%JV_KA_Q%JV_F_NE……。>
	CMsg%id%11_1 <ifNPCOK &EnemyNPC Accept>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  History 2 &SetEnemyFac %3%  SetDebriefing %id%11  CancelSubPlot %plotid1% if# P%id%02 0 Alert 3>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1 Alert 4 Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 5   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You locate the raiders.>
		% Msg2 <You discovered that your enemy was working for %name3%.>
		% Msg3 <Your reinforcements are here, as promised.>
		% Msg4 <You were defeated by the raiders. There can be no doubt that they are working for %name3%.>
		% Msg5 <You have defeated the raiders. There can be no doubt that they are working for %name3%.>
		Msg1 <賊の居場所を突き止めた。>
		Msg2 <敵が %name3% の手先であることを突き止めた。>
		Msg3 <味方の援軍が到着した。>
		Msg4 <賊に敗れた。彼らが %name3% の手先であることに疑いの余地はない。>
		Msg5 <賊を倒した。彼らが %name3% の手先だったことに疑いの余地はない。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %3%   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 150>
			GoSmallDeploy <WMecha 2 StoryDL 90>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end
	end

Content
	name <Defend The Prototype>
	size 10
	% desc <You find your enemies transporting a prototype weapon.>
	desc <敵がプロトタイプの兵器を輸送していることを知る。>
	requires <*:CS_MechaEncounter F:P.pat -!Ne>
	changes <F:P>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoDecimation     <P= %id%02 1>

	%%  Debriefing Msg
	% Msg%id%11 <You say that they were testing a weapons platform? Talk about bad news...>
	Msg%id%11 <奴らが新たな武器を開発していると？ 悪いニュース%JV_M_DA%JV_F_NE……。>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  TeamMonologue 2 2   SetXXRPlot &EnemyFac XXR_P_WeaponProgram  SetDebriefing %id%11   CancelSubPlot %plotid1%>
		nu1 <if= T1 0   Return   if= L1 0  L= 1 1  ifG T3 0 else GoWinMission Goto GoLoseMission>
		nu2 <if= T2 0   if= T3 0   if= L1 0   L= 1 1  Goto GoWinMission>
		nu3 <if= T2 0   if= T3 0   if= L1 0   L= 1 1  Goto GoWinMission>
		GoWinMission  <Alert 4 History 5   XPV 100  SALVAGE  AddRenown 1   Trigger0 .%id%_%plotid%_GoWin   WinSubPlot %plotid%>
		GoLoseMission <Alert 6 History 7                                   Trigger0 .%id%_%plotid%_GoLoss  LoseSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You locate your enemies. They appear to be escorting a large vehicle of some type.>
		% Msg2_1 <Defend the prototype! It must be protected, at all costs!>
		% Msg2_2 <>
		% Msg2_3 <>
		% Msg3 <You discovered that your enemy was working for %name3%.>
		% Msg4 <The prototype weapon has been destroyed. You wonder how many more of these things they might be working on.>
		% Msg5 <You fought and destroyed an experimental weapon.>
		% Msg6 <You shudder to think what will happen if this prototype should enter general production.>
		% Msg7 <You failed to destroy an experimental weapon.>
		Msg1 <敵の一団を発見した。大型の乗り物か何かを護衛しているようだ。>
		Msg2_1 <プロトタイプを守る%JG_NDA！ どんな犠牲を払ってでも、必ず%JV_M_DA！>
		Msg2_2 <>
		Msg2_3 <>
		Msg3 <敵が %name3% の手先であることを突き止めた。>
		Msg4 <試作型の武器は破壊された。こんなものがあとどれだけ作られているのだろう？>
		Msg5 <試作型の新兵器と交戦し、破壊した。>
		Msg6 <あの武器が量産された時に起こることを考えると、身が震えた。>
		Msg7 <試作型の新兵器を破壊することに失敗した。>

		sub
			team 1
			SetEnemy 2 3
			ParaX 5
			ParaY 10

			team 2
			name <Mecha Forces>
			SetEnemy 1
			SetAlly 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%02 0 else GoSmallDeploy WMecha 2 StoryDL 120>
			GoSmallDeploy <WMecha 2 StoryDL 70>
			ParaX 40
			ParaY 40

			Team 3
			name <Prototype>
			SetAlly 2
			SetEnemy 1
			ParaX 45
			ParaY 45

			rect
			name <Enemy Zone>
			special <SubZone>
			width 5
			height 5
			MFX 40
			MFY 40
			sub
				SuperProp
				requires <*Superweapon>
				SetTeam 3
			end

		end
	end


Content
	name <Prototype Field Test>
	size 10
	% desc <You find your enemies transporting a prototype weapon. Again.>
	desc <敵がプロトタイプの兵器を輸送していることを知る。また。>
	requires <*:CS_MechaEncounter F:P.wep &Secondary>
	changes <F:P>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained decimation
	% P%id%03 = Have gained reinforcements
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoDecimation     <P= %id%02 1>
	.%id1%_%plotid1%_GoReinforcements <P= %id%03 1>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Decimation&Reinforcements>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  TeamMonologue 2 2  History 3   CancelSubPlot %plotid1%>
		nu1 <if= T1 0   Return   if= L1 0  L= 1 1  ifG T3 0 else GoWinMission Goto GoLoseMission>
		nu2 <if= T2 0   if= T3 0   if= L1 0   L= 1 1  Goto GoWinMission>
		nu3 <if= T2 0   if= T3 0   if= L1 0   L= 1 1  Goto GoWinMission>
		GoWinMission  <Alert 4 History 5   XPV 100  SALVAGE  AddRenown 1   Trigger0 .%id%_%plotid%_GoWin   WinSubPlot %plotid%>
		GoLoseMission <Alert 6 History 7                                   Trigger0 .%id%_%plotid%_GoLoss  LoseSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You locate the raiders. They appear to be escorting a large vehicle of some type.>
		% Msg2_1 <We're being attacked... This will make the perfect field test for our new weapon!>
		% Msg2_2 <>
		% Msg2_3 <>
		% Msg3 <You found your enemies field testing a prototype weapon.>
		% Msg4 <You destroyed the weapon.>
		% Msg5 <You destroyed the prototype.>
		% Msg6 <You shudder to think what will happen if this prototype should enter general production.>
		% Msg7 <You failed to destroy the prototype.>
		Msg1 <敵の一団を発見した。大型の乗り物か何かを護衛しているようだ。>
		Msg2_1 <敵襲%JG_DA%JV_SIL_R実戦試験にはもってこいの機会%JV_M_DA%JV_NA！>
		Msg2_2 <>
		Msg2_3 <>
		Msg3 <敵が新兵器の実地試験を行っているのを発見した。>
		Msg4 <敵の武器を破壊した。>
		Msg5 <試験中だった新兵器を破壊した。>
		Msg6 <あの武器が量産された時に起こることを考えると、身が震えた。>
		Msg7 <試験中だった新兵器を破壊することに失敗した。>

		sub
			team 1
			SetEnemy 2 3
			SetAlly 4
			ParaX 5
			ParaY 10

			team 2
			name <Mecha Forces>
			SetEnemy 1 4
			SetAlly 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%02 0 else GoSmallDeploy WMecha 2 StoryDL 100>
			GoSmallDeploy <WMecha 2 StoryDL 60>
			ParaX 40
			ParaY 40

			Team 3
			name <Prototype>
			SetAlly 2
			SetEnemy 1 4
			ParaX 45
			ParaY 45

			Team 4
			name <Allies>
			SetAlly 1
			SetEnemy 2 3
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%03 0   WMecha 4 StoryDL 60>
			ParaX 10
			ParaY 5

			rect
			name <Enemy Zone>
			special <SubZone>
			width 5
			height 5
			MFX 40
			MFY 40
			sub
				SuperProp
				requires <*Superweapon>
				SetTeam 3
			end

		end
	end


%%  *******************************
%%  ***   CHOOSE  YER  POISON   ***
%%  *******************************
%%
%% A special sub-class of mecha encounters in which the PC is introduced to the
%% hometown's primary antagonists. Generally, the player will then be able to
%% decide which faction is going to become the core story enemy.

Content
	name <Choose Yer Poison FCOMS>
	% desc <Two pirate forces are fighting. Pick whichever one you think started it.>
	desc <２つの海賊勢力が戦っている。どちらが先に手を出したのか当てよう。>
	requires <*:CS_MechaEncounter L:FCOMS F:-- (L:Ally|P:--) -L:Enemy ~*CORE_INTRO ~*CORE_OFF_>
	changes <F:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is one pirate team
	% E4 is the other one
	% E5 is the Pirate with whom the PC will speak
	Element3 <Faction (REDMA|CRIHN) -PCFAC>
	Element4 <Faction (REDMA|CRIHN) !Enemy 3 -PCFAC>
	Element5 <Prefab>
	Place5 <2 (Enemies1) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have E3
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %5% StoryDL SetNPCFaction %5% %3%>

	% You can get reinforcements, but no decimation.
	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>

	%%  Debriefing Msg - Fight E3
	Msg%id%11 <>

	%%  Debriefing Msg - Fight E4
	Msg%id%12 <>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1 ForceChat %5%  CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return    if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid% History 4 if= P%id%03 1  SetXXRAttitude %5% XXR_A_IsSenior>
		nu2 <if= T2 0  if= T4 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid% if= P%id%03 1  SetXXRAttitude %5% XXR_A_IsJunior>
		nu4 <Goto nu2>
		end <SetEncounterInactive %2% ifNPCOK %5% FreezeNPC %5%>

		% Msg1 <You find two groups of pirates fighting. One team bears the colors of the Red Mask Raiders, the other the Blades of Crihna.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated the mecha.>
		% Msg4 <You were defeated.>
		Msg1 <２つの海賊勢力が砲火を交えているのを発見した。片方は Red Mask Raiders、もう片方は Blades of Crihna のようだ。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <敵メックに勝利した。>
		Msg4 <戦いに敗れた。>

		sub
			team 1
			setally 3
			SetEnemy 2 4
			ParaX 5
			ParaY 10

			team 2
			name <Enemies1>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %3%   WMecha 2 StoryDL 80>
			ParaX 40
			ParaY 45

			team 3
			setally 1
			setenemy 2 4
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5

			team 4
			name <Enemies2>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %4%   WMecha 4 StoryDL 150>
			ParaX 45
			ParaY 40
		end

		Persona 5
		special <UNLISTED NOESCAPE>
		greeting <if= PlotStatus %plotid% %id% else %pop%  EndChat Say %id%01 AddChat %id%01 AddChat %id%02 if= v%id%01 0 v= %id%01 1 History %id%02>
		result%id%01 <EndChat Say %id%03 AddChat %id%03 AddChat %id%04>
		result%id%02 <EndChat Say %id%04 AddChat %id%03 AddChat %id%04>
		result%id%03 <EndChat Say %id%05 History %id%06 Retreat 2 &SetEnemyFac %4% PCFEnemy %4% SetDebriefing %id%12 AddReact d10 SetXXRAttitude %5% XXR_A_IsEqual>
		result%id%04 <EndChat Say %id%07 History %id%08 Retreat 4 &SetEnemyFac %3% PCFEnemy %3% SetDebriefing %id%11 P= %id%03 1  if= 0 &EnemyNPC &SetEnemyNPC %5%>
		result%id%05 <Goto result%id%03>
		result%id%06 <Goto result%id%04>
		% Msg%id%01 <This is %name5% of %name3%. You're not a member of %name4%... get the blazes out of here before I'm forced to hurt you.>
		% Msg%id%02 <You found two groups of pirates fighting.>
		% Msg%id%03 <We weren't looking for any trouble, just passing through, when all of a sudden that lot jumped us like they owned the place. I mean, we had to fight back, right?>
		% Msg%id%04_1 <Look, I'm a small time crook and I admit it, but those Blades are up to something bigger than that... They've been hunting down our guys in \SCENE RootSceneID , taking full control of all the crime that goes on here.>
		% CMsg%id%04_1 <if= ChatNPCFac REDMA Accept>
		% Msg%id%04_2 <It's the Masks who started it! I'm a smuggler, not a fighter- these guys have already made it dangerous to work the dusty ring, and now they've expanded all the way to the spinners!>
		% CMsg%id%04_2 <if= ChatNPCFac CRIHN Accept>
		% Msg%id%05_1 <If word gets out that I ran from a fight, the Queen'll have my hide... Still, I'd rather risk that than die right now. Good luck, \PC !>
		% CMsg%id%05_1 <if= ChatNPCFac REDMA Accept>
		% Msg%id%05_2 <Y'know, we used to be the most feared pirate fleet in the solar system, and now we can't even protect our own... Good luck, \PC !>
		% CMsg%id%05_2 <if= ChatNPCFac CRIHN Accept>
		% Msg%id%06 <You sent %name5% away, and fought %name4%.>
		% Msg%id%07_1 <Hey, look what you did- while you were talking, those stinking Blades got away! I'm not going home until I kick someone's arse... Let me show you my \CHATNPCMECHA !!!>
		% CMsg%id%07_1 <if= ChatNPCFac REDMA Accept>
		% Msg%id%07_2 <You doubt my pirate honor!? The Red Masks can wait for another day... for right now, my quarry is you!!!>
		% CMsg%id%07_2 <if= ChatNPCFac CRIHN Accept>
		% Msg%id%08 <You fought %name5% of %name3%.>
		% Prompt%id%01 <What's going on here?>
		% Prompt%id%01_1 <Tell me what you're doing here.>
		% Prompt%id%02 <I'm responding to a disturbance. I guess that's you.>
		% Prompt%id%02_1 <And miss a good fight? Not likely.>
		% Prompt%id%03 <Get out of here. I'll deal with them.>
		% Prompt%id%03_1 <You get out of here, I'll deal with it.>
		% Prompt%id%04 <Your story sounds fishy. What are you really up to?>
		% Prompt%id%04_1 <I don't believe you.>
		Msg%id%01 <こちらは %name3% の %name5% 。%JS_AGGは %name4% と無関係な人間%JG_DA%JV_SIL_R撃たれる羽目になる前に、さっさとここから離脱する%JV_N%JV_M_DA%JV_NA。>
		Msg%id%02 <２つの海賊団が戦っているのを発見した。>
		Msg%id%03 <モメ事を起こしに来たんじゃない%JV_ZO……ただここを通っていただけなのに、奴らが縄張りを荒らされた犬みたいに襲ってきた%JG_NDA。それなら戦うしかない%JV_DAROU、違う%JV_KA_Q？>
		Msg%id%04_1 <%JR_HEY、%JF2は確かにコソ泥かもしれない%JG_GA%JV_NA、あの Blades どもはもっとヤバいことをしようとしてる%JG_NDA%JV_SIL_R奴らは \SCENE RootSceneID で%JF2%JF_TACHIの仲間を殺して、自分たちがここの獲物を総取りにするつもりな%JG_SK。>
		CMsg%id%04_1 <if= ChatNPCFac REDMA Accept>
		Msg%id%04_2 <Red Mask の連中が仕掛けてきた%JG_NDA！ %JF2はただの運び人で、荒事屋じゃない%JV_F_WA……奴らはただでさえ Dusty Ring の仕事を危険にしてるってのに、とうとうコロニーにまで出張ってきた%JG_SK！>
		CMsg%id%04_2 <if= ChatNPCFac CRIHN Accept>
		Msg%id%05_1 <もし%JF2が戦いから逃げたなんて知れ渡ったら、Queen は絶対に刺客を差し向けてくる%JG_GA……それでも、今ここで死ぬよりはマシ%JV_KA_Q%JV_F_NE。達者で%JV_NA、\PC！>
		CMsg%id%05_1 <if= ChatNPCFac REDMA Accept>
		Msg%id%05_2 <ふん……昔は太陽系で最も恐れられた海賊団だったってのに、今じゃ自分の身も守れないとは%JV_NA。達者で%JV_NA、\PC！>
		CMsg%id%05_2 <if= ChatNPCFac CRIHN Accept>
		Msg%id%06 <%name5% を追い払い、%name4% と戦った。>
		Msg%id%07_1 <ああ、何て真似をしてくれた%JG_NDA%JV_SIL_R喋ってる間に Blades のクソどもに逃げられたじゃない%JV_KA_Q！ 誰かをブチのめさないと治まらない%JV_ZO……この \CHATNPCMECHA の力を見ていくがいい%JV_F_WA！！>
		CMsg%id%07_1 <if= ChatNPCFac REDMA Accept>
		Msg%id%07_2 <海賊の誇りを疑うの%JV_KA_Q？ Red Mask どもを狩るのはいつでも出来る%JG_NDA%JV_SIL_R先に%JS_AGGを片付けてやる%JV_F_WA！>
		CMsg%id%07_2 <if= ChatNPCFac CRIHN Accept>
		Msg%id%08 <%name3% の %name5% と戦った。>
		Prompt%id%01 <何が起こってる%JG_NDA？>
		Prompt%id%01_1 <ここで何をしている%JG_NDA。>
		Prompt%id%02 <邪魔者が話しかけてきてる%JV_F_WA%JV_NA……%JS_AGG%JV_KA_Q%JV_F_YO。>
		Prompt%id%02_1 <で、お楽しみを逃すの%JV_KA_Q？ 嫌%JG_DANE。>
		Prompt%id%03 <ここから去る%JG_NDA。あれの相手は%JF2がする。>
		Prompt%id%03_1 <帰るのは%JS2%JG_DAYO。残りの始末は%JF2が付ける。>
		Prompt%id%04 <嘘っぽい話%JG_DANE。本当の目的は何%JV_M_DA？>
		Prompt%id%04_1 <信用できない%JV_F_WA%JV_NA。>
	end
	inv
		NPC Pirate
	end

Content
	name <Choose Yer Poison RISHI>
	% desc <A lance of Silver Knights stand between you and some pirates.>
	desc <Silver Knights の一隊があなたと海賊との間に立ち塞がった。>
	requires <*:CS_MechaEncounter L:RISHI F:-- (L:Ally|P:--) -L:Enemy ~*CORE_INTRO ~*CORE_OFF_>
	changes <F:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the L5 Alliance
	% E4 is the Blades of Crihna
	% E5 is the Alliance pilot with whom the PC will speak
	Element3 <Faction MAQUI>
	Element4 <Faction CRIHN>
	Element5 <Prefab>
	Place5 <2 (Enemies1) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have challenged Aegis
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %5% StoryDL>

	% You can get reinforcements, but no decimation.
	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>

	%% Debriefing Message: PC fought Blades (win or lose)
	% Msg%id%01 <You made the right decision, those Blades were up to no good. They're getting bolder and bolder in their provocations... I wouldn't be surprised if they're planning another terror attack.>
	Msg%id%01 <%JS2は正しい選択をした%JV_F_WA……あの Blades たちは悪事を企んでいた%JV_N%JV_M_DA。奴らは日に日に増長を続けていく……もし次のテロ計画を立てていると聞かされても、%JF2は驚かない%JV_DAROU%JV_F_NE。>

	%% Debriefing Message: PC fought Knights (win or lose)
	% Msg%id%02 <What was %name5% doing close enough to Dominion space to respond to a distress call? So the Alliance has troops stationed on our border... They surely wouldn't be planning an attack, not with Kosaka Spinner watching.>
	Msg%id%02 <救難信号を拾えるほど Dominion の宙域に近い所で、%name5% は何をしてた%JG_DA%JV_SIL_R？ Alliance が我々の領域の境界に兵を置いているとして……まさか、Kosaka Spinner の目の前で攻撃作戦を始めたりはしないだろう%JG_GA。>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1 ForceChat %5%  CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return    if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid% History 4 if= P%id%03 1  SetXXRAttitude %5% XXR_A_IsSenior>
		nu2 <if= T2 0  if= T4 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid% if= P%id%03 1  SetXXRAttitude %5% XXR_A_IsJunior>
		nu4 <Goto nu2>
		end <SetEncounterInactive %2% ifNPCOK %5% FreezeNPC %5%>

		% Msg1 <You spot a group of pirates from the Blades of Crihna escorting an unmarked ship. Stationed between you and them, though, is a lance of Silver Knights.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated the mecha.>
		% Msg4 <You were defeated.>
		Msg1 <Blades of Crihna の海賊の一団が、所属不明の船を護衛しているのを発見した。そして、あなたと彼らとの間には、Silver Knights の一部隊がいる。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <敵メックに勝利した。>
		Msg4 <戦いに敗れた。>

		sub
			team 1
			setally 3
			SetEnemy 2 4
			ParaX 5
			ParaY 10

			team 2
			name <Enemies1>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction 3   WMecha 2 StoryDL 80>
			ParaX 40
			ParaY 45

			team 3
			setally 1
			setenemy 2 4
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5

			team 4
			name <Enemies2>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %4%   WMecha 4 StoryDL 150>
			ParaX 45
			ParaY 40
		end

		Persona 5
		special <UNLISTED NOESCAPE>
		greeting <if= PlotStatus %plotid% %id% else %pop%  EndChat Say %id%01 AddChat %id%01 AddChat %id%02 AddChat %id%08 if= v%id%01 0 v= %id%01 1 History %id%02>
		result%id%01 <EndChat Say %id%03 AddChat %id%03 AddChat %id%04 AddChat %id%07>
		result%id%02 <EndChat Say %id%04 AddChat %id%05 AddChat %id%06 AddChat %id%07>
		result%id%03 <EndChat Say %id%05 History %id%06 Retreat 2 &SetEnemyFac %4% PCFEnemy %4% SetDebriefing %id%01  AddReact -d10 SetXXRAttitude %5% XXR_A_Antagonistic>
		result%id%04 <EndChat Say %id%07 History %id%08 Retreat 4 &SetEnemyFac %3% PCFEnemy %3% SetDebriefing %id%02 P= %id%03 1>
		result%id%05 <Goto result%id%03>
		result%id%06 <Goto result%id%04>
		result%id%07 <EndChat Say %id%09 History %id%06 Retreat 2 &SetEnemyFac %4% PCFEnemy %4% SetDebriefing %id%01 AddLawful 1 AddReact d10 SetXXRAttitude %5% XXR_A_IsEqual>
		result%id%08 <EndChat Say %id%10 AddChat %id%03 AddChat %id%06 AddChat %id%07>
		% Msg%id%01 <Hold your fire. These Blades are escorting a civilian vessel; they did not come here to cause trouble.>
		% Msg%id%02 <You were blocked from some pirated by the Silver Knights.>
		% Msg%id%03 <We are simply responding to a distress call, as per F.C.S. dictate 5247 dash 9. The captain of the Bohemian ship told us that they're just passing through... I ask you one last time to stand down.>
		% Msg%id%04 <I have no evidence that these pilots are guilty of anything. How can you expect me to leave their ship defenseless? I ask you one last time to step down.>
		% Msg%id%05 <It appears that you won't listen to reason. Unfortunately, we have no standing to challenge you in Dominion space. I only pray that justice be served.>
		% Msg%id%06 <You sent %name5% away, and fought the Blades.>
		% Msg%id%07 <Was that a challenge? I guess we're now legally entitled to fight! I'll show you what my \CHATNPCMECHA can do.>
		% Msg%id%08 <You fought %name5%'s Alliance patrol.>
		% Msg%id%09 <So you know the law... and here I thought you were just some hotshot rocket spoiling for a fight. We will escort the ship back home ourselves. You can deal with the Blades as you see fit; I trust justice will be served.>
		% Msg%id%10 <We are merely responding to a distress call. The captain of this ship assures us they have done nothing wrong. As a Knight it's my duty to protect anyone who requests aid... I ask you one last time to stand down.>
		% Prompt%id%01 <They've invaded Dominion territory, as have you.>
		% Prompt%id%01_1 <What are the Silver Knights doing in Rishiri space?>
		% Prompt%id%02 <So they say. My sources report otherwise.>
		% Prompt%id%02_1 <Maybe the ship didn't, but those pirates did.>
		% Prompt%id%03 <And you believe that? Look, those pirates are wanted!>
		% Prompt%id%04 <I don't care about your dictates. Get out of the way, or else!>
		% Prompt%id%05 <Go escort the ship yourself. I have pirates to deal with.>
		% Prompt%id%06 <You're in no place to be making ultimatums, jerk.>
		% Prompt%id%07 <And by regulation 1314-5R, I'm asking you to step down.>
		% CPrompt%id%07 <ifG PCLaw -1 ifInsightKn SkillTar StoryDL Accept>
		% Prompt%id%08 <Wait, I thought you knights hated pirates!?>
		Msg%id%01 <武器を収めて%JG_R。あの Blades は民間の船を護衛しているだけ%JV_M_DA%JV_F_YO……悪さをするために来ているわけじゃない%JV_F_NO。>
		Msg%id%02 <海賊への攻撃を、Silver Knights によって邪魔された。>
		Msg%id%03 <%JF2%JF_TACHIは救難信号の下へ駆けつけただけ%JV_M_DA%JV_F_YO、F.C.S. 指令 5247-9 の定めによって%JV_NA。あの Bohemian の船の船長によれば、ただこの宙域を通過しているだけとのこと……もう一度だけ要請する%JV_ZO、武器を収めて%JG_R。>
		Msg%id%04 <あのパイロットたちが有罪であるとする証拠はない%JV_F_WA。あの船を丸腰で見送れとでも言うの%JV_KA_Q？ もう一度だけ要請する%JV_ZO、退去して%JG_R。>
		Msg%id%05 <話し合いに応じる意思はないよう%JG_DANE。残念だ%JG_GA、Dominion の宙域で戦いを挑む大儀は%JF2%JF_TACHIには無い%JV_F_WA……願わくば、正義が成されんことを。>
		Msg%id%06 <%name5% を追い払い、Blades と戦った。>
		Msg%id%07 <それは宣戦布告%JV_KA_Q？ それなら法的にも戦う正当性が生まれる……%JF2の \CHATNPCMECHA の力を見せてやる%JV_ZO！>
		Msg%id%08 <%name5% の率いる Alliance のパトロール隊と戦った。>
		Msg%id%09 <そちらも法を知っているの%JV_KA……ただ戦いを求めるだけの鉄砲玉だと思っていた%JV_Nだ%JG_GA。あの船は%JF2%JF_TACHIが無事に送り届けるから、%JS2は本来の仕事の通り Blades に対処するといい%JV_F_WA。正義が成されることを信じている%JV_ZO%JV_F_YO。>
		Msg%id%10 <%JF2%JF_TACHIはただ救難信号に対応しているだけ%JG_DA。あの船の船長は何も違法なことはないと証言している%JV_F_NO。救いを求める者すべてを守るのが、騎士としての%JF2の責務……もう一度だけ要請する%JV_ZO、退去して%JG_R。>
		Prompt%id%01 <彼らは Dominion の領域を侵犯している%JV_F_WA。%JS2も%JG_DA。>
		Prompt%id%01_1 <Rishiri の領域で Silver Knights が何をしている%JG_NDA？>
		Prompt%id%02 <そう%JV_KA_Q。こっちの報告では違うらしい%JG_GAね。>
		Prompt%id%02_1 <あの船がそうだとして、海賊は別%JG_DA。>
		Prompt%id%03 <で、それを信じると%JV_SIL？ あれは手配中の海賊%JG_DA！>
		Prompt%id%04 <そっちのルールは関係ない%JV_F_WA。そこを退くか……それとも？>
		Prompt%id%05 <なら自分たちであの船を護衛すればいい。こっちは海賊の相手をする%JV_F_WA。>
		Prompt%id%06 <最後通牒を突き付けられるような立場のつもりなの%JV_KA？ マヌケ%JV_M_DA%JV_NA。>
		Prompt%id%07 <なら、法令 1314-5R により、%JS2%JS_TACHIに退去を求める%JV_F_WA。>
		CPrompt%id%07 <ifG PCLaw -1 ifInsightKn SkillTar StoryDL Accept>
		Prompt%id%08 <何%JV_M_DA、Silver Knights は海賊の敵じゃなかったの%JV_KA_Q？>
	end
	inv
		NPC Knight
	end

Content
	name <Choose Yer Poison MAQUI>
	% desc <An Aegis strike team has chased pirates into Alliance space.>
	desc <Aegis の攻撃隊が海賊を追って Alliance の領空へ侵入した。>
	requires <*:CS_MechaEncounter L:MAQUI F:-- (L:Ally|P:--) -L:Enemy ~*CORE_INTRO ~*CORE_OFF_>
	changes <F:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the Aegis Space Force
	% E4 is the Red Mask Raiders
	% E5 is the Aegis pilot with whom the PC will speak
	Element3 <Faction AEGSF>
	Element4 <Faction REDMA>
	Element5 <Prefab>
	Place5 <2 (Enemies1) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have challenged Aegis
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %5% StoryDL SetNPCFaction %5% %3%>

	% You can get reinforcements, but no decimation.
	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>

	%%  Debriefing Msg - Fight Red Mask Raiders
	% Msg%id%11 <Can't blame %name5% for intruding. The Red Masks have been getting bolder and more powerful with each passing day... it seems like our best efforts do little more than slow them down.>
	Msg%id%11 <侵犯については、あまり %name5% を責められない%JV_F_WA%JV_NA。Red Masks は日に日に強さと横暴さを増している……%JF2%JF_TACHIの最大限の努力も、奴らをほんの少し食い止める程度の結果にしかなっていない%JV_F_WA。>

	%%  Debriefing Msg - Fight Aegis Space Force
	% Msg%id%12 <Chasing the pirates into our space was clearly just a ruse. Aegis Overlord thinks all the colonies should be ruled from Luna, though they wouldn't dare openly fight the Alliance... not yet, anyhow.>
	Msg%id%12 <海賊を追っていたというのは、間違いなくただの口実%JV_DAROU。Aegis Overlord はすべてのコロニーを支配下に置こうと考えている%JG_GA、それでも表立って Alliance と戦うつもりはない……今のところは、どうにか%JV_NA。>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1 ForceChat %5%  CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return    if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid% History 4 if= P%id%03 1  SetXXRAttitude %5% XXR_A_IsSenior>
		nu2 <if= T2 0  if= T4 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid% if= P%id%03 1  SetXXRAttitude %5% XXR_A_IsJunior>
		nu4 <Goto nu2>
		end <SetEncounterInactive %2% ifNPCOK %5% FreezeNPC %5%>

		% Msg1 <You spot a lance of pirates from the Red Mask Raiders being pursued by an Aegis strike team. Both groups of mecha are intruders in Alliance territory.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated the mecha.>
		% Msg4 <You were defeated.>
		Msg1 <Red Mask Raiders の海賊部隊が Aegis の攻撃隊に追われているのを発見した。どちらの集団も、Alliance の領域を侵犯している。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <敵メックに勝利した。>
		Msg4 <戦いに敗れた。>

		sub
			team 1
			setally 3
			SetEnemy 2 4
			ParaX 5
			ParaY 10

			team 2
			name <Enemies1>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %3%   WMecha 2 StoryDL 80>
			ParaX 40
			ParaY 45

			team 3
			setally 1
			setenemy 2 4
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5

			team 4
			name <Enemies2>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %4%   WMecha 4 StoryDL 150>
			ParaX 45
			ParaY 40
		end

		Persona 5
		special <UNLISTED NOESCAPE>
		greeting <if= PlotStatus %plotid% %id% else %pop%  EndChat Say %id%01 AddChat %id%01 AddChat %id%02 if= v%id%01 0 v= %id%01 1 History %id%02>
		result%id%01 <EndChat Say %id%03 AddChat %id%03 AddChat %id%04>
		result%id%02 <EndChat Say %id%04 AddChat %id%05 AddChat %id%06>
		result%id%03 <EndChat Say %id%05 History %id%06 Retreat 2 &SetEnemyFac %4% PCFEnemy %4% SetDebriefing %id%11 AddReact d10 SetXXRAttitude %5% XXR_A_IsEqual>
		result%id%04 <EndChat Say %id%07 History %id%08 Retreat 4 &SetEnemyFac %3% PCFEnemy %3% SetDebriefing %id%12 P= %id%03 1>
		result%id%05 <Goto result%id%03>
		result%id%06 <Goto result%id%04>
		% Msg%id%01 <This is %name5% of the Aegis Space Force. Those mecha attacked a Lunar trading vessel, and I will see them brought to justice.>
		% Msg%id%02 <You found some Red Mask Raiders being chased by the Aegis Space Force.>
		% Msg%id%03 <Aegis Overlord does not require your assistance. It is my sworn duty to protect our citizens and Lunar interests anywhere in the solar system.>
		% Msg%id%04 <I've sworn an oath to defend Luna from all enemies, both within and without. If you intend to stand between me and my prey then you are our enemy as well.>
		% Msg%id%05 <Very well. I'll trust you to deal with this.>
		% Msg%id%06 <You sent %name5% away, and fought the pirates yourself.>
		% Msg%id%07 <Do you think you can stop us? I'll give you a taste of my \CHATNPCMECHA !>
		% Msg%id%08 <You fought %name5%'s Aegis strike team.>
		% Prompt%id%01 <Why don't we fight them together, then you go back home?>
		% Prompt%id%01_1 <I understand. Why don't I help you out?>
		% Prompt%id%02 <Get out of Alliance space before I bring YOU to justice.>
		% Prompt%id%02_1 <You're an intruder here as well, you know.>
		% Prompt%id%03 <Not here, it isn't. Let me deal with the pirates.>
		% Prompt%id%04 <This isn't your space. Leave now, or else!>
		% Prompt%id%05 <This is my jurisdiction, I'll deal with the pirates!>
		% Prompt%id%06 <Oh yeah? Maybe I am your enemy, then!>
		Msg%id%01 <こちらは Aegis Space Force 所属の %name5% %JG_DA。あのメック部隊は、月の交易船を襲撃した罪でこれから裁かれる%JV_F_WA。>
		Msg%id%02 <Red Mask Raiders の一団が Aegis Space Force に追われているのを発見した。>
		Msg%id%03 <Aegis Overlord は%JS2の支援を必要としない。この太陽系のいかなる場所でも月の財産と市民を守るのが、%JF2の絶対の使命%JG_DA。>
		Msg%id%04 <%JF2は、どんな場所でもあらゆる敵から月を守ると誓った%JV_F_NO。獲物の前に立ちはだかるというのなら、%JS2も%JF2%JF_TACHIの敵と見なす%JV_F_WA。>
		Msg%id%05 <いい%JV_DAROU。正しい対処を期待している%JV_ZO%JV_SIL。>
		Msg%id%06 <%name5% を追い返し、自分の手で海賊と戦った。>
		Msg%id%07 <%JF2%JF_TACHIを止められると？ この \CHATNPCMECHA の力を味わっていくがいい%JV_F_WA！>
		Msg%id%08 <%name5% の率いる Aegis の攻撃隊と戦った。>
		Prompt%id%01 <なら一緒に戦うから、終わったら帰ってほしい。>
		Prompt%id%01_1 <了解した%JV_F_WA。なら手を貸してもいい%JV_DAROU？>
		Prompt%id%02 <Alliance の宙域から直ちに退去しなければ、裁かれるのは%JS_AGG%JG_DAYO。>
		Prompt%id%02_1 <そっちも侵入者だってのは分かってるよ%JV_NA？>
		Prompt%id%03 <ここでそういうのは無し%JV_M_DA%JV_F_YO。海賊にはこちらで対処する%JV_F_WA。>
		Prompt%id%04 <ここは月の縄張りじゃない%JV_F_NO。今すぐ去るか、それとも？>
		Prompt%id%05 <権限はこちらにある%JV_N%JV_M_DA。海賊の相手は%JF2がする！>
		Prompt%id%06 <ああそう%JV_KA_Q？ じゃあ、%JF2も%JS_AGGの敵な%JV_N%JV_M_DA%JV_NA！>
	end
	inv
		NPC Mecha Pilot
	end



%%  *******************
%%  ***   GENERAL   ***
%%  *******************

Content
	name <Our New Enemy Will Be Played By...>
	% desc <An existing character gets drawn in to become the new core story enemy.>
	desc <既存のキャラクタがメインストーリーの新たな敵として抜擢される。>
	requires <*:CS_MechaEncounter &Raiders E:-- F:++ -!Ne ~!Hi>
	changes <E:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the new enemy
	Element3 <Character HasMecha !Comrade -2 -Friend -Ally -Family -Lover>
	Place3 <2 (Enemies) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%  NPCLevel %3% StoryDL>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation <P= %id%03 1>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  ForceChat %3%   StoryNote 2 &SetENemyNPC %3%  CancelSubPlot %plotid1% if# P%id%02 0 Alert 3>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   Alert 4 History 6   LoseSubPlot %plotid% Trigger0 .%id%_%plotid%_GoLoss>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 7 WinSubPlot %plotid%  Trigger0 .%id%_%plotid%_GoWin>
		end <SetEncounterInactive %2% ifNPCDead %3% else GoFreeze Print 9 Goto GoFreeze>
		GoFreeze <FreezeNPC %3%>

		% Msg1 <You locate the group of raiders that you've been searching for. They are being led by %name3%.>
		% Msg2 <You fought %name3% of \FACTION &EnemyFac .>
		% Msg3 <Your reinforcements are here, as promised.>
		% Msg4 <You have been defeated by %name3%.>
		% Msg6 <%name3% defeated you.>
		% Msg7 <You defeated %name3%'s lance.>
		% Msg9 <%name3%'s cockpit is mysteriously empty. Could \SPR %3% have survived?>
		Msg1 <行方を追っていた賊の一団を発見した。%name3% によって率いられている。>
		Msg2 <\FACTION &EnemyFac の %name3% と戦った。>
		Msg3 <味方の援軍が到着した。>
		Msg4 <%name3% との戦いに敗れた。>
		% ラベル間違いを修正。
		Msg6 <%name3% との戦いに敗れた。>
		Msg7 <%name3% の部隊を撃退した。>
		Msg9 <奇妙にも、%name3% のコクピットはもぬけの殻だった。生き延びたのだろうか？>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= P%id%03 0 else GoSmall WMecha 2 StoryDL 80>
			GoSmall <WMecha 2 StoryDL 30>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		Persona 3
		special <UNLISTED>
		greeting <EndChat ifChatNPCKnown else .%id%_GoUnknownGreeting Say %id%01 AddChat %id%01 AddChat %id%02>
		*.%id%_GoUnknownGreeting <*BattleChallenge result%id%01 na>
		*result%id%01 <*THEME_EXPO&Enemy na>
		result%id%02 <AddEasygoing d8 Goto result%id%01>
		% Msg%id%01 <Hello \PC ... You've been interfering with \FACTION &EnemyFac for long enough. I've been ordered to take you out of the picture.>
		% Msg%id%01_1 <>
		% CMsg%id%01_1 <ifNPCHeroic Accept>
		% Msg%id%01_2 <So \PC , we meet again... You've been quite the pain to \FACTION &EnemyFac so they've asked me to get rid of you permanently.>
		% CMsg%id%01_2 <ifNPCVillainous Accept>
		% Prompt%id%01 <Tell your boss that I'm not going to back down.>
		% Prompt%id%01_1 <Didn't they tell you that I don't back down?>
		% Prompt%id%02 <I dunno if I'm ready for this kind of commitment...>
		% Prompt%id%02_1 <Guess we'll be seeing each other more often, then.>
		Msg%id%01 <ようこそ \PC ……%JS_AGGは \FACTION &EnemyFac に構いすぎたよう%JV_M_DA%JV_NA。%JF2は%JS_AGGを舞台から引き摺り下ろせと命じられて来た%JG_NDA。>
		Msg%id%01_1 <>
		CMsg%id%01_1 <ifNPCHeroic Accept>
		Msg%id%01_2 <\PC、また会った%JV_F_WA%JV_NA……%JS_AGGにずいぶんと痛手を負わされた \FACTION &EnemyFac から、その心配を永久に取り除いてほしいと頼まれた%JV_ZO。>
		CMsg%id%01_2 <ifNPCVillainous Accept>
		Prompt%id%01 <引き下がるつもりはないと、ボスに伝えてくるといい%JV_F_WA。>
		Prompt%id%01_1 <%JF2は引き下がったりしない、と聞かされなかったの%JV_KA_Q？>
		Prompt%id%02 <そういうお付き合いの申し込みはちょっと……ねえ？>
		Prompt%id%02_1 <それじゃ、これからちょくちょく会うことになる%JG_SY。>
	end

Content
	name <Let's See How You Measure Up>
	% desc <A sorting battle against a new enemy NPC.>
	desc <新たな敵 NPC との力関係が決まる戦い。>
	requires <*:CS_MechaEncounter &Raiders E:-- F:++ ~!Lo -!Md -!Hi -!Ex>
	changes <E:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the new enemy
	Element3 <NewNPC -2 -7>
	Place3 <2 (Enemies) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%  NPCLevel %3% StoryDL>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation <P= %id%03 1>

	%%  Debriefing Message
	% Msg%id%11 <%name3%, you say? I don't know anything about \OPR %3% ... I expect you'll find out shortly.>
	% Msg%id%11_1 <I think I've heard of this %name3%. They say \SPR %3% works for \FACTION &EnemyFac .>
	% CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>
	% Msg%id%11_2 <I know about %name3%... \SPR %3% 's clashed with \FACTION &AllyFac before. I believe \SPR %3% works for \FACTION &EnemyFac .>
	% CMsg%id%11_2 <ifFactionExists &EnemyFac ifFactionExists &AllyFac Accept>
	% Msg%id%11_3 <%name3% has fought with \FACTION &AllyFac before. I advise you to take care; you'll probably be crossing paths with \OPR %3% again.>
	% CMsg%id%11_3 <ifFactionExists &AllyFac Accept>
	Msg%id%11 <%name3%？ 何も情報はない%JV_F_WA%JV_NA……すぐに%JS2自身で確かめることになる%JV_DAROU。>
	Msg%id%11_1 <その %name3% という人物は聞いたことがあると思う%JV_F_WA。確か、\FACTION &EnemyFac の手の者だと……。>
	CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>
	Msg%id%11_2 <%name3% のことは知っている%JV_ZO……\SPR %3%は以前に \FACTION &AllyFac と関わりがあった%JG_NDA。奴らの手先となっていると考えて間違いない%JV_DAROU。>
	CMsg%id%11_2 <ifFactionExists &EnemyFac ifFactionExists &AllyFac Accept>
	Msg%id%11_3 <%name3% は以前に \FACTION &AllyFac と戦ったことがある%JG_NDA。よく注意しておいたほうがいい%JV_ZO、\SPR %3%とはまた道を交えることになる%JV_DAROUから%JV_NA。>
	CMsg%id%11_3 <ifFactionExists &AllyFac Accept>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  ForceChat %3%   StoryNote 2 &SetENemyNPC %3%  SetDebriefing %id%11  CancelSubPlot %plotid1% if# P%id%02 0 Alert 3>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   Alert 4 Monologue %3% 5 History 6   LoseSubPlot %plotid% Trigger0 .%id%_%plotid%_GoLoss  SetXXRAttitude %3% XXR_A_IsSenior>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 7 Monologue %3% 8   WinSubPlot %plotid%  Trigger0 .%id%_%plotid%_GoWin  SetXXRAttitude %3% XXR_A_IsJunior>
		end <SetEncounterInactive %2% ifNPCDead %3% else GoFreeze Print 9 Goto GoFreeze>
		GoFreeze <FreezeNPC %3%>

		% Msg1 <You locate the group of raiders that you've been searching for.>
		% Msg2 <You fought %name3% of \FACTION &EnemyFac .>
		% Msg3 <Your reinforcements are here, as promised.>
		% Msg4 <You have been defeated by %name3%.>
		% Msg5 <Just as I expected, you're a mere amateur. Don't bother me again until you're worth my time.>
		% Msg5_1 <Sorry that I had to hurt you, but you left me no other choice. Stay out of my business from now on.>
		% CMsg5_1 <ifNPCHeroic Accept>
		% Msg5_2 <Do you understand now, worm? Challenge me again and you won't live to tell about it.>
		% CMsg5_2 <ifNPCVillainous Accept>
		% Msg6 <%name3% defeated you.>
		% Msg7 <You defeated %name3%'s lance.>
		% Msg8 <Aw, man, I didn't expect you to be so tough... Would you be willing to go best two out of three?>
		% Msg8_1 <Hmph, so you're tough... Being strong still doesn't make you right, you know.>
		% CMsg8_1 <ifNPCHeroic Accept>
		% Msg8_2 <What, how could I lose to a jerk like you!? That's it, next time I won't hold back at all!>
		% CMsg8_2 <ifNPCVillainous Accept>
		% Msg9 <%name3%'s cockpit is mysteriously empty. Could \SPR %3% have survived?>
		Msg1 <行方を追っていた賊の一団を発見した。>
		Msg2 <\FACTION &EnemyFac の %name3% と戦った。>
		Msg3 <味方の援軍が到着した。>
		Msg4 <%name3% に敗北した。>
		Msg5 <思った通り、ただのアマチュアだった%JV_F_WA%JV_NA。相手をする価値のある腕になるまで、%JF2には関わらないこと%JG_DAYO。>
		Msg5_1 <傷つける結果になったのは残念だ%JG_GA、%JS2が他の選択肢を与えてくれなかったから%JG_DAYO。これからは%JF2の仕事の邪魔をしないで%JG_R。>
		CMsg5_1 <ifNPCHeroic Accept>
		Msg5_2 <これで虫ケラにも理解できた%JV_Q？ 次にまた邪魔することがあれば、もうそれが分かるまで生きてはいられない%JV_ZO。>
		CMsg5_2 <ifNPCVillainous Accept>
		% ラベル間違いを修正。
		Msg6 <%name3% に敗北した。>
		Msg7 <%name3% の部隊を撃破した。>
		Msg8 <ぐぐ、ここまで強いとは思わなかった%JV_ZO……今回のは、３ラウンド制の１本目ってことで引き下がってやる%JG_YO。>
		Msg8_1 <むむ、手強い%JV_F_WA……だ%JG_GA知ってる%JV_DAROU、強いものが正しいわけじゃない%JV_ZO。>
		CMsg8_1 <ifNPCHeroic Accept>
		Msg8_2 <何故%JV_M_DA……どうして%JF2が%JS_AGGのようなマヌケに負ける%JG_NDA！？ 上等%JV_M_DA%JV_F_YO、次は一切の手加減をしない%JV_ZO！>
		CMsg8_2 <ifNPCVillainous Accept>
		Msg9 <奇妙にも、%name3% のコクピットはもぬけの殻だった。生き延びたのだろうか？>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= P%id%03 0 else GoSmall WMecha 2 StoryDL 80>
			GoSmall <WMecha 2 StoryDL 30>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		Persona 3
		special <UNLISTED>
		greeting <EndChat Say %id%01 AddChat %id%01 AddChat %id%02>
		*result%id%01 <*THEME_EXPO&Enemy na>
		result%id%02 <AddSociable -d6 Goto result%id%01>
		% Msg%id%01 <Turn back, or in the name of \FACTION &EnemyFac I will destroy you!>
		% Msg%id%01_1 <I'm only going to give you one warning. Turn back now, or the entire might of \FACTION &EnemyFac will defeat you!>
		% CMsg%id%01_1 <ifNPCHeroic Accept>
		% Msg%id%01_2 <Get lost, jerk. I'm here on serious business from \FACTION &EnemyFac , and intend to crush anyone who gets in the way.>
		% CMsg%id%01_2 <ifNPCVillainous Accept>
		% Prompt%id%01 <Let's see if you can back up those words.>
		% Prompt%id%01_1 <You're the one who's going to back down.>
		% Prompt%id%02 <Whatever.>
		Msg%id%01 <引き返す%JG_NDA%JV_SIL_Rさもなければ、\FACTION &EnemyFac の名において%JS_AGGを排除する%JV_F_WA！>
		Msg%id%01_1 <警告は一度限り%JG_DA。今すぐ引き返すか、それとも \FACTION &EnemyFac の全勢力によって滅ぼされるか……！>
		CMsg%id%01_1 <ifNPCHeroic Accept>
		Msg%id%01_2 <雑魚はさっさと消える%JV_N%JV_M_DA%JV_NA。こっちは \FACTION &EnemyFac からの大事な仕事の最中な%JG_NDA%JV_SIL_R邪魔をする奴は、全員叩き潰す%JV_ZO。>
		CMsg%id%01_2 <ifNPCVillainous Accept>
		Prompt%id%01 <口に見合った実力があるのか、お手並み拝見%JV_M_DA%JV_F_NE。>
		Prompt%id%01_1 <引っ込むのはそっち%JG_DAYO。>
		Prompt%id%02 <そういうの、どうでもいいから……。>

	end




Content
	name <Edie Brickell Never Hurt Anyone>
	size 5
	% desc <The Bohemian Collective distances itself from your enemy.>
	desc <Bohemian Collective はあなたの敵とは距離を置いている。>
	requires <*:CS_MechaEncounter F:BOHEM E:++ -&Secondary -!Ne ~!Md ~!Hi>
	% The Bohemian Collective, being largely an anarchic group of live-and-let-live leave-me-aloneist
	% libertarians/libertines, doesn't make a very good enemy. Honestly, I can see pissing one or two
	% of them off, or maybe even three or four, but the entire faction? You made them agree on something?
	% Impossible. If a splinter group wants to kill you, they're probably just posers. Or pirates.
	changes <F:++>

	% E1 is the outdoors scene where this encounter will take place
	% E2 is the encounter
	% E3 is an envoy from the Dusty Ring
	% E4 is a pirate faction to be the new enemy
	% E5 is a pirate/mook of the Enemy NPC
	Element3 <Prefab>
	Place3 <2 (Envoy) sd ally>
	Element4 <Faction (REDMA|CRIHN) -ArchAlly !XClude -3>
	Element5 <Prefab>

	% P%id%01 = Initialization Counter

	update <if= P%id%01 0 P= %id%01 1 NPCLevel %3% StoryDL SetNPCFaction %5% %4%>

	% This subplot must propgate the effects of its own subplot backwards to
	% the parent plot.
	.%id1%_%plotid1%_GoWin  <WinSubPlot %plotid%  Trigger0 .%id%_%plotid%_GoWin>
	.%id1%_%plotid1%_GoLoss <LoseSubPlot %plotid% Trigger0 .%id%_%plotid%_GoLoss>

	%% Debriefing Msg
	% Msg%id%11_1 <\PERSONA &EnemyNPC actually works for %name4%... I'm not surprised. The Bohemians generally just want to be left alone.>
	% CMsg%id%11_1 <ifNPCOK &EnemyNPC ifNPCCheerful Accept>
	% Msg%id%11_2 <So they say \PERSONA &EnemyNPC works for %name4%... They probably just kicked \OPR &EnemyNPC out after they started taking too much heat.>
	% CMsg%id%11_2 <ifNPCOK &EnemyNPC ifNPCMelancholy Accept>
	% Msg%id%11_3 <\PERSONA &EnemyNPC actually works for %name4%... Can't say I'm surprised. The Bohemians colonies are too disorganized to pull off the kind of attacks we've been seeing.>
	% CMsg%id%11_3 <ifNPCOK &EnemyNPC ifNPCPassionate Accept>
	Msg%id%11_1 <\PERSONA &EnemyNPC は実際に %name4% の協力者だった……驚くようなことではない%JV_F_WA%JV_NA。Bohemian は基本的に外部との干渉を好まない人々だから。>
	CMsg%id%11_1 <ifNPCOK &EnemyNPC ifNPCCheerful Accept>
	Msg%id%11_2 <つまり、\PERSONA &EnemyNPC は %name4% の協力者だったと……恐らく、面倒事を呼び込みすぎたせいで Bohemian から追い出されたん%JV_DAROU%JV_NA。>
	CMsg%id%11_2 <ifNPCOK &EnemyNPC ifNPCMelancholy Accept>
	Msg%id%11_3 <\PERSONA &EnemyNPC は実際に %name4% の協力者だった……驚いたとは言えない%JV_F_WA%JV_NA。Bohemian のコロニーは、今まであったような組織立った攻撃を行えるような集団ではない%JG_SK。>
	CMsg%id%11_3 <ifNPCOK &EnemyNPC ifNPCPassionate Accept>

	% SubPlot1 is the Stop E5 mission
	SubPlot1 <*:CS_StopNPCMission&Secondary 5>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1   History 2   &SetEnemyFac %4%   SetDebriefing %id%11  ForceChat %3%>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Monologue %3% 3 Retreat 3 History 4 SMemo 5  SetPlotStatus %plotid1% %id1%>
		end <SetEncounterInactive %2% FreezeNPC %3%>

		% Msg1 <You find a lance of Bohemian mecha fighting some pirates.>
		% Msg2 <%name3% revealed that \PERSONA &EnemyNPC was a pirate, not a bohemian.>
		% Msg3_1 <\PERSONA &EnemyNPC 's number one fighter %name5% is here on a mission. Stop \OPR %5% , and many lives will be spared. We will meet again.>
		% CMsg3_1 <ifNPCOK %3% Accept>
		% Msg3_2 <\PERSONA &EnemyNPC ... \PPR &EnemyNPC henchman... you must stop %name5%... we... we will meet again...>
		% CMsg3_2 <ifNPCDead %3% Accept>
		% Msg4 <You learned that \PERSONA &EnemyNPC 's henchman %name5% was in town on a mission.>
		% Msg5 <%name3% told you that \PERSONA &EnemyNPC works for %name4%, and \PPR &EnemyNPC henchman %name5% is in town on a mission.>
		Msg1 <Bohemian のメック隊が海賊と戦っているのを発見した。>
		Msg2 <%name3% から、\PERSONA &EnemyNPC が Bohemian ではなく海賊だと告げられた。>
		Msg3_1 <\PERSONA &EnemyNPC の一番の手駒である %name5% が何かの目的でここに来てる%JG_NDA。奴を止めれば多くの命が救われる……%JS2とはまた会うことになる%JV_DAROU。>
		CMsg3_1 <ifNPCOK %3% Accept>
		Msg3_2 <\PERSONA &EnemyNPC ……奴の右腕…… %name5% を、止めて……%JF2と%JS2……は、また……会……う……。>
		CMsg3_2 <ifNPCDead %3% Accept>
		Msg4 <\PERSONA &EnemyNPC の側近である %name5% が何らかの目的で街に侵入していることを知った。>
		Msg5 <%name3% から、\PERSONA &EnemyNPC が %name4% に協力していることと、その側近である %name5% が何かの任務で街に侵入していることを伝えられた。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			name <Pirates>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %4%   WMecha 2 StoryDL 150>
			GoSmallDeploy <WMecha 2 StoryDL 90>
			ParaX 25
			ParaY 45

			team 3
			name <Envoy>
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  SetSelfFaction 12  WMecha 3 StoryDL 60>
			ParaX 45
			ParaY 5
		end

		Persona 3
		special <UNLISTED NOESCAPE>
		greeting <EndChat Say 1 AddChat 1 AddChat 2>
		result1 <EndChat Say 2 AddChat 3>
		result2 <EndChat Say 3 AddChat 3>
		result3 <EndChat Say 4>
		% Msg1 <Hold your fire, I come to you bearing a message from the dusty ring! The Bohemian Collective is not your enemy. We seek only peace with the people of \SCENE &EpisodeScene .>
		% Msg2 <\PERSONA &EnemyNPC does not represent us; in fact, \SPR &EnemyNPC has long been a member of %name4%, and it is they who have directed \PPR &EnemyNPC actions against you.>
		% Msg3 <I see that \PERSONA &EnemyNPC has been busy spreading lies. You should know that \SPR &EnemyNPC is not a member of the collective, but instead a pirate with %name4%. It is them that you should be fighting.>
		% Msg4 <I have additional information which may help you decide, but first we should deal with \PERSONA &EnemyNPC 's henchmen.>
		% Prompt1 <Tell that to \PERSONA &EnemyNPC !>
		% Prompt2 <You really think I'm going to believe that?>
		% Prompt3 <How do I know I can trust you?>
		Msg1 <武器を収めて%JG_R_AGG、%JF2は Dusty Ring を代表してメッセージを伝えに来た%JV_N%JV_M_DA！ Bohemian Collective は%JS2の敵ではない%JV_F_WA。%JF2%JF_TACHIが \SCENE &EpisodeScene の人々との間に求めているのは、平和だけな%JG_NDA。>
		Msg2 <\PERSONA &EnemyNPC の行動は%JF2%JF_TACHIの意思ではない%JV_F_WA。奴はもうずっと以前から %name4% の一員で、それこそが奴を%JS2に差し向けた黒幕な%JG_SK。>
		Msg3 <\PERSONA &EnemyNPC はよほど頑張って嘘を広めてる%JV_N%JV_M_DA%JV_NA。奴は Bohemian Collective の一員じゃない%JV_F_WA、ただの %name4% の海賊仲間%JG_DAYO。%JS2が戦うべき相手はそいつら%JG_DA。>
		Msg4 <その判断の助けになるだろう情報はまだある%JG_GA、その前にまず \PERSONA &EnemyNPC の手勢を片付けるべき%JG_DA。>
		Prompt1 <それは \PERSONA &EnemyNPC に対して言ってほしい%JV_F_WA%JV_NA！>
		Prompt2 <そんな話を信じるとでも？>
		Prompt3 <%JS2を信用する根拠は？>
	end
	inv
		NPC Explorer
		chardesc Old
		SetFaction 12

		NPC Pirate
		chardesc Young
		job_desig <MOOK_>
	end

Content
	name <MUGL, You Useless Morons>
	size 10
	% desc <Your enemy, frustrated with MUGL Enterprises's incompotence, leaves them for a different corp.>
	desc <MUGL Enterprises の無能っぷりに苛立った敵は辞職して他の会社へ移籍していく。>
	requires <*:CS_MechaEncounter F:MUGLE (P:--|P:CORPO) (E:M.---|E:M.mer) -E:A.nme (!Ne|!Lo)>
	%% MUGL Enterprises isn't a particularly good villain... or, should I say, not a particularly intimidating
	%% villain. I mean, how would you feel if Sanrio were trying to kill you? Actually, that does sound pretty
	%% terrifying... In any case this component will help to cement their reputation as the newest and to-date
	%% least respected of the L5 mecha corporations.
	changes <F:++ E:M>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the encounter
	% E3 is the enemy NPC
	% E4 is the faction which gave the NPC the better offer
	% E5 is a local public scene
	% E6 is another MUGL pilot who E3 is assisting, supposedly
	Element3 <Grab 1>
	Place3 <2 (Enemies) sd enemy>
	% The new enemy faction should be an enemy to both the PC and to MUGL.
	Element4 <Faction ArchEnemy !XClude -2 !XClude -3 Corporate>
	Element5 <Scene Public !Near -7 !Okay -2>
	Element6 <Character HasMecha Cheerful !Comrade -2 !Near 5 NeverFail>
	NeverFail6 <Mecha Pilot>
	Place6 <2 (Enemies) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %3% StoryDL NPCLevel %6% StoryDL>

	% Gaining the decimation advantage means that E6 won't show up to the battle.
	.%id1%_%plotid1%_GoDecimation     <P= %id%02 1  MoveAndPacifyNPC %6% 5>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		% L3 = Enemy Died/Plot Immunity Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   CancelSubPlot %plotid1%  Alert 1 Monologue %3% 2 if= P%id%02 0 else GoDecimated Monologue %6% 3 Monologue %3% 4 History 5>
		GoDecimated <Monologue %3% 6 History 7>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid% if# L3 0 Monologue %3% 8 Monologue %3% 9 Goto GoSetAttitude>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%  Alert 11  if= L3 0 else GoE3DiedEnd  if# P%id%02 0 else GoE3AliveEnd  ifNPCOK %6% else GoE3AliveEnd Monologue %6% 12 History 15  Goto GoE3AliveEnd>
		GoE3AliveEnd <Monologue %3% 13 Monologue %3% 9 Goto GoSetAttitude>
		GoE3DiedEnd <Alert 14 Goto GoSetAttitude>
		Faint%3% <L= 3 1 FreezeNPC %3%>
		end <SetEncounterInactive %2%>
		GoSetAttitude <History 10   SetXXRMotivation %3% XXR_M_Mercenary>

		% Msg1 <You face a lance of mecha from MUGL Enterprises led by %name3%.>
		% Msg2_1 <Hello again, \PC . I thought you'd try to interfere with %name6%'s mission, so I came here to help out.>
		% Msg3 <Yeah! No-one messes with the Bunny and gets away with it!>
		% Msg4 <Just shut up and fight, %name6%.>
		% Msg5 <You fought a group of mecha led by %name3% and %name6%.>
		% Msg6 <Now, where the blazes is %name6%...?>
		% Msg7 <You fought %name3%, who was supposed to be helping %name6%.>
		% Msg8 <That crappy MUGL mecha nearly killed me! How is anyone supposed to work with substandard equipment like this!?>
		% Msg9_1 <I quit! MUGL Enterprises can kiss my arse, I'm gonna go accept that offer at %name4%!>
		% Msg10 <%name3% quit MUGL to go work for %name4%.>
		% Msg11 <You have defeated all of the MUGL mecha.>
		% Msg12 <Hey %name3%, I'm here to start our mission now! Sorry I'm a bit late... ashes, what happened!?>
		% Msg13_1 <That's it! I've had it with this two-bit cartoon rabbit company! How do they expect us to win in garbage mecha like this!?>
		% Msg14 <You are surprised to find the cockpit of %name3%'s mecha empty, except for a completed job application for %name4%.>
		% Msg15 <%name6% arrived too late to help %name3%.>
		Msg1 <%name3% に率いられた MUGL Enterprises のメック部隊と対峙した。>
		Msg2_1 <また会った%JV_F_WA%JV_NA、\PC。どうせ %name6% の仕事を邪魔しに来るだろうと思ったから、%JF2も挨拶に来てやった%JV_ZO。>
		Msg3 <ハッ！ ウサちゃんの手に掛かって逃げられるものなどいない%JG_SK！>
		Msg4 <いいから黙って戦う%JG_NDA%JV_SIL_R %name6%。>
		Msg5 <%name3% と %name6% に率いられたメックの一団と戦った。>
		Msg6 <で、%name6% のバカは一体どこに行った%JG_NDA%JV_SIL_R？>
		Msg7 <%name6% の支援に来ていたらしい %name3% と戦った。>
		Msg8 <MUGL の無能メックのお陰で危うく死に掛けた%JV_ZO！ こんな二流の装備品でどうやって仕事をしろって%JG_SK！？>
		Msg9_1 <辞めてやる！ MUGL Enterprises なんかクソ喰らえ%JG_DA%JV_SIL_R%JF2は %name4% からのオファーを受ける%JV_ZO！>
		Msg10 <%name3% は MUGL を辞めて %name4% に移籍していった。>
		Msg11 <すべての MUGL メックを倒した。>
		Msg12 <よーし %name3%、ミッションの準備はＯＫ%JG_KANA！ 遅れてゴメ……え、何%JV_M_DAこの状況は！？>
		Msg13_1 <もういい！ こんな白黒アニメウサギの会社はもうたくさん%JG_DA！ こんなゴミみたいなメックでどうやって勝てって%JG_SK！？>
		Msg14 <驚くべきことに、%name3% が乗っていたはずのコクピットは空だった。代わりにそこには、書き上げられた %name4% への採用願書があった。>
		Msg15 <%name6% が %name3% の援軍に現れた時には、もう手遅れだった。>

		sub
			team 1
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			name <Enemies>
			SetEnemy 1
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 40>
			ParaX 45
			ParaY 45
		end
	end


Content
	name <I Have Become Death>
	size 9
	% desc <Your enemy no longer cares, and so won't hold back any longer.>
	desc <敵はもう様子見も手加減もしない。>
	requires <*:CS_MechaEncounter E:++ F:++ (E:M.---|E:M.rev) (E:A.hat|E:A.mut|E:A.obs|E:A.env|E:A.---|E:A.jr_|E:A.sr_|E:A.dis) !Hi -&Secondary>
	changes <E:M>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the "kicker" encounter- the one which starts the main plot
	% E3 is the enemy
	% E4 is the urban scene for the encounters to follow
	% E5 is the final battle scene
	% E6 is the Enemy's lieutenant
	% E7 is the third in command
	% E8 is the fourth
	% E9 is the *FactionRampage mood which accompanies this episode
	% E10 is an enemy of the enemy faction needed for narrative purposes
	Element3 <Grab 1>
	Place3 </>
	Element4 <Scene Urban !Near -7>
	Element5 <Prefab>
	Place5 <4>
	Element6 <Character Villainous HasMecha !Comrade -2 !Global NeverFail>
	NeverFail6 <Mecha Pilot>
	Place6 <5 (Enemies) SD enemy>
	Element7 <NewNPC -2 -7 Passionate>
	Place7 </>
	Element8 <Character Heroic HasMecha !Comrade -2 !Global NeverFail>
	Place8 </>
	Element9 <Prefab>
	Element10 <Faction !Enemy -2>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	% P%id%04 = Completed first combat
	% P%id%05 = E8 backed out of fight
	% P%id%06 = E7 backed out of (final) fight

	update <if= P%id%01 0 P= %id%01 1 SetNPCFaction %6% &EnemyFac SetNPCFaction %7% &EnemyFac SetNPCFaction %8% &EnemyFac>

	% Set either reinforcements or decimation here
	.%id3%_%plotid3%_GoReinforcements <P= %id%02 1>
	.%id3%_%plotid3%_GoDecimation     <P= %id%03 1>

	.%id1%_%plotid1%_GoWin <SetPlotStatus %plotid2% %id2%  SMemo %id%01     if= P%id%05 0 History %id%03     ifNPCOK %8% MoveNPC %8% %5% SetNPCTeam %8% 2>
	.%id2%_%plotid2%_GoWin <SetPlotStatus %plotid3% %id3%  Alert %id%02 SMemo %id%02 History %id%04 SetEncounterActive %5%  ifNPCOK %7% if= P%id%06 0 MoveNPC %7% %5% SetNPCTeam %7% 2>

	% Msg%id%01 <You have defeated %name8%, but %name7% is still out there looking for you.>
	% Msg%id%02 <You have defeated both %name8% and %name7%. Now it's time to bring the fight to %name6%.>
	% Msg%id%03 <You defeated %name8% in mecha combat.>
	% Msg%id%04 <You defeated %name7% in mecha combat.>
	Msg%id%01 <%name8% を撃破したが、まだ %name7% があなたのことを探し回っている。>
	Msg%id%02 <%name8% と %name7% の両方を撃破した。これで次は %name6% と戦える。>
	Msg%id%03 <メック戦で %name8% を撃破した。>
	Msg%id%04 <メック戦で %name7% を撃破した。>

	% SubPlot1 is the first substage boss battle
	% SubPlot2 is the second substage boss battle
	% SubPlot3 is the ability to gain an advantage in the final battle
	SubPlot1 <*:CS_SubBossRoadblock 4 8>
	SubPlot2 <*:CS_SubBossRoadblock 4 7>
	SubPlot3 <*:CS_GainAdvantageVsNPC&Decimation&Reinforcements 6>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 30
		MapHeight 30

		Start <if= L2 0 L= 2 1 Alert 1 Monologue %3% 2 Monologue %6% 3  History 4  SetXXRMotivation %3% XXR_M_Nihilism   SetNPCRep %3% 1 -100   SetMood %9% &EpisodeScene>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1                           Monologue %6% 7  Goto GoBeginRoadblock>
		nu2 <if= T2 0   if= V1 0 V= 1 1   AddRenown 1   SALVAGE   Monologue %6% 8 Monologue %7% 9 Monologue %8% 10  XPV 100 P= %id%04 1 Return  Goto GoBeginRoadblock>
		end <SetEncounterInactive %2%>
		GoBeginRoadblock <SMemo 5 History 6 SetPlotStatus %plotid1% %id1%>

		% Msg1 <You arrive at the end of a battle between %name3% and %name10%.>
		% Msg2 <You missed the action, \PC . My work here is finished. %name6%, I will leave you to mop up the rest. I don't care how many civilians you have to kill.>
		% Msg3 <It'll be my pleasure, captain. \SCENE &EpisodeScene will know that it belongs to \FACTION &EnemyFac !>
		% Msg4 <%name3% ordered \PPR %3% lieutenant %name6% to raze \SCENE &EpisodeScene .>
		% Msg5 <%name3% left \PPR %3% lieutenant to raze \SCENE &EpisodeScene . %name6% ordered %name7% and %name8% to hunt you down.>
		% Msg6 <%name6% assigned %name7% and %name8% to hunt you down.>
		% Msg7 <Don't think you can get away. I'll assign %name7% and %name8% to make sure you don't survive.>
		% Msg8 <You're stronger than you look, but don't think you're safe just yet. I'll send %name7% and %name8% to hunt you down.>
		% Msg9 <Finally, an opponent who might be worth my talents.>
		% Msg10 <I don't know... are we really doing the right thing here?>
		Msg1 <%name3% と %name10% の戦いが決しようとしているところに到着した。>
		Msg2 <一足遅かった%JV_F_WA%JV_NA、\PC。%JF2の仕事はもう終わった%JV_ZO。%name6%、残りの始末は%JS_AGGに任せる%JV_F_WA%JV_F_YO。市民は何人殺そうが好きにするといい%JV_F_WA。>
		Msg3 <大将、それはもう喜んで。\SCENE &EpisodeScene の奴らは、自分たちが \FACTION &EnemyFac の支配下だってことを思い知る%JV_DAROU！>
		Msg4 <%name3% は手下である %name6% に \SCENE &EpisodeScene の蹂躙を命じた。>
		Msg5 <%name3% は \SCENE &EpisodeScene を蹂躙するために手下を残していった。その手下である %name6% は、あなたを狩るために %name7% と %name8% を差し向けてきた。>
		Msg6 <%name6% が %name7% と %name8% を刺客として差し向けてきた。>
		Msg7 <逃げられるとは思わないこと%JV_M_DA%JV_NA。%name7% と %name8% が%JS_AGGを確実に始末する%JV_DAROU。>
		Msg8 <見掛けよりも腕が立つようだ%JG_GA、安心するのはまだ早い%JV_ZO。%name7% と %name8% に%JS_AGGを狩るよう命じたから%JV_NA。>
		Msg9 <ついに、この%JF2の才覚に値するかもしれない相手が現れた%JV_F_WA%JV_KA_Q……。>
		Msg10 <どうなの%JG_KANA%JV_SIL_Rこれって本当に正しいことなの%JV_KA_Q？>

		sub
			team 1
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			SetEnemy 1
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 100>
			ParaX 25
			ParaY 25
		end

		MetaScene 5 2
		%  This is the final battle against E6 and the surviving henchmen. It's likely to be
		%  very tough, so hopefully the PC has gained the advantage or removed some of the
		%  henchmen.
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1  ForceChat %6%>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1 LoseRenown History 1 SetMoodTimeLimit %9% 86400 LoseSubPlot %plotid%   Trigger0 .%id%_%plotid%_GoLoss>
		nu2 <if= T2 0   if= V1 0 V= 1 1   Alert 2 History 3   XPV 100  SALVAGE  KillMood %9%   AddRenown 1   Trigger0 .%id%_%plotid%_GoWin   WinSubPlot %plotid%>
		end <SetEncounterInactive %5%>

		% Msg1 <You were defeated in combat by %name6%'s lance.>
		% Msg2 <With %name6% defeated, %name3%'s followers will be forced to leave \SCENE &EpisodeScene and peace will return.>
		% Msg3 <You defeated %name6%'s lance, driving them from \SCENE &EpisodeScene .>
		Msg1 <%name6% の部隊との戦闘に敗れた。>
		Msg2 <%name6% を撃破したことで、%name3% の一味は \SCENE &EpisodeScene を追われることになる。平和が戻るだろう。>
		Msg3 <%name6% の部隊を撃破し、\SCENE &EpisodeScene から追い払った。>

		sub
			team 1
			SetEnemy 2
			SetAlly 3
			ParaX 5
			ParaY 5

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= P%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 100>
			GoSmallDeploy <WMecha 2 StoryDL 25>
			ParaX 45
			ParaY 45

			team 3
			name <Reinforcements>
			SetEnemy 2
			SetAlly 1
			Deploy <if# P%id%02 0   WMecha 2 StoryDL 100>
			ParaX 10
			ParaY 10
		end

		Persona 6
		special <UNLISTED>
		greeting <if= PlotStatus %plotid% %id% else %pop% EndChat Say %id%01 AddChat %id%01>
		*result%id%01 <*THEME_EXPO&Enemy na>
		% Msg%id%01 <You managed to escape both %name7% and %name8%... that's quite impressive. Unfortunately it will be of no use to you now.>
		% Prompt%id%01 <I'll do the same to you.>
		Msg%id%01 <%name7% と %name8% の手から逃れるとは……大した腕%JG_DANE。だ%JG_GA、その幸運もここで無意味なものになる%JV_F_WA。>
		Prompt%id%01 <%JS_AGGにも同じ運命を辿らせてやる%JG_YO。>

		Persona 7
		special <UNLISTED>
		% V%id%01 = Have fought before
		%  If the PC completed the first combat and heard E7 speak, it might be
		%  possible to convince them to not fight now.
		greeting <if= PlotStatus %plotid% %id% else %pop% if= v%id%01 0 else .%id%_GoSecondTime EndChat Say %id%01 AddChat %id%01 AddChat %id%02 V= %id%01 1>
		*.%id%_GoSecondTime <*Back_For_More>
		*result%id%01 <*THEME_EXPO&Enemy na>
		result%id%02 <EndChat Say %id%02 P= %id%06 1 AddChat %id%03>
		result%id%03 <Goto result%id%01>
		% Msg%id%01 <So there you are... I heard what you did to %name8%, but I assure you that I won't be nearly so easy to beat.>
		% Msg%id%02 <%name6% isn't the boss of me! I don't have to listen to \OPR %6%... it's just that right now I want to kick your ass of my own free will!>
		% Prompt%id%01 <We'll find out soon enough.>
		% Prompt%id%02 <If you're so tough, then why aren't you %name3%'s second?>
		% CPrompt%id%02 <if# P%id%04 0 ifInsight SkillTar StoryDL Accept>
		% Prompt%id%03 <[Continue]>
		Msg%id%01 <そこにいたの%JV_KA…… %name8% がどうなったかは聞いた%JG_GA、%JF2が同じように簡単にやられるとは思わないこと%JG_DANE。>
		Msg%id%02 <%name6% は%JF2のボスなんかじゃない！ あんな奴の言葉を聞く必要はない%JV_F_WA……今はこの%JF2が、自分の意思で%JS_AGGを叩きのめそうとしているだけ%JG_DA！>
		Prompt%id%01 <結果はすぐに分かる%JG_YO。>
		Prompt%id%02 <そんなに強いなら、どうして %name6% よりも下っ端な%JG_NDA？>
		CPrompt%id%02 <if# P%id%04 0 ifInsight SkillTar StoryDL Accept>
		Prompt%id%03 <[続ける]>

		Persona 8
		special <UNLISTED>
		% V%id%01 = Have fought before
		%  If the PC completed the first combat and heard E8 speak, it might be
		%  possible to convince them to not fight now.
		greeting <if= PlotStatus %plotid% %id% else %pop% if= P%id%05 0 else %pop% if= v%id%01 0 else .%id%_GoSecondTime EndChat Say %id%01 AddChat %id%01 AddChat %id%02 V= %id%01 1>
		*.%id%_GoSecondTime <*Back_For_More>
		*.%id%_GoArgumentFail <*IDisagreeYouDie>
		.%id%_GoArgumentWin <Retreat 2 P= %id%05 1>
		.%id%_GoArgumentMeh <EndChat Say %id%04 History %id%07 PCFriend %8% Goto .%id%_GoArgumentWin>
		.%id%_GoJoinLance <EndChat Say %id%05 History %id%06 PCAlly %8% AddLancemate %8% SetXXRMotivation %8% XXR_M_GreaterGood Goto .%id%_GoArgumentWin>
		*result%id%01 <*THEME_EXPO&Enemy na>
		result%id%02 <EndChat Say %id%02 AddChat %id%03 AddChat %id%04 AddChat %id%05>
		result%id%03 <ifPCHeroic else .%id%_GoArgumentFail ifConversation SkillTar StoryDL else .%id%_GoArgumentFail EndChat Say %id%03 AddChat %id%06 AddChat %id%07>
		result%id%04 <Goto result%id%01>
		result%id%05 <ifConversation SkillTar StoryDL else .%id%_GoArgumentFail EndChat Say %id%04 PCFriend %8% History %id%07 Goto .%id%_GoArgumentWin>
		result%id%06 <ifG PCHeroism d50 else .%id%_GoArgumentMeh Goto .%id%_GoJoinLance>
		result%id%07 <ifG ChatNPCHeroism d50 else .%id%_GoArgumentMeh Goto .%id%_GoJoinLance>
		% Msg%id%01 <I've caught you! %name6% ordered me to defeat you, so I can't allow you to escape!>
		% Msg%id%02 <What else can I do? I may not like what %name3%'s doing to \SCENE &EpisodeScene , but I must remain loyal to \FACTION &EnemyFac .>
		% Msg%id%03 <But... but what about my friends? Is this really the right thing to do?>
		% Msg%id%04 <You're right... I won't fight you, but I can't betray my friends either. Goodbye \PC .>
		% Msg%id%05 <I think... I think you're right. I'll help you to defeat %name3%.>
		% Msg%id%06 <You convinced %name8% to join your side.>
		% Msg%id%07 <You convinced %name8% to abandon the fight.>
		% Prompt%id%01 <Let's get this over with.>
		% Prompt%id%02 <You don't have to do this, you know.>
		% CPrompt%id%02 <if# P%id%04 0 Accept>
		% Prompt%id%03 <Forget about them, and join my team instead!>
		% Prompt%id%04 <Die by my hand, then.>
		% Prompt%id%05 <You know what you're doing is wrong.>
		% Prompt%id%06 <%name3% must be stopped, for everyone's sake.>
		% Prompt%id%07 <Do whatever you think is right.>
		Msg%id%01 <捕まえた%JG_YO！ %JS2を倒せって %name6% に命令されたから、逃がしてやるわけにはいかない%JV_F_NO%JV_F_YO！>
		Msg%id%02 <でも他にどうしようもない%JV_DAROU？ %name3% が \SCENE &EpisodeScene にしていることは気に入らない%JG_GA、\FACTION &EnemyFac を裏切るわけにはいかない%JG_NDA。>
		Msg%id%03 <でも……じゃあ%JF2の友達はどうなる%JG_NDA？ これは本当に正しいことなの%JV_KA_Q？>
		Msg%id%04 <%JS2が正しい%JG_YO%JV_SIL_Rでも%JF2は友達を裏切ることはできない。さよなら%JV_M_DA%JV_F_YO、\PC。>
		Msg%id%05 <それは……それは多分、%JS2が正しい。%name3% を倒すのに力を貸%JV_SOU。>
		Msg%id%06 <%name8% を説得して味方に引き入れた。>
		Msg%id%07 <%name8% を説得して戦いを放棄させた。>
		Prompt%id%01 <さっさと終わらせる%JV_ZO。>
		Prompt%id%02 <こんなことをする必要はない、って本当は分かってるんじゃないの%JV_KA_Q%JV_SIL？>
		CPrompt%id%02 <if# P%id%04 0 Accept>
		Prompt%id%03 <全部忘れて、%JF2の仲間になる%JG_NDA！>
		Prompt%id%04 <なら、この手で死なせてやる%JG_YO。>
		Prompt%id%05 <自分が間違ってるって分かってる%JV_N%JV_M_DA%JV_NA。>
		Prompt%id%06 <%name3% を止めなきゃいけない%JV_F_NO%JV_F_YO。人々のために。>
		Prompt%id%07 <自分が正しいと思うことをする%JG_NDA。>
	end
	inv
		stc CORE-ACTIVATABLE
		name <%name6%'s Lance>
		name_I18N <%name6% の部隊>

		Mood 3
		name <"I Have Become Death" Mood>
		plot_type <*FactionRampage>
		Element1 <Grab -2>
		Update <if= v1 0 V= 1 1   News 1>
		% Msg1_1 <%city% under siege as %name3%'s personal forces take control.>
		% Msg1_2 <Mecha from \FACTION &EnemyFac take control of %city% under the orders of %name3%.>
		% Msg1_3 <%name3% has begun a purge of \PPR %3% enemies from %city%; authorities powerless to stop the destruction.>
		% Meme Messages
		% Msg_1 <When will the trouble with %me_name1% end?>
		% CMsg_1 <if# ChatNPCFac %me_1% Accept>
		% Msg_2 <Someone really ought to do something about %me_name1%... They must be stopped!>
		% CMsg_2 <if# ChatNPCFac %me_1% Accept>
		% Msg_3 <What did %city% do to deserve this? Those jerks from %me_name1% are acting like they own the place.>
		% CMsg_3 <if# ChatNPCFac %me_1% Accept>
		Msg1_1 <%name3% の私兵により、%city% が包囲制圧されている。>
		Msg1_2 <%name3% の命令により、\FACTION &EnemyFac のメックが %city% を制圧している。>
		Msg1_3 <%name3% は %city% で次々と抵抗勢力を排除している。現地の治安当局はこの破壊活動を食い止める力を持っていない。>
		% Meme Messages
		Msg_1 <いつになったら %me_name1% の悪事が終わる%JG_NDA？>
		CMsg_1 <if# ChatNPCFac %me_1% Accept>
		Msg_2 <いい加減誰か %me_name1% を何とかして%JG_R_AGG%JV_SIL_R奴らを止めて%JG_R_AGG！>
		CMsg_2 <if# ChatNPCFac %me_1% Accept>
		Msg_3 <どうして %city% がこんな目に遭わなきゃならない%JG_NDA？ あの %me_name1% の悪党ども、我が物顔で歩き回ってる%JV_ZO……。>
		CMsg_3 <if# ChatNPCFac %me_1% Accept>
	end



Content
	name <Revenge Road>
	size 12
	% desc <The Enemy has mobilized all forces to destroy the PC.>
	desc <敵は PC を潰すために全戦力を動員した。>
	requires <*:CS_MechaEncounter E:++ E:A.hat (E:M.---|E:M.com|E:M.see) -&Secondary>
	changes <E:M>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy
	% E4 is an environs scene
	% E5 is an urban scene
	% E6 is Seeker #1
	% E7 is Seeker #2
	Element3 <Grab 1>
	Place3 </>
	Element4 <Scene Environs !Near -7>
	Element5 <Scene Urban !Near -7>
	Element6 <Prefab>
	Place6 <4>
	Element7 <Prefab>
	Place7 <5>

	% P%id%01 = Have activated henchmen

	% This subplot must propgate the effects of its own subplot backwards to
	% the parent plot. Yahoo.
	.%id1%_%plotid1%_GoWin  <WinSubPlot %plotid%  Trigger0 .%id%_%plotid%_GoWin>
	.%id1%_%plotid1%_GoLoss <LoseSubPlot %plotid% Trigger0 .%id%_%plotid%_GoLoss>

	% SubPlot1 = The enemy mission you have to stop
	SubPlot1 <*:CS_StopNPCMission&IsEnemyNPC&Secondary 3>

	sub
		Persona 3
		special <Unlisted>
		greeting <if= PlotStatus %plotid% %id% else GoChat EndChat Say %id%01 AddCHat %id%01>
		GoChat <NewChat SayAnything>
		result%id%01 <EndCHat Say %id%02>
		% Msg%id%01 <Well done, \PC . I suppose you'll be disappointed to learn that your actions here won't prevent me from completing my mission.>
		% Msg%id%02 <Hardly. This is just the beginning! I've mobilized all of my lancemates and ordered them to destroy you. You will probably find yourself far too busy to stop me... that, or dead. Preferably dead.>
		% Prompt%id%01 <Maybe not, but I've decimated your forces!>
		% Prompt%id%01_1 <Maybe not, but I've made it harder on you!>
		Msg%id%01 <いい仕事ぶり%JV_M_DA%JV_F_NE、\PC。もっとも、%JF2の目的を阻止するのには無意味だったと、すぐに失望を知ることになるだろう%JG_GA%JV_NA。>
		Msg%id%02 <この程度でいい気になるの%JV_KA_Q？ こんなのはただの始まりに過ぎない%JV_F_WA%JV_F_YO！ %JF2はすべての仲間に%JS_AGGを殺せと命じた%JV_ZO。もう%JF2を止めるどころの話ではない%JV_DAROUよ……あるいは、単に死ぬか。死んでくれると嬉しい%JG_GA%JV_NA？>
		Prompt%id%01 <かもしれない%JV_F_WA%JV_NA。それでも%JS_AGGの手勢は潰した%JV_ZO！>
		Prompt%id%01_1 <そう%JV_KA_Q。なら%JS_AGGにはもっと酷い目に遭ってもらう%JV_F_WA！>

		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1 History 1>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   LoseSubPlot %plotid%   Trigger0 .%id1%_%plotid1%_GoLoss>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 2  SMemo 3  History 4   ForceChat %3%  SetPlotStatus %plotid1% %id1%  SetXXRMotivation %3% XXR_M_Revenge  P= %id%01 1>
		end <SetEncounterInactive %2%>

		% Msg1 <You fought a group of %name3%'s henchmen.>
		% Msg2 <You have defeated all of %name3%'s henchmen.>
		% Msg3 <You haven't yet stopped %name3%'s mission, and \SPR %3% has mobilized all of \PPR %3% forces to prevent you from doing so.>
		% Msg4 <%name3% mobilized all of \PPR %3% forces to destroy you.>
		Msg1 <%name3% の手勢の一団と戦った。>
		Msg2 <%name3% の手勢をすべて倒した。>
		Msg3 <まだ %name3% の目的を阻止できていない。\SPR %3%は持てる戦力のすべてを投入してあなたを妨害するつもりだ。>
		Msg4 <%name3% はあなたを殺すために手勢のすべてを動員した。>

		sub
			team 1
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			SetEnemy 1
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 150>
			ParaX 45
			ParaY 45
		end

		MetaScene 6 2
		special <UNCHARTABLE>
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1>
		nu1 <if= T1 0   Return if= L2 1 L= 2 2 AddRenown -1>
		nu2 <if= T2 0 if= T3 0   if= L2 1 L= 2 2 Alert 2 Return>
		nu3 <if= T2 0 if= T3 0   if= L2 1 L= 2 2 Alert 2 Return>
		end <L= 2 0>

		% Msg2 <You have defeated this group of %name3%'s henchmen, but there will be more coming soon.>
		Msg2 <%name3% の手勢の一隊を撃破したが、すぐに次の部隊が現れるだろう。>

		sub
			team 1
			SetEnemy 2 3
			ParaX 25
			ParaY 25

			team 2
			name <From the Top>
			SetEnemy 1
			SetAlly 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 50>
			ParaX 20
			ParaY 5

			team 3
			name <From the Bottom>
			SetEnemy 1
			SetAlly 2
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 3 StoryDL 50>
			ParaX 30
			ParaY 45
		end

		MetaScene 7 2
		special <UNCHARTABLE>
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1>
		nu1 <if= T1 0   Return if= L2 1 L= 2 2 AddRenown -1>
		nu2 <if= T2 0 if= T3 0   if= L2 1 L= 2 2 Alert 2 Return>
		nu3 <if= T2 0 if= T3 0   if= L2 1 L= 2 2 Alert 2 Return>
		end <L= 2 0>

		% Msg2 <You have defeated this group of %name3%'s henchmen, but there will be more coming soon.>
		Msg2 <%name3% の手勢の一隊を撃破したが、すぐに次の部隊が現れるだろう。>

		sub
			team 1
			SetEnemy 2 3
			ParaX 25
			ParaY 25

			team 2
			name <Left Flank>
			SetEnemy 1
			SetAlly 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 50>
			ParaX 5
			ParaY 20

			team 3
			name <Right Flank>
			SetEnemy 1
			SetAlly 2
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 3 StoryDL 50>
			ParaX 45
			ParaY 30
		end

	end
	inv
		Encounter
		name <Henchmen>
		name_I18N <%name3% の手勢>
		% V1 = Recharge counter
		update <if= PlotStatus %plotid% %id% else GoHide if# p%id%01 0 else GoHide ifG ComTime V1 else GoHide SetStat STAT_MetaVisibility 0   Goto GoSetOrders>
		EncounterMove 20
		use <ifG StatVal STAT_MetaVisibility -1  Print -1   V= 1 ComTime   V+ 1 10800   Exit Destination>
		ATTACK <ifG StatVal STAT_MetaVisibility -1   ifG PCScale 0    V= 1 ComTime   V+ 1 10800   ifUStealth SkillTar StoryDL else GoAutoAttack   ifYesNo -3 -4 -5 else GoAvoidAttack Goto GoAutoAttack>
		% Msg-2 <You are suddenly attacked by %name3%'s henchmen!>
		Msg-2 <突然、%name3% の取り巻きが襲ってきた！>

		Encounter
		name <Henchmen>
		name_I18N <%name3% の手勢>
		% V1 = Recharge counter
		update <if= PlotStatus %plotid% %id% else GoHide if# p%id%01 0 else GoHide ifG ComTime V1 else GoHide SetStat STAT_MetaVisibility 0   Goto GoSetOrders>
		EncounterMove 20
		use <ifG StatVal STAT_MetaVisibility -1  Print -1   V= 1 ComTime   V+ 1 10800   Exit Destination>
		ATTACK <ifG StatVal STAT_MetaVisibility -1   ifG PCScale 0    V= 1 ComTime   V+ 1 10800   ifUStealth SkillTar StoryDL else GoAutoAttack   ifYesNo -3 -4 -5 else GoAvoidAttack Goto GoAutoAttack>
		% Msg-2 <You are suddenly attacked by %name3%'s henchmen!>
		Msg-2 <突然、%name3% の取り巻きが襲ってきた！>
	end


Content
	name <Enemy Upgrade>
	% desc <Your enemy is given one last chance to defeat you or be replaced.>
	desc <クビ寸前の敵は、あなたを倒す最後のチャンスを与えられた。>
	requires <*:CS_MechaEncounter E:A.jr_ F:++ ~!Md ~!Hi>
	changes <E:A E:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy fighter
	% E4 is the replacement enemy
	Element3 <Grab 1>
	Place3 <2 (Enemies) sd enemy>
	Element4 <Prefab>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %3% StoryDL SetNPCFaction %4% &EnemyFac>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	%% Debriefing Msg - PC throws fight
	% Msg%id%11 <It appears that you didn't put up much of a fight. The enemy forces escaped unharmed.>
	Msg%id%11 <%JS2はまるで戦いを挑まなかったらしい%JV_F_WA%JV_NA。敵戦力は無傷で逃げていった%JV_ZO。>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 4 ForceChat %3%  History 1 CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%  ifNPCOK %3% else GoE3Died  Monologue %4% 5  Monologue %3% 6  SetXXRAttitude %3% XXR_A_IsEqual  History 7>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%  ifNPCOK %3% else GoE3Died Goto GoE3Defeated>

		end <SetEncounterInactive %2%>

		GoE3Defeated <Monologue %4% 8 FreezeNPC %3% FreezeNPC %4% &SetEnemyNPC %4% SetXXRAttitude %4% XXR_A_IsSenior History 9>
		GoE3Died <Monologue %4% 10 FreezeNPC %4% &SetEnemyNPC %4% SetXXRAttitude %4% XXR_A_IsSenior History 11>

		% Msg1 <%name3% was ordered to defeat you or be fired.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated %name3%'s lance.>
		% Msg4 <You face a mecha force led by %name3% of \FACTION &EnemyFac .>
		% Msg5 <Congratulations, %name3%, it seems that you will keep your job.>
		% Msg6 <I'm just as surprised as anyone!>
		% Msg7 <You lost the battle, much to %name3%'s surprise.>
		% Msg8 <%name3%, you have failed \FACTION &EnemyFac for the last time. From this point on I will deal with \PC myself.>
		% Msg9 <You defeated %name3%, who was fired by %name4%.>
		% Msg10 <It's a shame that %name3% never lived up to \PPR %3% potential. I promise you this, \PC : \FACTION &EnemyFac will not allow you to escape.>
		% Msg11 <You killed %name3%. %name4% promised revenge.>
		Msg1 <%name3% は、あなたを倒せなければクビになる羽目になった。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <%name3% の部隊を撃破した。>
		Msg4 <\FACTION &EnemyFac の %name3% に率いられたメック部隊と対峙した。>
		Msg5 <おめでとう、%name3%。どうやらクビにはされずに済んだよう%JV_M_DA%JV_NA。>
		Msg6 <%JF2も自分でビックリ%JV_DESUよ！>
		Msg7 <%name3% 自身すら驚くことに、あなたは敗北した。>
		Msg8 <%name3%、最後まで \FACTION &EnemyFac の期待を裏切った%JV_F_WA%JV_NA。ここからはこの%JF2自身が \PC を始末を付ける%JV_ZO。>
		Msg9 <%name3% に勝利し、\SPR %3%は %name4% からクビを言い渡された。>
		Msg10 <%name3% が自身の才覚を活かすことなく終わったのは残念なことだった%JV_F_WA。だ%JG_GA約束する%JV_ZO、\PC …… \FACTION &EnemyFac は決して%JS_AGGを逃がさない。>
		Msg11 <あなたが %name3% を殺したことで、%name4% は復讐を宣言した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 80>
			GoSmallDeploy <WMecha 2 StoryDL 40>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		Persona 3
		special <UNLISTED>
		% V%id%01 = reaction bonus
		greeting <if= PlotStatus %plotid% %id% else %pop% EndChat Say %id%01 AddChat %id%01 AddChat %id%02 AddChat %id%03>
		*result%id%01 <*THEME_EXPO&Enemy na>
		result%id%02 <EndChat Say %id%02 AddChat %id%04 AddChat %id%05 AddChat %id%06>
		result%id%03 <ifNPCVillainous else .%id%_GoR3Win EndChat Say %id%04 AddChat %id%04>
		.%id%_GoR3Win <EndChat Say %id%03 AddChat %id%04 AddChat %id%05 AddChat %id%06 if= v%id%01 0 V= %id%01 1 AddReact d10>
		result%id%04 <Goto result%id%01>
		result%id%05 <ifNPCVillainous else .%id%_GoR5Win EndChat Say %id%05>
		.%id%_GoR5Win <EndChat Say %id%06 AddReact d30 ifG React 45 PCFriend %3% SetXXRAttitude %3% XXR_A_Thankful>
		result%id%06 <EndChat Say %id%07 AddChat %id%07 AddChat %id%08>
		result%id%07 <EndChat Say %id%08 History %id%09 SetXXRAttitude %3% XXR_A_IsEqual PCFriend %3% SetDebriefing %id%11  L= 1 1 Retreat 2 XPV 200 Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		result%id%08 <Goto result%id%01>
		% Msg%id%01 <This is it, \PC ... My boss %name4% told me that I have to defeat you, or else I'm going to get fired from \FACTION &EnemyFac .>
		% Msg%id%02 <Oh, \SPR %4% 's one of the hot pilots at \FACTION &EnemyFac . I don't think \SPR %4% likes me very much... keeps using words like "incompetent" and "execrable".>
		% Msg%id%03 <It's been a great pleasure fighting against you, too, \PC ... It's hard to believe that it could all be ending...>
		% Msg%id%04 <What, are you nuts? You do realize that I've been trying to kill you, don't you?>
		% Msg%id%05 <And maybe you're gonna die right now! My \ChatNPCMecha can't lose this time!>
		% Msg%id%06 <That's so kind of you to say... My... My... My \ChatNPCMecha will... Oh, I can't even say it. Let's just get this done with.>
		% Msg%id%07 <You want to keep me around that badly? I don't know... Are you really willing to do that?>
		% Msg%id%08 <Victory! Come on, lance, let's get out of here.>
		% Msg%id%09 <You threw the fight so %name3% could keep \PPR %3% job.>
		% Prompt%id%01_1 <Don't worry, I'll miss you.>
		% CPrompt%id%01_1 <ifG React 10 Accept>
		% Prompt%id%01_2 <Good. Maybe then you'll stop bugging me.>
		% CPrompt%id%01_2 <ifG 11 React Accept>
		% Prompt%id%02 <Who is this %name4%?>
		% Prompt%id%03 <No way! Where am I going to get an enemy as good as you?>
		% CPrompt%id%03 <ifG React 25 Accept>
		% Prompt%id%04 <Well, let's get it over with, then.>
		% Prompt%id%05 <Maybe after you're fired you can come work for me.>
		% CPrompt%id%05 <ifG React 15 Accept>
		% Prompt%id%06 <You know, I could throw the fight...>
		% CPrompt%id%06 <ifG React 35 ifInsight HardSkilltar StoryDL Accept>
		% Prompt%id%07 <Yes, I'll throw the fight for you.>
		% Prompt%id%08 <No, I'm just yanking your chain.>
		Msg%id%01 <ここまで%JV_M_DA%JV_F_YO、\PC。%JS2を倒せなかったら \FACTION &EnemyFac から追い出される、って%JF2のボスの %name4% に言われてる%JG_NDA。>
		Msg%id%02 <ああ、あの人は \FACTION &EnemyFac でもトップクラスの腕利き%JG_DAYO。%JF2のことはあんまり好きじゃないみたいだ%JG_GA%JV_NA……いつも無能だとかゴミだとかいう言葉ばっかり浴びせられるから。>
		Msg%id%03 <\PC、こっちこそ%JS2と戦えて本当に楽しかった%JG_YO%JV_SIL_R。これで最後だなんて、信じられない%JG_NE%JV_SIL_R。>
		Msg%id%04 <は、何を言ってる%JG_NDA？ %JF2はずっと%JS2を殺そうとしてたんだって分かってるの%JV_KA_Q？>
		Msg%id%05 <それより前に、%JS2は今ここで死んじゃう%JV_DAROU！ %JF2の \ChatNPCMecha は今度こそ負けられない%JG_NDA！>
		Msg%id%06 <そこまで言ってくれるなんて……%JF2、%JF2は……%JF2の \ChatNPCMecha は……ああ、言葉が出ない%JV_ZO。早いところ、終わりにし%JV_YOU。>
		Msg%id%07 <そこまで%JF2のことを……！ どうしよう……本当にそれでいいの%JV_Q？>
		Msg%id%08 <勝った！ じゃあみんな、ここから脱出%JG_DA！>
		Msg%id%09 <%name3% がクビにならないように、戦いを放棄した。>
		Prompt%id%01_1 <大丈夫%JV_M_DA、見逃してあげる%JG_YO。>
		CPrompt%id%01_1 <ifG React 10 Accept>
		Prompt%id%01_2 <それは何より%JV_M_DA%JV_F_NE。ついでに、纏わりつくのを止めたらどう%JG_KANA。>
		CPrompt%id%01_2 <ifG 11 React Accept>
		Prompt%id%02 <その %name4% ってのは誰%JV_M_DA%JV_F_YO？>
		Prompt%id%03 <まさか！ %JS2みたいないい相手が他のどこにいる%JG_NDA？>
		CPrompt%id%03 <ifG React 25 Accept>
		Prompt%id%04 <そう%JV_KA_Q、なら早いところ終わらせる%JV_ZO。>
		Prompt%id%05 <それなら、クビになった後にでも%JF2の側に来ればいい%JV_F_YO。>
		CPrompt%id%05 <ifG React 15 Accept>
		Prompt%id%06 <別に、勝ちを譲ってやってもいいんだ%JG_GA……。>
		CPrompt%id%06 <ifG React 35 ifInsight HardSkilltar StoryDL Accept>
		Prompt%id%07 <%JR_YES、%JS2の勝ちってことでいい%JG_YO。>
		Prompt%id%08 <%JR_NO、ちょっと揺さぶって遊んでみただけ%JG_DAYO。>
	end
	inv
		NPC Mecha Pilot
		Initiative
		ElectronicWarfare
		SpotWeakness
		Talent 5
		Talent 8
		Talent 16
		MOTIVATION:Professional
	end


Content
	name <E-Member Battle>
	% desc <Fight a member of the enemy faction.>
	desc <敵勢力のメンバーと戦う。>
	requires <*:CS_MechaEncounter ~&Raiders F:++ &Secondary -!Ne -!Lo>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy fighter
	Element3 <Character HasMecha !Global !Comrade -2>
	Place3 <2 (Enemies) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %3% StoryDL>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 4 ForceChat %3%  History 1 CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You fought %name3% of \FACTION &EnemyFac .>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated %name3%'s lance.>
		% Msg4 <You face a mecha force led by %name3% of \FACTION &EnemyFac .>
		Msg1 <\FACTION &EnemyFac の %name3% と戦った。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <%name3% の部隊を撃破した。>
		Msg4 <\FACTION &EnemyFac の %name3% に率いられたメック部隊と対峙した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 80>
			GoSmallDeploy <WMecha 2 StoryDL 40>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		Persona 3
		special <UNLISTED>
		greeting <if= PlotStatus %plotid% %id% else %pop% Goto GoGreet>
		*GoGreet <*BattleChallenge GoThemeExpo na>
		*GoThemeExpo <*THEME_EXPO&Enemy na>
	end

Content
	name <They Are A Pirate>
	% desc <Your enemy has been hired by a pirate captain.>
	desc <敵は海賊の頭領に雇われている。>
	requires <*:CS_MechaEncounter E:++ F:-- -!Ne (L:FCOMS|L:MAQUI|L:RISHI) ~E:THIEF ~E:M.mer ~C:POLIC ~P:POLIC ~P:SILKN ~P:ROCKE>
	changes <F:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the pirate faction
	% E4 is the enemy fighter
	% E5 is the enemy NPC
	Element3 <Faction (CRIHN|REDMA) !XClude -3 -ArchAlly>
	Element4 <Prefab>
	Place4 <2 (Enemies) sd enemy>
	Element5 <Grab 1>
	Place5 </>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %4% StoryDL SetNPCFaction %4% %3%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	%% Debriefing Message
	% Msg%id%11_1 <%name5% has taken up the black flag. I guess that means we're going to be taking on all of %name3%, now.>
	% CMsg%id%11_1 <ifChatNPCAlly Accept>
	Msg%id%11_1 <%name5% は海賊旗を掲げた%JV_KA_Q%JV_SIL。つまりこれで、%JF2%JF_TACHIは %name3% 全体を相手にすることになったわけ%JV_M_DA%JV_F_NE%JV_SIL。>
	CMsg%id%11_1 <ifChatNPCAlly Accept>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		% rumor%id% <%name5% has a meeting planned with some unsavory types.>
		rumor%id% <%name5% は何やらキナ臭い相手と会う予定がある>
		MapWidth 50
		MapHeight 50

		% Start <if= L2 0 L= 2 1   Alert 4 Alert 5 ForceChat %4% &SetEnemyFac %3%  PCFEnemy %3%  Debriefing %id%11  History 1 CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		Start <if= L2 0 L= 2 1   Alert 4 Alert 5 ForceChat %4% &SetEnemyFac %3%  PCFEnemy %3%  SetDebriefing %id%11  History 1 CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You learned that %name3% hired %name5%.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated %name4%'s lance.>
		% Msg4 <You catch a glimpse of %name5%'s mecha speeding off in the distance, and immediately give chase.>
		% Msg5 <Suddenly, you are attacked by a group of pirates who were apparently traveling with \OPR %5% .>
		Msg1 <%name3% が %name5% を雇ったことが判明した。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <%name4% の部隊を撃破した。>
		Msg4 <逃げていく %name5% のメックの僅かな機影を遠方に捉え、すぐに追跡を開始した。>
		Msg5 <すると突然、\SPR %5%の同行者であると思われる海賊の一団から襲撃を受けた。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction %3%   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 100>
			GoSmallDeploy <WMecha 2 StoryDL 60>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		Persona 4
		special <UNLISTED>
		greeting <if= PlotStatus %plotid% %id% else %pop% Goto GoGreet>
		GoGreet <NewChat Say 1 AddChat 1 AddChat 2>
		*result1 <*THEME_EXPO&Enemy na>
		result2 <AddEasygoing d10   Goto result1>
		% Msg1 <You must be \PC ... %name5% said \SPR %5% had a fan club when \SPR %5% signed up. You better know, you pick a fight with one of us and you pick a fight with all %name3%.>
		% prompt1 <I'm willing to take those odds.>
		% prompt2 <My fight is just with %name5%, not with you.>
		Msg1 <%JS_AGGが \PC %JV_M_DA%JV_NA……契約の時、%name5% は自分にはファンクラブがあると言っていたから%JV_NA。%JS_AGGも分かってる%JV_DAROU、ウチの誰かに喧嘩を売れば、それは %name3% 全体を敵に回すってこと%JG_DAYO。>
		prompt1 <まとめて相手をしてやる%JG_YO。>
		prompt2 <%JF2の敵は %name5% だけ%JG_DAYO。面倒臭い%JG_SY。>
	end
	inv
		NPC Pirate
	end

Content
	name <You Haven't Won Yet>
	% desc <PC waels on Enemy's henchmen, Enemy shows up immediately to wael on PC.>
	desc <PC が敵の取り巻きを叩くと、PC を叩くためにただちに本人が現れる。>
	requires <*:CS_MechaEncounter (E:M.pro|E:M.see) (E:A.---|E:A.sr_) -!Ne -&Secondary>
	changes <E:A>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the encounter for the second fight. Brutal!
	% E4 is the enemy
	% E5 is a secret- that there's an ambush waiting!
	Element3 <Prefab>
	Place3 <1>
	Element4 <Grab 1>
	Place4 <3 (Enemies)>
	Element5 <Prefab>

	% P%id%01 = Initialization Counter
	% P%id%02 = Decimation Counter
	% P%id%03 = Reinforcements Counter
	% P%id%04 = Learn Secret Counter

	update <if= P%id%01 0 P= %id%01 1   SetPlotStatus %plotid1% %id1%  SetPlotStatus %plotid2% %id2%  NPCLevel %4% StoryDL>

	.%id1%_%plotid1%_GoDecimation <P= %id%02 1>
	.%id1%_%plotid1%_GoReinforcements <P= %id%03 1>
	.%id2%_%plotid2%_GoLearnSecret <P= %id%04 1>


	% SubPlot1 is the Gain Advantage task
	% SubPlot2 is the Learn Secret task
	SubPlot1 <*:CS_GainAdvantageVsNPC&Decimation&Reinforcements 4>
	SubPlot2 <*:CS_LearnSecretAboutNPC 5 4>


	sub
		MetaScene 2 2
		% This first scene is a pretty easy fight. If the PC doesn't know that there
		% is going to be an ambush, all advantages will be spent here. Otherwise the
		% advantages will be spent in the second, tougher encounter.
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  CancelSubPlot %plotid1%  CancelSubPlot %plotid2%  if= p%id%04 0 if# P%id%03 0 Alert 2>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   Alert 4 History 4   Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100   SALVAGE   Alert 3   SetEncounterActive %3% Return>
		end <SetEncounterInactive %2%  if= p%id%04 0 if# P%id%03 0   Alert 5>

		% Msg1 <You locate the raiders. This looks like it's going to be a pretty easy fight.>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated the henchmen... but where is %name4%?>
		% Msg4 <You were defeated by %name4%'s henchmen.>
		% Msg5 <Your reinforcements head off for repairs.>
		Msg1 <賊の居場所を突き止めた。見るからに楽な戦いになりそうだ。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <取り巻きを退けた……しかし、%name4% はどこに？>
		Msg4 <%name4% の取り巻きに敗れた。>
		Msg5 <援軍は修理のために帰投していった。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%04 0 else GoBigDeploy if# P%id%02 0 else GoBigDeploy   WMecha 2 StoryDL 60>
			GoBigDeploy <WMecha 2 StoryDL 90>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if= p%id%04 0 if# P%id%03 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		MetaScene 3 2
		% This second scene is much harder. The Enemy is here, along with a full
		% complement of guards... unless the PC managed to get both the advantage and
		% the secret, that is.
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		special <ARENA>
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1 Monologue %4% 2  History 4  if# p%id%04 0  PCMonologue 3>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   Monologue %4% 5  History 6   Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100   SALVAGE   Alert 7 Monologue %4% 8  History 9  SetXXRAttitude %4% XXR_A_IsEqual  Trigger0 .%id%_%plotid%_GoWin  WinSubPlot %plotid%>
		end <SetEncounterInactive %3% ifNPCDead %4% Print 10>

		% Msg1 <Without warning, you are attacked by %name4%!>
		% Msg2 <My associates have failed one too many times, \PC . Now I'll finish you myself.>
		% Msg3 <Fortunately I saw this coming.>
		% Msg4 <After defeating \PPR %4% lance, %name4% appeared to fight you personally.>
		% Msg5 <It appears that you aren't so great after all.>
		% Msg6 <You were defeated by %name4%.>
		% Msg7 <You have defeated %name4% and all of \PPR %4% lancemates.>
		% Msg8 <It appears that I was wrong about you, \PC ... You are a worthy adversary. I look forward to our next battle.>
		% Msg9 <You defeated %name4%, earning \PPR %4% respect.>
		% Msg10 <After the battle, you notice that %name4%'s cockpit is mysteriously empty.>
		Msg1 <何の前触れもなく、%name4% が襲い掛かってきた！>
		Msg2 <手下どもはあまりにも使えない奴ばかりだった。\PC、この%JF2が直々に引導を渡してくれる%JV_F_WA。>
		Msg3 <思ってた通りの展開%JG_DAYO。>
		Msg4 <手勢を撃退された %name4% が、決着を付けるために１人で現れた。>
		Msg5 <結局のところ、%JS_AGGはその程度だったということ%JG_DA。>
		Msg6 <%name4% に敗れた。>
		Msg7 <%name4% とその僚機をすべて撃破した。>
		Msg8 <%JS_AGGのことを見くびっていたよう%JV_M_DA%JV_NA、\PC ……%JS_AGGは間違いなく強敵%JG_DA。次に戦うのを楽しみにしている%JV_ZO。>
		Msg9 <%name4% を撃破し、強敵として認められた。>
		Msg10 <戦いが終わると、%name4% のコクピットは既にもぬけの殻になっていた。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%04 1 else GoBigDeploy if# P%id%02 0 else GoBigDeploy   WMecha 2 StoryDL 40>
			GoBigDeploy <WMecha 2 StoryDL 100>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if= p%id%04 1 if# P%id%03 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

	end
	inv
		STC CORE-MECHAAMBUSH-ACTIVATABLE
		name <Surprise Ambush>

		Secret
		% Msg <%name4% has been watching you; \SPR %4% 's not going to let you get away this time.>
		Msg <%name4% は%JS2を監視していた%JV_F_WA。今度こそ逃がすつもりはなさそう%JG_DAYO。>
	end

Content
	name <Not Part of the Job>
	% desc <PC finds enemy, but fighting PC isn't part of the job.>
	desc <PC が敵を見つけたが、彼の仕事には PC と戦うことは含まれていない。>
	requires <*:CS_MechaEncounter E:++ (E:A.equ|E:A.env|E:A.adm|E:A.---) E:M.--- ~E:MILIT ~E:POLIT ~E:GOOD_ -&Secondary>
	changes <E:M>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy
	% E4 is the secondary enemy
	Element3 <Grab 1>
	Place3 </>
	Element4 <Prefab>
	Place4 </>

	% P%id%01 = Initialization Counter

	% At initialization, prepare E4 for combat
	update <if= P%id%01 0 P= %id%01 1  NPCLevel %4% StoryDL  MoveNPC %4% %2%  SetNPCTeam %4% 2  SetNPCFaction %4% &EnemyFac>

	% This subplot must propgate the effects of its own subplot backwards to
	% the parent plot. Yahoo.
	.%id1%_%plotid1%_GoWin  <Trigger0 .%id%_%plotid%_GoWin>
	.%id1%_%plotid1%_GoLoss <Trigger0 .%id%_%plotid%_GoLoss>

	% SubPlot1 = The enemy mission you have to stop
	SubPlot1 <*:CS_StopNPCMission&IsEnemyNPC&Secondary 3>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 30
		MapHeight 30

		% At startup, E3 and E4 argue over the situation.
		% You must win this fight, or E4's forces will complete E3's mission.
		Start <if= L2 0 L= 2 1  Alert 4 Monologue %4% 1 Monologue %3% 2 Monologue %4% 3 Alert 5 History 6   SetXXRMotivation %3% XXR_M_Professional>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   LoseRenown  CancelSubPlot %plotid%  Trigger0 .%id%_%plotid%_GoLoss  SetXXRAttitude %4% XXR_A_IsSenior>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 7 SMemo 7   SetPlotStatus %plotid1% %id1%  SetXXRAttitude %4% XXR_A_IsJunior>
		end <SetEncounterInactive %2% CancelSubPlot %plotid%>
		% Msg1 <Look, it's that pilot you told us about! Let's go fight \OPR 0 ...>
		% Msg1_1 <Look, it's \PC ! This is our big chance to finish \OPR 0 off once and for all...>
		% Msg1_2 <Say, isn't that the pilot who's always causing you problems? Let's go fight \OPR 0 !>
		% Msg2 <Fighting \PC isn't part of the plan, %name4% . You're jeopardizing our mission.>
		% Msg2_1 <We aren't here to pick fights, %name4% . We've got a mission to complete and you're jeopardizing it right now.>
		% CMsg2_1 <ifNPCHeroic Accept>
		% Msg2_2 <As much as I'd love \PC 's head on a stick, that's not why we came to \SCENE RootSceneID . We have a mission to complete and I'm not gonna let you muck it up.>
		% CMsg2_2 <ifNPCVillainous Accept>
		% Msg3 <Bah, you go do your precious mission. I'll catch up with you when I'm finished here.>
		% Msg3_1 <Got to do everything by the book, don't you %name3%? You go on ahead. I'll catch up when I'm finished here.>
		% Msg3_2 <You must think \PC 's really something, don't you? I'll beat \OPR 0 easy, then go finish your stupid mission.>
		% Msg4 <You face a large force of mecha led by %name3%.>
		% Msg5 <If you want to stop %name3%'s plan, it looks like you'll need to defeat %name4% first.>
		% Msg6 <You fought %name4%, while %name3% left to complete a mission.>
		% Msg7 <You defeated %name4%. Now, it's time to find %name3%.>
		Msg1 <あれ%JV_M_DA%JV_F_YO、%JS2が言ってたパイロット%JG_DA！ すぐに仕掛け%JV_YOU……！>
		Msg1_1 <あそこ%JV_M_DA%JV_F_YO、\PC がいる！ あいつを始末する絶好のチャンスだ%JV_ZO……！>
		Msg1_2 <%JR_HEY、あれがいつも%JS2を悩ませてるパイロットじゃないの%JV_KA_Q？ すぐに仕掛け%JV_YOU……！>
		Msg2 <\PC と戦うのは計画の内にはない%JV_ZO、%name4%。無用なリスクを持ち込むんじゃない%JV_F_WA%JV_F_YO。>
		Msg2_1 <戦闘に来てるんじゃない%JV_ZO、%name4%。それは本来の任務を危険に晒す行為%JG_DA。>
		CMsg2_1 <ifNPCHeroic Accept>
		Msg2_2 <あれを晒し首にしてやりたいのは同じだ%JG_GA、それは \SCENE RootSceneID に来た目的じゃない%JV_F_WA。%JF2%JF_TACHIには任務がある%JV_N%JV_M_DA、それに唾を吐くような真似は許さない%JV_ZO%JV_F_YO。>
		CMsg2_2 <ifNPCVillainous Accept>
		Msg3 <バカ%JV_M_DA%JV_NA、なら御大事なミッションは%JS_AGGが先に行って片付けてくればいい%JV_DAROU。%JF2はあれを始末してから合流する%JV_F_WA。>
		Msg3_1 <紙に書いてあることしかできないの%JV_KA_Q、%name3%？ %JS2は先に行けばいい%JV_DAROU、こっちはあれを始末してから合流する%JV_F_WA。>
		Msg3_2 <そんなに \PC が怖いの%JV_KA_Q？ あんなものはさっさと始末して、その下らない任務はその後で片付ければいい%JG_SK。>
		Msg4 <%name3% に率いられたメックの大部隊に遭遇した。>
		Msg5 <%name3% の計画を阻止するためには、まず %name4% を撃破する必要があるようだ。>
		Msg6 <%name4% と戦っている間に、%name3% は計画の遂行のために去っていった。>
		Msg7 <%name4% を撃破した。次は %name3% を見つける番だ。>

		sub
			team 1
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			SetEnemy 1
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 70>
			ParaX 25
			ParaY 25
		end
	end
	inv
		NPC Mercenary
		job_desig <MOOK_>
		chardesc passionate melancholy
	end


Content
	name <You Can't Stop Me>
	% desc <Enemy NPC taunts PC, then leaves to complete some mission.>
	desc <敵 NPC は PC を挑発し、何かの任務を片付けるために去っていく。>
	requires <*:CS_MechaEncounter E:++ E:A.nme -&Secondary>
	changes <E:A>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy
	Element3 <Grab 1>
	Place3 </>

	% This subplot must propgate the effects of its own subplot backwards to
	% the parent plot. Yahoo.
	.%id1%_%plotid1%_GoWin  <Trigger0 .%id%_%plotid%_GoWin>
	.%id1%_%plotid1%_GoLoss <Trigger0 .%id%_%plotid%_GoLoss>

	% SubPlot1 = The enemy mission you have to stop
	SubPlot1 <*:CS_StopNPCMission&IsEnemyNPC&Secondary 3>

	sub
		Persona 3
		special <Unlisted>
		greeting <if= PlotStatus %plotid% %id% else GoChat EndChat Say %id%01 AddCHat %id%01>
		GoChat <NewChat SayAnything>
		result%id%01 <EndCHat Say %id%02 Print %id%03>
		% Msg%id%01 <\PC , so we finally meet. I am %name3%. I understand that you gave my men some trouble back there.>
		% Msg%id%02 <I'd advise you to not meddle in my affairs again. I've got a mission to complete and no insignificant worm like yourself is going to stand in my way. Here's a small taste of what you can expect should we happen to meet again.>
		% Msg%id%03 <%name3% leaves the area.>
		% Prompt%id%01 <No, I gave them a lot of trouble.>
		Msg%id%01 <\PC、ようやく会えた%JV_F_WA%JV_NA。%JF2が %name3% %JV_M_DA%JV_F_YO。%JF2の部下が少々世話になったらしい%JV_F_WA%JV_NA%JV_SIL。>
		Msg%id%02 <%JF2の仕事の邪魔をするのはもう止めておけと忠告しておく%JV_ZO。%JF2の成すべき計画に、%JS_AGGのようなウジ虫の入り込む余地はない。次があったらどういうことになるのか、その片鱗を味わっていくといい%JV_F_WA。>
		Msg%id%03 <%name3% はこのエリアを去った。>
		Prompt%id%01 <少々じゃない%JV_F_WA、相当に%JG_DAYO。>

		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 30
		MapHeight 30

		% Whether you win or lose this fight isn't important. Of course, there are some benefits
		% to winning... The timer starts from the conclusion of the fight, because I can be just
		% as cruel to my NPCs as I am to the PC.
		Start <if= L2 0 L= 2 1   ForceChat %3%  StoryNote 1   SetXXRAttitude %3% XXR_A_IsSenior>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   AddRenown -1  SetPlotStatus %plotid1% %id1%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 2   SetPlotStatus %plotid1% %id1%>
		end <SetEncounterInactive %2% CancelSubPlot %plotid%>

		% Msg1 <You fought %name3%'s lancemates, while \SPR %3% left to complete a mission.>
		% Msg2 <You defeated %name3%'s lancemates, but where did \SPR %3% go?>
		Msg1 <%name3% の部隊と戦っている間に、\SPR %3%自身は目的の遂行のために去っていった。>
		Msg2 <%name3% の僚機を撃破した。しかし、\SPR %3%自身はいったいどこへ？>

		sub
			team 1
			SetEnemy 2
			ParaX 5
			ParaY 5

			team 2
			SetEnemy 1
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 100>
			ParaX 25
			ParaY 25
		end
	end

Content
	name <Learn of Enemy Leader>
	% desc <Fight some raiders; learn the identity of their leader, who isn't present.>
	desc <賊と交戦し、不在だった彼らのリーダーの正体を明らかにする。>
	requires <*:CS_MechaEncounter &Raiders E:-->
	changes <E:++>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the new enemy
	Element3 <NewNPC -2 -7>
	Place3 </>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>

	%%  Debriefing Message
	% Msg%id%11 <%name3%, you say? I don't know anything about \OPR %3% ... I expect you'll find out shortly.>
	% Msg%id%11_1 <I think I've heard of this %name3%. They say \SPR %3% works for \FACTION &EnemyFac .>
	% CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>
	% Msg%id%11_2 <I know about %name3%... \SPR %3% 's clashed with \FACTION &AllyFac before. I believe \SPR %3% works for \FACTION &EnemyFac .>
	% CMsg%id%11_2 <ifFactionExists &EnemyFac ifFactionExists &AllyFac Accept>
	% Msg%id%11_3 <%name3% has fought with \FACTION &AllyFac before. I advise you to take care; you'll probably be crossing paths with \OPR %3% again.>
	% CMsg%id%11_3 <ifFactionExists &AllyFac Accept>
	Msg%id%11 <%name3%？ 何も情報はない%JV_F_WA%JV_NA……すぐに%JS2自身で確かめることになる%JV_DAROU。>
	Msg%id%11_1 <その %name3% という人物は聞いたことがあると思う%JV_F_WA。確か、\FACTION &EnemyFac の手の者だと……。>
	CMsg%id%11_1 <ifFactionExists &EnemyFac Accept>
	Msg%id%11_2 <%name3% のことは知っている%JV_ZO……\SPR %3%は以前に \FACTION &AllyFac と関わりがあった%JG_NDA。奴らの手先となっていると考えて間違いない%JV_DAROU。>
	CMsg%id%11_2 <ifFactionExists &EnemyFac ifFactionExists &AllyFac Accept>
	Msg%id%11_3 <%name3% は以前に \FACTION &AllyFac と戦ったことがある%JG_NDA。よく注意しておいたほうがいい%JV_ZO、\SPR %3%とはまた道を交えることになる%JV_DAROUから%JV_NA。>
	CMsg%id%11_3 <ifFactionExists &AllyFac Accept>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  TeamMonologue 2 2   SetXXRAttitude %3% XXR_A_NeverMet  StoryNote 3   &SetEnemyNPC %3%  SetDebriefing %id%11  CancelSubPlot %plotid1% if# P%id%02 0 Alert 6>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1   Alert 4   Trigger0 .%id%_%plotid%_GoLoss>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 5   Trigger0 .%id%_%plotid%_GoWin>
		end <SetEncounterInactive %2%>

		% Msg1 <You locate the group of raiders that you've been searching for.>
		% Msg2_1 <Huh, who's this? Another challenger for %name3%, I guess... \SPR %3% 's not here right now, but the rest of us should be able to handle you just fine.>
		% Msg2_2 <Look over there, I guess that's what passes for the town guard in \SCENE RootSceneID . %name3%'s gonna reward us if we defeat \OPR 0 ourselves!>
		% Msg2_3 <Hey look, it's a cavalier! I know %name3% hates for us to attack without talking first, but \SPR %3% 's not here so let's get to it!>
		% CMsg2_3 <ifG NPCHeroism %3% 0 Accept>
		% Msg2_4 <Look at that, an innocent little junior cavalier. %name3%'s gonna be sorry \SPR %3% missed this carnage, but \SPR %3% won't forgive us if we let that creep live!>
		% CMsg2_4 <ifG 0 NPCHeroism %3% Accept>
		% Msg2_5 <Crap, we're under attack, and %name3% isn't here! What would \SPR %3% say to do? Quick you lunks, defend the honor of \FACTION &EnemyFac !>
		% CMsg2_5 <ifFactionExists &EnemyFac Accept>
		% Msg3 <You fought the raiders, but their leader %name3% wasn't present.>
		% Msg4 <If the raiders were capable of this by themselves, you're probably lucky that %name3% wasn't with them.>
		% Msg5 <You have defeated the raiders, but their leader %name3% is nowhere to be found.>
		% Msg6 <Your reinforcements are here, as promised.>
		Msg1 <行方を追っていた賊の一団を発見した。>
		Msg2_1 <誰%JV_M_DA%JV_F_YOコイツは？ 大方、また %name3% に歯向かう連中なんだろう%JG_GA。%JT_Aがいなくても、%JF2%JF_TACHIだけで十分に始末を付けられる%JV_DAROUよ。>
		Msg2_2 <あれは何%JV_M_DA？ \SCENE RootSceneID だとあんなのでも守備隊に入れる%JV_N%JV_M_DA%JV_NA。%JF2%JF_TACHIだけで片付ければ、%name3% から報酬が出る%JV_DAROUよ！>
		Msg2_3 <メック乗りのお出まし%JV_KA_Q%JV_F_NE！ 交渉無しに仕掛けるのは %name3% がヘソを曲げるだろう%JG_GA、この場に居ないなら関係ない%JV_F_WAよ%JV_NA！>
		CMsg2_3 <ifG NPCHeroism %3% 0 Accept>
		Msg2_4 <おやおや、純真無垢な新米パイロットの登場%JV_KA_Q%JV_F_NE。%name3% は殺しの機会を逃して残念がるだろう%JG_GA、この虫を生かして帰したらこっちが酷い目に遭うから%JV_NA！>
		CMsg2_4 <ifG 0 NPCHeroism %3% Accept>
		Msg2_5 <ああ敵が来た、%name3% のいない時に！ %JT_Aだったらどう命令する%JV_F_NO……？ ああもうノロマども、\FACTION &EnemyFac の誇りを守る%JG_SK！>
		CMsg2_5 <ifFactionExists &EnemyFac Accept>
		Msg3 <賊と戦ったが、そのリーダーであるらしい %name3% は不在だった。>
		Msg4 <ただの賊だけでこれだけの力を持っているなら、%name3% が不在だったのは幸運だったのだろう。>
		Msg5 <賊を排除したが、彼らのリーダーだという %name3% の姿はどこにもなかった。>
		Msg6 <味方の援軍が到着した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   WMecha 2 StoryDL 150>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end
	end

Content
	name <Henchmen Battle>
	% desc <Fight some henchmen of the enemy NPC.>
	desc <敵 NPC の取り巻きの一部と戦う。>
	requires <*:CS_MechaEncounter ~&Raiders E:++ -E:A.--- &Secondary -!Md -!Hi -!Ex>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   TeamMonologue 2 1  History 2 CancelSubPlot %plotid1% if# P%id%02 0 Alert 3>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 4   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1_1 <Look, it's \PC ! Whoever defeats \OPR 0 is going to be rewarded by \PERSONA &EnemyNPC !>
		% Msg1_2 <>
		% Msg1_3 <>
		% Msg1_4 <>
		% Msg1_5 <>
		% Msg2 <You fought a group of \PERSONA &EnemyNPC 's henchmen.>
		% Msg3 <Your reinforcements are here, as promised.>
		% Msg4 <You have defeated the raiders.>
		Msg1_1 <あれは \PC %JG_DA！ 倒せば \PERSONA &EnemyNPC から報酬が出る%JV_ZO！>
		Msg1_2 <>
		Msg1_3 <>
		Msg1_4 <>
		Msg1_5 <>
		Msg2 <\PERSONA &EnemyNPC の取り巻きの一団と戦った。>
		Msg3 <味方の援軍が到着した。>
		Msg4 <賊を撃破した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 150>
			GoSmallDeploy <WMecha 2 StoryDL 90>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end
	end

Content
	name <MIX Master>
	% desc <Instead of containing an encounter itself, this one just pawns things off on the MIX.>
	desc <敵を直接定義する代わりに、ここでは MIX 系統の敵定義を利用する。>
	requires <*:CS_MechaEncounter ~&Raiders E:++ ~F:++ ~P:++ -&Beancounter>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the Enemy NPC
	Element3 <Grab 1>

	% P%id%01 = Initialization Counter
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoWin  <Trigger0 .%id%_%plotid%_GoWin>
	.%id1%_%plotid1%_GoLoss <Trigger0 .%id%_%plotid%_GoLoss>

	% SubPlot1 = MIX Encounter
	SubPlot1 <*:CS_MIX_Encounter 1 2 3>


%  ***************************
%  ***   OMEGA  MISSIONS   ***
%  ***************************
%
% In certain cases, the core story development will outpace the PC's
% advancement. This can happen if the PC loses some episodes after triggering
% their context changes. In this case, the following episodes will be
% omega missions until the PC reaches the next difficulty band.

Content
	name <Rookie Omega>
	% desc <Can't face a professional, senior enemy until !Lo at least>
	desc <難度レベルが少なくとも !Lo になるまでは、Professional や Senior ランクの敵は出現させない>
	requires <*:CS_MechaEncounter (E:A.sr_|E:A.ant|E:A.sec|E:A.equ|E:A.env|E:A.pch|E:A.hat|E:A.mut|E:A.obs) (E:M.pro|E:M.com|E:M.ggd|E:M.see|E:M.rev|E:M.cha|E:M.nih) ~!Lo -!Md -!Hi -!Ex -&Beancounter>
	% Certain advanced motivations/attitudes will also trigger this omega
	% state, even though they may not be part of the beanpole or even strictly
	% possible at this time.

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy NPC
	Element3 <Grab 1>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1%>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 1  Monologue %3% 2  History 3 CancelSubPlot %plotid1% if# P%id%02 0 Alert 4>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 5   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You arrive just in time to see %name3%'s lance finishing off a rival cavalier.>
		% Msg1_1 <You arrive just in time to see %name3%'s men finishing off a lance from \FACTION &AllyFac .>
		% CMsg1_1 <ifFactionExists &AllyFac Accept>
		% Msg1_2 <You arrive just in time to see %name3%'s lance finishing off a ship belonging to \FACTION &AllyFac .>
		% CMsg1_2 <ifFactionExists &AllyFac Accept>
		% Msg2_1 <You're too late, \PC . My work here is finished... but you may provide some entertainment for my lance.>
		% Msg2_2 <My work here is finished. I don't want to fight you, \PC , but you need to learn to keep out of our plans.>
		% CMsg2_2 <ifNPCHeroic Accept>
		% Msg2_3 <How does it feel to watch your comrades die and be unable to save them? My work here is finished... Men, whoever brings me \PC 's severed head wins an instant promotion.>
		% CMsg2_3 <ifNPCVillainous Accept>
		% Msg2_4 <You're too late, \PC . I hope you can understand how important the work of \FACTION &EnemyFac is... but I'm afraid that I can't allow you to interfere. Lance, please stop \OPR 0 .>
		% CMsg2_4 <ifNPCHeroic ifFactionExists &EnemyFac Accept>
		% Msg2_5 <You're too late to save them, \PC ; I've killed them all. The same will happen to you if you continue to oppose \FACTION &EnemyFac ... Men, defeat this worm.>
		% CMsg2_5 <ifNPCVillainous ifFactionExists &EnemyFac Accept>
		% Msg3 <You were attacked by %name3%'s henchmen.>
		% Msg4 <Your reinforcements are here, as promised.>
		% Msg5 <You have defeated %name3%'s henchmen.>
		Msg1 <あなたが到着したのは、ちょうど %name3% の部隊が交戦相手のメックにとどめを刺した瞬間だった。>
		Msg1_1 <あなたが到着したのは、ちょうど %name3% の部隊が \FACTION &AllyFac の部隊にとどめを刺した瞬間だった。>
		CMsg1_1 <ifFactionExists &AllyFac Accept>
		Msg1_2 <あなたが到着したのは、ちょうど %name3% の部隊が \FACTION &AllyFac 所属の船を沈めた瞬間だった。>
		CMsg1_2 <ifFactionExists &AllyFac Accept>
		Msg2_1 <遅かった%JV_F_WA%JV_NA、\PC。ここでの仕事はもう終わった後%JV_M_DA%JV_F_YO……%JF2の手下の遊びにでも付き合ってやるといい%JV_F_WA。>
		Msg2_2 <ここでの仕事はもう終わった%JV_F_WA。%JF2には%JS_AGGと戦う気はない%JG_GAね、\PC、いい加減に人の邪魔をしないことを学んだほうがいい%JV_F_WA%JV_NA。>
		CMsg2_2 <ifNPCHeroic Accept>
		Msg2_3 <目の前で仲間を見殺しにした気分はどう%JV_M_DA？ %JF2のここでの仕事はもう終わった……お前たち、\PC の生首を持ってくればその場で昇進させてやる%JV_ZO%JV_F_YO。>
		CMsg2_3 <ifNPCVillainous Accept>
		Msg2_4 <遅かった%JV_F_WA%JV_NA、\PC。\FACTION &EnemyFac の計画がどれだけ重要なのか理解してもらえるといいんだ%JG_GA……とにかく、邪魔をさせるわけにはいかない。みんな、\SPR 0を阻止して%JG_R。>
		CMsg2_4 <ifNPCHeroic ifFactionExists &EnemyFac Accept>
		Msg2_5 <助けに来るには遅すぎた%JV_F_WA%JV_NA、\PC。もう全員殺した後%JG_DAYO。\FACTION &EnemyFac への敵対を続けるなら、%JS_AGGも同じ目に遭うことになる%JV_F_WA……お前たち、あのウジ虫を潰す%JG_NDA。>
		CMsg2_5 <ifNPCVillainous ifFactionExists &EnemyFac Accept>
		Msg3 <%name3% の取り巻きに攻撃された。>
		Msg4 <味方の援軍が到着した。>
		Msg5 <%name3% の取り巻きを撃破した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 160>
			GoSmallDeploy <WMecha 2 StoryDL 100>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end
	end


Content
	name <Omega State>
	% desc <Fight a member of the enemy faction. This subplot only occurs when the beanpole is ended.>
	desc <敵勢力のメンバーと戦う。このサブプロットは beanpole 系列のイベントが終了する時に発生する。>
	% If the enemy NPC is both nihilistic and obsessed with the PC, no
	% further character development is possible.
	requires <*:CS_MechaEncounter E:A.obs E:M.nih F:++ -&Beancounter>

	% E1 is the outdoors scene where this encounter will be placed
	% E2 is the metascene to be used for this encounter
	% E3 is the enemy fighter
	Element3 <Character HasMecha !Global !Comrade -2 NeverFail>
	NeverFail3 <Mecha Pilot>
	Place3 <2 (Enemies) sd enemy>

	% P%id%01 = Initialization Counter
	% P%id%02 = Have gained reinforcements
	% P%id%03 = Have gained decimation
	update <if= V%id%01 0 V= %id%01 1   SetPlotStatus %plotid1% %id1% NPCLevel %3% StoryDL>

	.%id1%_%plotid1%_GoReinforcements <P= %id%02 1>
	.%id1%_%plotid1%_GoDecimation     <P= %id%03 1>

	% SubPlot1 = Gain Advantage vs Raiders
	SubPlot1 <*:CS_GainAdvantageVsMecha&Reinforcements&Decimation>

	sub
		MetaScene 2 2
		% L1 = Encounter Over Counter
		% L2 = Initialization Counter
		MapWidth 50
		MapHeight 50

		Start <if= L2 0 L= 2 1   Alert 4 ForceChat %3%  History 1 CancelSubPlot %plotid1% if# P%id%02 0 Alert 2>
		nu1 <if= T1 0   Return   if= V1 0 V= 1 1         Trigger0 .%id%_%plotid%_GoLoss LoseSubPlot %plotid%>
		nu2 <if= T2 0   if= V1 0 V= 1 1   XPV 100  AddRenown 1   SALVAGE   Alert 3   Trigger0 .%id%_%plotid%_GoWin WinSubPlot %plotid%>
		end <SetEncounterInactive %2%>

		% Msg1 <You fought %name3% of \FACTION &EnemyFac .>
		% Msg2 <Your reinforcements are here, as promised.>
		% Msg3 <You have defeated %name3%'s lance.>
		% Msg4 <You face a mecha force led by %name3% of \FACTION &EnemyFac .>
		Msg1 <\FACTION &EnemyFac の %name3% と戦った。>
		Msg2 <味方の援軍が到着した。>
		Msg3 <%name3% の部隊を撃破した。>
		Msg4 <\FACTION &EnemyFac の %name3% に率いられたメック部隊と対峙した。>

		sub
			team 1
			setally 3
			SetEnemy 2
			ParaX 5
			ParaY 10

			team 2
			name <Enemies>
			SetEnemy 1 3
			Deploy <if= PlotStatus %plotid% %id% SetSelfFaction &EnemyFac   if= p%id%03 0 else GoSmallDeploy WMecha 2 StoryDL 100>
			GoSmallDeploy <WMecha 2 StoryDL 60>
			ParaX 45
			ParaY 45

			team 3
			setally 1
			setenemy 2
			Deploy <if= PlotStatus %plotid% %id%  if# P%id%02 0   WMecha 3 StoryDL 60>
			ParaX 10
			ParaY 5
		end

		Persona 3
		special <UNLISTED>
		greeting <if= PlotStatus %plotid% %id% else %pop% Goto GoGreet>
		*GoGreet <*BattleChallenge GoThemeExpo na>
		*GoThemeExpo <*THEME_EXPO&Enemy na>
	end

