%
%  ************************************
%  ***      CORE  STORY  PLOTS      ***
%  ***      EASY  MONEY  TRACK      ***
%  ************************************
%
% The PC is looking for easy money- steer them towards a *CS_SEEKPLUNDER component.
%

Plot
	name <Thief Tipoff>
	% desc <An unaligned will tip off the PC.>
	desc <流れ者が PC に儲け話を寄越す。>
	requires <*CORE_EMO_ ~P:-->

	% E1 is a local public scene
	% E2 is the thief
	element1 <Scene !Near -7 public (building|meeting)>
	element2 <Character !Near 1 THIEF Criminal NeverFail>
	Place2 <1 (Citizens) pass>
	NeverFail2 <Thief>

	end <if= PlotStatus %plotid% 0 ifNPCDead %2% LoseEpisode>

	% SubPlot1 is the plunder-seeking bit.
	subplot1 <*CS_SeekPlunder>

	sub
		Persona 2
		% rumor0 <%name2% knows something that you might want to know.>
		rumor0 <%name2% は%JS2が知りたがるかもしれない話を知っている>
		greeting <if= PlotStatus %plotid% 0 else .%id%_GoChat Goto .%id%_GoGreet>
		.%id%_GoChat <RevertPersona>
		*.%id%_GoGreet <*YouCouldUseHelp .%id%_GoBriefing>
		.%id%_GoBriefing <NewChat Say %id%01 SMemo %id%02 History %id%03 SetPlotStatus %plotid1% %id1%>
		% Msg%id%01 <\HINT %id1% I figured that you might want to know.>
		% Msg%id%02 <%name2% gave you a hot tip. \HINT %id1%>
		% Msg%id%03 <%name2% gave you a hot tip.>
		Msg%id%01 <\HINT %id1% %JS2なら知りたがるだろうと思って%JV_NA。>
		Msg%id%02 <%name2% から怪しい儲け話を聞いた。\HINT %id1%>
		Msg%id%03 <%name2% から怪しい儲け話を聞いた。>
	end


Plot
	name <PCFac Tipoff>
	% desc <A member of the PC's faction will tip them off about it.>
	desc <PC の所属勢力のメンバーが儲け話を寄越す。>
	requires <*CORE_EMO_ P:++ ~P:PCFAC>

	% E1 is a local public scene
	% E2 is a member of the PC's faction
	element1 <Scene !Near -7 public (building|meeting)>
	element2 <Character !Near 1 !Comrade -3 NeverFail>
	Place2 <1 (Guards) SD>

	5min <if= PlotStatus %plotid% 0  if= RootSceneID &EpisodeScene  SetNPC %2% EMail %id%01  SetPlotStatus %plotid% %id%>
	end <if= PlotStatus %plotid% %id% ifNPCDead %2% LoseEpisode>

	% Msg%id%01_1 <%name2%@ \SCENE &EpisodeScene :// If you're in town I'd love to speak with you.>
	% Msg%id%01_2 <%name2%@ \SCENE &EpisodeScene :// Got a hot tip for you, \PC . There could be easy money involved.>
	% Msg%id%01_3 <%name2%@ \SCENE &EpisodeScene :// I've got some info. Come to \EXACT_SCENE %1% .>
	% Msg%id%01_4 <%name2%@ \SCENE &EpisodeScene :// I've been asked to tell you something, but this is way too sensitive for email.>
	% Msg%id%01_5 <%name2%@ \SCENE &EpisodeScene :// Umcae to \EXACT_SCENE %1% for an Othae Iptae.>
	Msg%id%01_1 <%name2%@ \SCENE &EpisodeScene :// 街に来ているなら、ぜひ%JS2と話がしたい%JV_F_WA。>
	Msg%id%01_2 <%name2%@ \SCENE &EpisodeScene :// ちょっとした情報がある%JV_ZO、\PC。楽に儲かるかもしれない類の話%JV_M_DA%JV_F_YO。>
	Msg%id%01_3 <%name2%@ \SCENE &EpisodeScene :// 少々ネタが入った%JV_F_NO。\EXACT_SCENE %1% まで来るといい%JV_F_WA。>
	Msg%id%01_4 <%name2%@ \SCENE &EpisodeScene :// %JS2にあることを教えるように頼まれた%JG_GA、メールでは伝えるにはデリケートな話%JV_M_DA%JV_F_YO。>
	Msg%id%01_5 <%name2%@ \SCENE &EpisodeScene :// ゥケモァェナしハ"ァェに \EXACT_SCENE %1% コィへァェ>

	% SubPlot1 is the plunder-seeking bit.
	subplot1 <*CS_SeekPlunder>

	sub
		Persona 2
		greeting <if= PlotStatus %plotid% %id% else .%id%_GoChat Goto .%id%_GoGreet>
		.%id%_GoChat <RevertPersona>
		*.%id%_GoGreet <*HowAreYou .%id%_GoBriefing>
		.%id%_GoBriefing <NewChat Say %id%01 SMemo %id%02 History %id%03 SetPlotStatus %plotid1% %id1%>
		% Msg%id%01 <\HINT %id1% I figured that you might want to know.>
		% Msg%id%02 <%name2% told you about some easy money. \HINT %id1%>
		% Msg%id%03 <%name2% told you about some easy money.>
		Msg%id%01 <\HINT %id1% %JS2なら知りたがるだろうと思って%JV_NA。>
		Msg%id%02 <%name2% から楽に儲かる話を聞いた。\HINT %id1%>
		Msg%id%03 <%name2% から楽に儲かる話を聞いた。>
	end

Plot
	name <Welcome Wagon>
	% desc <A police officer inadvertently gives the PC a tip.>
	desc <警察官が PC にうっかり情報を漏らす。>
	requires <*CORE_EMO_>

	% E1 is a local scene
	% E2 is the police officer
	Element1 <Scene !Near -7 public (building|meeting)>
	Element2 <Character POLIC Sociable HasMecha !Near 1 -Friend -Nemesis -Lover -Family NeverFail>
	NeverFail2 <Police Officer>

	start <if= PlotStatus %plotid% 0  ifNPCOK %2% else .%id%_GoEndPlot  if= RootSceneID &EpisodeScene  ifScene .%id%_scenetype  Alert %id%01  ForceChat %2%>
	.%id%_GoEndPlot <LoseEpisode>
	.%id%_scenetype <outdoors>

	% Msg%id%01 <Before you even have the chance to do anything illegal, you are accosted by a large force of police mecha.>
	Msg%id%01 <違法行為など働く間もなかったというのに、あなたは何故か大量の警察部隊のメックに詰め寄られた。>

	% SubPlot1 is the plunder-seeking bit.
	subplot1 <*CS_SeekPlunder>

	sub
		Persona 2
		special <UNLISTED NOESCAPE>
		greeting <if= PlotStatus %plotid% 0 else .%id%_GoChat EndChat Say %id%01 AddChat %id%01 AddReact -15>
		.%id%_GoChat <RevertPersona>
		result%id%01 <EndChat Say %id%02 SMemo %id%03 History %id%04 AddChat %id%02 AddChat %id%03 AddChat %id%04 SetPlotStatus %plotid1% %id1%>
		result%id%02 <EndChat Say %id%05>
		result%id%03 <EndChat Say %id%06>
		result%id%04 <EndChat Say %id%07 AddReact d10>
		% Msg%id%01 <Don't think I don't know what you're doing in town, \PC , and don't think for one minute that you're going to get away with it...>
		% Msg%id%02 <Oh, come on. \HINT %id1% That's the reason you came here, isn't it?>
		% Msg%id%03 <%name2% inadvertently gave you some useful info. \HINT %id1%>
		% Msg%id%04 <%name2% inadvertently gave you some useful info.>
		% Msg%id%05 <What!? Forget I said anything... and whatever you do, don't try to act on it...>
		% Msg%id%06 <Just don't break any laws and you won't have anything to worry about, then.>
		% Msg%id%07 <Make sure you don't... I'll have my eyes on you.>
		% Prompt%id%01 <What are you talking about?>
		% Prompt%id%01_1 <I have no idea what you're talking about.>
		% Prompt%id%02 <You don't say..? Thanks for the tip.>
		% Prompt%id%02_1 <Is that so..? Thanks for telling me.>
		% Prompt%id%03 <Hey, don't think I'm some common crook...>
		% CPrompt%id%03 <if# PCFac PRIVA Accept>
		% Prompt%id%03_1 <Are you calling me a crook?>
		% Prompt%id%04 <Don't worry. I won't overstep my letter of marque.>
		% CPrompt%id%04 <if= PCFac PRIVA Accept>
		Msg%id%01 <%JS_AGGがこの街で何をしているのか、%JF2が知らないなんて思わないこと%JV_M_DA%JV_NA、\PC。ましてや、そのまま無事に逃げられるなどとは%JV_NA……！>
		Msg%id%02 <とぼけないで%JG_R_AGG。\HINT %id1% それが%JS_AGGがここに来た理由%JV_DAROU、違うの%JV_KA_Q？>
		Msg%id%03 <%name2% がうっかりと有用な情報を漏らした。\HINT %id1%>
		Msg%id%04 <%name2% はあなたにうっかりと有用な情報を漏らした。>
		Msg%id%05 <%JR_BIKKURI！？ 今のは忘れて%JG_R_AGG%JV_SIL_R何をしに来たのか知らない%JG_GA、それには手を出さないで%JG_R%JV_SIL_R。>
		Msg%id%06 <なら、法を破ったりさえしなければ面倒事も起こらない%JG_SK。>
		Msg%id%07 <その言葉を忘れないこと%JV_M_DA%JV_NA……%JF2はちゃんと見張っている%JV_ZO%JV_F_YO。>
		Prompt%id%01 <何の話をしてる%JG_NDA？>
		Prompt%id%01_1 <何を言ってるのかさっぱり分からないんだ%JG_GA。>
		Prompt%id%02 <……マジで？ ヒントありがとう。>
		Prompt%id%02_1 <……そうなの%JV_KA_Q？ 教えてくれてありがとう。>
		Prompt%id%03 <%JR_HEY、人をその辺のろくでなし扱いしないで%JG_R_AGG。>
		CPrompt%id%03 <if# PCFac PRIVA Accept>
		Prompt%id%03_1 <人を罪人呼ばわりするの%JV_KA_Q？>
		Prompt%id%04 <心配しなくても、Privateer としての仕事しかしない%JG_YO。>
		CPrompt%id%04 <if= PCFac PRIVA Accept>
	end

Plot
	name <Easy Money Mentor>
	% desc <An experienced pirate will give you a tip.>
	desc <ベテランの海賊が儲け話を寄越す。>
	requires <*CORE_EMO_1 ~!Ne>

	% E1 is a local public scene
	% E2 is the EMO Mentor
	element1 <Scene !Near -7 public (building|meeting)>
	element2 <Prefab>
	place2 <1 pass>

	% P%id%01 = Email Counter
	5Min <if= RootSceneID &EpisodeScene  if= P%id%01 0 P= %id%01 1 SetNPC %2% EMail 1>

	%% FAIL CONDITIONS:
	%% - E2 dies before revealing secret.
	end <if= PlotStatus %plotid% 0 ifNPCDead %2% LoseEpisode>

	% Msg1_1  <%name2%@ \NARRATIVE 7 :// Looking for some easy money? Come see me at \EXACT_SCENE %1% .>
	% Msg1_2  <%name2%@ \NARRATIVE 7 :// This old timer has a few hints for you. Let's talk at \EXACT_SCENE %1% .>
	% Msg1_3  <%name2%@ \NARRATIVE 7 :// I request a parley with you at \EXACT_SCENE %1% .>
	Msg1_1  <%name2%@ \NARRATIVE 7 :// 楽な儲け話は要らない%JV_Q？ \EXACT_SCENE %1% で待ってる%JV_ZO。>
	Msg1_2  <%name2%@ \NARRATIVE 7 :// この老いぼれからちょっとしたヒントがある%JV_ZO。\EXACT_SCENE %1% で話をし%JV_YOU。>
	Msg1_3  <%name2%@ \NARRATIVE 7 :// \EXACT_SCENE %1% で%JS2と面談がしたい%JV_F_NO。>

	% SubPlot1 is the plunder-seeking bit.
	subplot1 <*CS_SeekPlunder>

	sub
		Persona 2
		greeting <if= PlotStatus %plotid% 0 else GoChat Goto .%id%_GoGreet>
		% rumor%id% <%name2% has been looking for you.>
		rumor%id% <%name2% が%JS2のことを探している>
		GoChat <NewChat SayAnything>
		*.%id%_GoGreet <*YouCouldUseHelp .%id%_GoBriefing>
		.%id%_GoBriefing <NewChat Say %id%01 SMemo %id%02 History %id%03 AddChat %id%01 AddChat %id%02 AddChat %id%03 SetPlotStatus %plotid1% %id1% SetXXRAttitude %2% XXR_A_IsSenior SetNPCBio %2% Msg%id%06>
		result%id%01 <NewChat Say %id%04>
		result%id%02 <NewChat Say %id%05 AddCheerful -d10  AddReact d20>
		result%id%03 <NewChat Say %id%07 AddCheerful -d10  AddReact -d20>
		% Msg%id%01 <I've got some info for you. \HINT %id1% This could be a great opportunity...>
		% Msg%id%01_1 <I've got a hot tip for you. \HINT %id1% Get there first and it'll all be yours.>
		% Msg%id%01_2 <Here's something you should know. \HINT %id1% Sounds like this could be a big chance for you.>
		% Msg%id%02 <%name2% gave you a hot tip. \HINT %id1%>
		% Msg%id%03 <%name2% gave you a hot tip.>
		% Msg%id%04 <Eh, maybe someday you can return the favor... just remember, there ain't no such thing as easy money.>
		% Msg%id%05 <You're suspicious... that's good. I'm just telling you what I know. What you do with it is up to you.>
		% Msg%id%06 <%name2% is a retired pirate who now gives out advice to beginners. You got a hot tip from \OPR %2% in \SCENE &EpisodeScene .>
		% Msg%id%07 <I'm just here to get you off your arse, not to do your work for you. Now get out there and see if you can track down any rumors!>
		% Prompt%id%01 <Thanks for the info.>
		% Prompt%id%01_1 <Thanks for letting me know.>
		% Prompt%id%02 <Why are you telling me this?>
		% Prompt%id%02_1 <How do I know I can trust your info?>
		% Prompt%id%03 <That's it!? How about something useful?>
		% Prompt%id%03_1 <Oh yeah, that info's a big help...>
		Msg%id%01 <%JS2にちょっとした情報がある%JV_N%JV_M_DA。\HINT %id1% これは滅多にないチャンスだ%JV_ZO……。>
		Msg%id%01_1 <先着様限定の大ヒント%JG_DA。\HINT %id1% 一番に乗り込めば独り占めできる%JV_ZO%JV_F_YO。>
		Msg%id%01_2 <%JS2に教えてやりたい情報はこれ%JG_DA。\HINT %id1% %JS2には願ってもないチャンスになる%JV_DAROU。>
		Msg%id%02 <%name2% から儲け話を聞いた。\HINT %id1%>
		Msg%id%03 <%name2% から儲け話を聞かされた。>
		Msg%id%04 <%JR_YES、いつか恩返しでも期待しておこう%JG_KANA%JV_SIL_Rしかし覚えておく%JV_N%JV_M_DA%JV_F_YO、簡単な儲け話なんてものは本当はどこにもない%JV_F_NO。>
		Msg%id%05 <疑っているよう%JV_M_DA%JV_NA……良いこと%JV_M_DA%JV_F_YO。%JF2は単に知っていることを教えただけ……そこからどうするかは%JS2次第%JV_M_DA%JV_YO。>
		Msg%id%06 <%name2% は引退した元海賊であり、現在は駆け出しに助言を送っている。\SPR %2%からは \SCENE &EpisodeScene で儲け話のヒントを聞いた。>
		Msg%id%07 <%JF2は単にヒヨッコの巣立ちを手助けしているだけで、代わりに仕事をしてやるためにここに居るわけじゃない%JV_F_NO。さあもう出て行って、噂の一つでも突き止めてみるがいい%JV_F_WA！>
		Prompt%id%01 <情報ありがとう。>
		Prompt%id%01_1 <教えてくれて感謝する%JG_YO。>
		Prompt%id%02 <どうしてそれを%JF2に？>
		Prompt%id%02_1 <それが嘘じゃないという証拠は？>
		Prompt%id%03 <それだけ！？ 役に立つってのはどういう意味%JG_DA？>
		Prompt%id%03_1 <ああそう、お役立ちねえ……。>
	end
	inv
		NPC Pirate
		chardesc Sociable Old Old Old Old Old Renowned Renowned
	end

